Серый форум — AHK: Получение элемента из из IE

Re: AHK: Получение элемента из из IE

null@example.com (estenha) — Fri, 16 Mar 2018 11:46:11 +0000

KusochekDobra
Спасибо, опробую и ваш вариант.
p.s. я опоздал на 35 секунд )

Re: AHK: Получение элемента из из IE

null@example.com (estenha) — Fri, 16 Mar 2018 11:40:52 +0000

Доброго времени суток! Вы не могли бы подсказать на примере вашего кода, который замечательно работает, как реализовать несколько иную задачу...

Сделал через IfInString и Array.Push (мне к тому же еще нужен именно последний элемент из списка идентичных ссылок.) Если кому интересно:

Larray := []
Needle = hyper-universe-
oIE := ComObjCreate("InternetExplorer.Application")
oIE.visible := True
oIE.navigate("https://www.mmorpg.com/sweepstakes")
While oIE.busy  
   Sleep, 20
links := oIE.document.links
; MsgBox % links.length
Loop % links.length  {
   link := links[A_Index - 1]
   b := link.href
   IfInString, b, %Needle%
	{
;	  MsgBox, % link.href
	  Larray.Push(link.href)
	}
}
z := Larray.MaxIndex()
MsgBox % "Последний элемент " Larray[z]

; for index, element in Larray ; здесь можно посмотреть, что в массиве
;	{
;		MsgBox % "Element number " . index . " is " . element
;	}

Re: AHK: Получение элемента из из IE

null@example.com (KusochekDobra) — Fri, 16 Mar 2018 11:40:17 +0000

По условию, отображаемый текст ссылки должен быть эквивалентен "Hyper Universe" без учёта регистра. Если нужны все ссылки, отображаемый текст которых содержит "Hyper Universe", можно записать так:


oIE := ComObjCreate("InternetExplorer.Application")
oIE.visible := True
oIE.navigate("https://www.mmorpg.com/sweepstakes")
While oIE.busy  
	Sleep, 20
links := oIE.document.links
Loop % links.length  {
	link := links[A_Index - 1]
	if (CheckString(link.innerText, "Hyper Universe"))
		MsgBox, % link.href
}
ExitApp
CheckString(mainStr, srchStr) {
	if mainStr contains %srchStr%
		return true
	return false
}

Если нужны ссылки только из заголовков к каждой игре, то можно сделать выборку по классу и потом проходить циклом по её результату:


oIE := ComObjCreate("InternetExplorer.Application")
oIE.visible := True
oIE.navigate("https://www.mmorpg.com/sweepstakes")
While oIE.busy  
	Sleep, 20
links := oIE.document.querySelectorAll(".suhlink")
Loop % links.length  {
	link := links[A_Index - 1]
	if (CheckString(link.innerText, "Hyper Universe"))
		MsgBox, % link.href
}
ExitApp
CheckString(mainStr, srchStr) {
	if mainStr contains %srchStr%
		return true
	return false
}

Если необходимо искать вхождения "hyper-universe" в тексте ссылки, замените условие:


if (CheckString(link.innerText, "Hyper Universe"))

На:


if (CheckString(link.href, "hyper-universe"))

Re: AHK: Получение элемента из из IE

null@example.com (estenha) — Fri, 16 Mar 2018 03:05:07 +0000

Доброго времени суток! Вы не могли бы подсказать на примере вашего кода, который замечательно работает, как реализовать несколько иную задачу - необходимо на основе подстроки из link.href выбирать определенные ссылки, т.е. в данном вашем коде и примере с сайта нужно находить, возьмем тот же Hyper Universe, в атрибуте href="/sweepstakes/hyper-universe-mvp-starter-pack-sweepstakes-1000000057" подстроку hyper-universe, и выводить полную ссылку с этой подстрокой в тот же MsgBox. Я пробовал использовать if Var contains MatchList - if link.href contains hyper-universe, но в этом случае выводятся все ссылки подряд. Видимо, по неопытности я чего-то еще не понимаю.

Malcev пишет:

У меня работает:

oIE := ComObjCreate("InternetExplorer.Application")
oIE.visible := True
oIE.navigate("https://www.mmorpg.com/sweepstakes")
While oIE.busy  
   Sleep, 20
links := oIE.document.links
Loop % links.length  {
   link := links[A_Index - 1]
   if (link.innerText = "Hyper Universe")
      MsgBox, % link.href
}

Re: AHK: Получение элемента из из IE

null@example.com (romzes96) — Thu, 15 Mar 2018 17:56:41 +0000

KusochekDobra
Спасибо. Все работает хорошо.

Re: AHK: Получение элемента из из IE

null@example.com (KusochekDobra) — Wed, 14 Mar 2018 10:49:25 +0000

Замените в примере, строку:

MsgBox, % href ? href : "Не найдено"

На:


if (href)
	activlink := href
else
	MsgBox, Не найдено.

Re: AHK: Получение элемента из из IE

null@example.com (romzes96) — Wed, 14 Mar 2018 09:39:56 +0000

teadrinker пишет:

Тогда так примерно:

linkText := "Dsaasd"

oIE := WBGet()
if !IsObject(oIE)  {
   MsgBox, Не удалось получить объект InternetExplorer
   return
}
links := oIE.document.links, href := ""
Loop % links.length  {
   link := links[A_Index - 1]
   if (link.innerText = linkText && href := link.href)
      break
}
MsgBox, % href ? href : "Не найдено"

WBGet(WinTitle := "ahk_class IEFrame", Svr# := 1)
{
   static msg := DllCall("RegisterWindowMessage", Str, "WM_HTML_GETOBJECT")
        , IID_IWebBrowserApp := "{0002DF05-0000-0000-C000-000000000046}"
        , IID_IHTMLDocument2 := "{332C4425-26CB-11D0-B483-00C04FD90119}"
        , VT_DISPATCH := 9, F_OWNVALUE := 1
        
   SendMessage, msg, 0, 0, Internet Explorer_Server%Svr#%, %WinTitle%
   lResult := ErrorLevel
   if (lResult = "FAIL")
      return
   
   VarSetCapacity(GUID, 16, 0)
   DllCall("ole32\CLSIDFromString", WStr, IID_IHTMLDocument2, Ptr, &GUID)
   DllCall("oleacc\ObjectFromLresult", Ptr, lResult, Ptr, &GUID, Ptr, 0, PtrP, pdoc)
   oWb := ComObject(VT_DISPATCH, ComObjQuery(pdoc, IID_IWebBrowserApp, IID_IWebBrowserApp), F_OWNVALUE)
   ObjRelease(pdoc)
   return oWb
}

Здравствуйте. Воспользовался Вашим кодом. для моих целей работает превосходно. Но не могу понять как сделать так что бы в конце не выпрыгивало окно с ссылкой. не могли бы Вы помочь разобраться? Хотелось бы что бы ссылка просто записывалась в переменную допустим activlink. Но что бы не было этого окна по завершению скрипта. Но что бы осталось окно о том что ссылка не найдена.

Re: AHK: Получение элемента из из IE

null@example.com (Malcev) — Fri, 26 Jan 2018 20:31:32 +0000

document.getElementsByClassName("contestopen")[0].getElementsByTagName("a")[0].href

Также можно через QuerySelectorAll либо XPath, почитайте информацию сами если заинтересует.

Re: AHK: Получение элемента из из IE

null@example.com (Alex_Lexon) — Fri, 26 Jan 2018 20:01:13 +0000

Malcev, при вводе этого:

document.getElementsByClassName("contestopen")[0].cells[1].links

выводит undefined

Re: AHK: Получение элемента из из IE

null@example.com (Malcev) — Fri, 26 Jan 2018 19:12:55 +0000

А в чем проблема? Приведите код.

Re: AHK: Получение элемента из из IE

null@example.com (Alex_Lexon) — Fri, 26 Jan 2018 18:33:11 +0000

Malcev, да, этот код действительно работает! Спасибо.
А если мне нужно вывести ссылки из getElementsByClassName, то тогда как? Ибо если пробую после класса ставить .links, то выдаёт - undefined.

Re: AHK: Получение элемента из из IE

null@example.com (Malcev) — Fri, 26 Jan 2018 17:39:24 +0000

У меня работает:

oIE := ComObjCreate("InternetExplorer.Application")
oIE.visible := True
oIE.navigate("https://www.mmorpg.com/sweepstakes")
While oIE.busy  
   Sleep, 20
links := oIE.document.links
Loop % links.length  {
   link := links[A_Index - 1]
   if (link.innerText = "Hyper Universe")
      MsgBox, % link.href
}

Re: AHK: Получение элемента из из IE

null@example.com (Alex_Lexon) — Fri, 26 Jan 2018 14:28:44 +0000

Не работает данный способ, возможно, Вы не совсем поняли, про какие ссылки я говорю.

Re: AHK: Получение элемента из из IE

null@example.com (Malcev) — Thu, 25 Jan 2018 22:31:41 +0000

Ссылки находятся во фрейме:

oIE := ComObjCreate("InternetExplorer.Application")
oIE.visible := True
oIE.navigate("https://www.mmorpg.com/sweepstakes")
While oIE.busy  
   Sleep, 20
links := oIE.document.parentWindow.frames[6].document.links
Loop % links.length  {
   link := links[A_Index - 1]
   MsgBox, % "Link text: " . link.innerText . "`nLink href: " . link.href
}

Re: AHK: Получение элемента из из IE

null@example.com (Alex_Lexon) — Thu, 25 Jan 2018 20:57:34 +0000

https://www.mmorpg.com/sweepstakes
Ссылки на игры, что находятся в классе "contestopen". Справа от описания есть названия игр, что являются ссылками, ссылки на игры из класса "contestopen" и нужны.