Серый форум — AHK: Как запретить ввод ПРОБЕЛА в поле для ввода?

Re: AHK: Как запретить ввод ПРОБЕЛА в поле для ввода?

null@example.com (MirchikAhtung) — Mon, 16 Apr 2018 13:32:55 +0000

teadrinker
Всё работает. Огромное вам спасибо :-)

Re: AHK: Как запретить ввод ПРОБЕЛА в поле для ввода?

null@example.com (teadrinker) — Mon, 16 Apr 2018 09:57:54 +0000

А, понял, в чём проблема. В функцию нужно передать имя окна, т. к. внутри функции переменная gui_name не видна:

values := [ {input: "gg ss", function: Func("FirstFunc" ), delay: 3000}
          , {input: "gg s" , function: Func("SecondFunc"), delay: 3000}
          , {input: "ss g" , function: Func("ThirdFunc" ), delay: 3000} ] 

gui_name := "Main"
Gui, %gui_name%:Add, Edit, vEdit gWatchEdit w150, Текст
Gui, %gui_name%:Show
Return

WatchEdit()  {
   global values
   GuiControlGet, Edit
   for k, v in values
      if RegExMatch(Edit, "^\Q" . v.input . "\E$") && i := k
         break
      
   if i  {
      obj := values[i]
      if !obj.delay
         obj.function.Call(A_Gui)
      else  {
         timer := obj.function.Bind(A_Gui)  ; передаём имя окна, оно здесь в переменной A_Gui
         SetTimer, % timer, % "-" . obj.delay
      }
   }
}

FirstFunc(GuiName)  {
   ExitApp
}

SecondFunc(GuiName)  {
   MsgBox, "gg s"
   GuiControl, %GuiName%:, Edit
}

ThirdFunc(GuiName)  {
   MsgBox, "ss g"
}

Re: AHK: Как запретить ввод ПРОБЕЛА в поле для ввода?

null@example.com (MirchikAhtung) — Mon, 16 Apr 2018 04:30:34 +0000

teadrinker
Похоже я не так объяснил, т.е запутав, из-за чего вы меня немного не так поняли.
Оно стирает, стирает ТЕКСТ при запуске скрипта, но нужно, чтобы стирало и текст что мы ввели, те gg s - выскочил msgbox - стёрлась строка и.т.д.

show := 1 

values := [ {input: "gg ss", function: Func("FirstFunc" ), delay: 300}
          , {input: "gg s" , function: Func("SecondFunc"), delay: 300}
          , {input: "ss g" , function: Func("ThirdFunc" ), delay: 300} ] 
gui_name := "Main" 
Gui, %gui_name%: +AlwaysOnTop 
Gui, %gui_name%:Add, Edit, vEdit gWatchEdit w150, ТЕКСТ
Gui, %gui_name%:Show
Sleep 1000
GuiControl, %gui_name%:, Edit 
Return

Re: AHK: Как запретить ввод ПРОБЕЛА в поле для ввода?

null@example.com (teadrinker) — Sun, 15 Apr 2018 21:44:17 +0000

gui_name := "Main" 
Gui, %gui_name%: +AlwaysOnTop 
Gui, %gui_name%:Add, Edit, vEdit w150, Текст
Gui, %gui_name%:Show
Sleep 1000
GuiControl, %gui_name%:, Edit

Re: AHK: Как запретить ввод ПРОБЕЛА в поле для ввода?

null@example.com (MirchikAhtung) — Sun, 15 Apr 2018 21:29:12 +0000

teadrinker
Я маленько запутался.
Я ранее пробовал - не работало.
Сейчас - не работает.
И так

GuiControl, %gui_name%:Show, Edit

и вот так

GuiControl, %gui_name%:, Edit

Не вижу очевидного, либо чего-то ещё не хватает?

Re: AHK: Как запретить ввод ПРОБЕЛА в поле для ввода?

null@example.com (teadrinker) — Sun, 15 Apr 2018 21:03:19 +0000

GuiControl, %gui_name%:, Edit

Ссылка на пример в хэлпе.

Re: AHK: Как запретить ввод ПРОБЕЛА в поле для ввода?

null@example.com (MirchikAhtung) — Sun, 15 Apr 2018 20:59:02 +0000

teadrinker
Про шерстил с конца до середины https://autohotkey.com/docs/commands/GuiControl.htm
Я себе пару нервных клеток убил, но результата не дало.
Напишите прямой ответ! Захочу - не найду.

Re: AHK: Как запретить ввод ПРОБЕЛА в поле для ввода?

null@example.com (teadrinker) — Sun, 15 Apr 2018 20:08:36 +0000

MirchikAhtung пишет:

GuiControl,, %gui_name%:Edit

%gui_name% не в том месте. Читайте хелп внимательнее.

Re: AHK: Как запретить ввод ПРОБЕЛА в поле для ввода?

null@example.com (MirchikAhtung) — Sun, 15 Apr 2018 20:04:26 +0000

teadrinker пишет:

У меня зачищает.

Gui, Add, Edit, vEdit w150, Текст
Gui, Show
Sleep, 1000
GuiControl,, Edit

Вот моё начало, я не понимаю что тут всё портит..

show := 1 

values := [ {input: "gg ss", function: Func("FirstFunc" ), delay: 300}
          , {input: "gg s" , function: Func("SecondFunc"), delay: 300}
          , {input: "ss g" , function: Func("ThirdFunc" ), delay: 300} ] 
gui_name := "Main" 
Gui, %gui_name%: +AlwaysOnTop 
Gui, %gui_name%:Add, Edit, vEdit gWatchEdit w150, Текст
Gui, %gui_name%:Show
GuiControl,, %gui_name%:Edit
Return

Re: AHK: Как запретить ввод ПРОБЕЛА в поле для ввода?

null@example.com (teadrinker) — Sun, 15 Apr 2018 19:55:24 +0000

У меня зачищает.

Gui, Add, Edit, vEdit w150, Текст
Gui, Show
Sleep, 1000
GuiControl,, Edit

Re: AHK: Как запретить ввод ПРОБЕЛА в поле для ввода?

null@example.com (MirchikAhtung) — Sun, 15 Apr 2018 19:20:24 +0000

teadrinker пишет:

Ассоциированная переменная не vEdit, а просто Edit. v — это название опции.

GuiControl,, Edit

Не зачищает строку для ввода.
Использую последний код, что ты мне скинул.

Re: AHK: Как запретить ввод ПРОБЕЛА в поле для ввода?

null@example.com (teadrinker) — Sun, 15 Apr 2018 19:00:55 +0000

MirchikAhtung пишет:

GuiControl,, vEdit

Ассоциированная переменная не vEdit, а просто Edit. v — это название опции.

Re: AHK: Как запретить ввод ПРОБЕЛА в поле для ввода?

null@example.com (MirchikAhtung) — Sun, 15 Apr 2018 18:45:35 +0000

teadrinker
Вдвойне рукалицо.
GuiControl, vEdit в функции после msgbox не затирает поле для ввода, мои знания в AHK очень скудны, и помимо этого ничего не лезет в голову..


SecondFunc()  {
   MsgBox, "gg s"
GuiControl,, vEdit
}

Re: AHK: Как запретить ввод ПРОБЕЛА в поле для ввода?

null@example.com (teadrinker) — Sun, 15 Apr 2018 14:18:07 +0000

MirchikAhtung, рукалицо.jpeg

values := [ {input: "gg ss", function: Func("FirstFunc" ), delay: 3000}
          , {input: "gg s" , function: Func("SecondFunc"), delay: 3000}
          , {input: "ss g" , function: Func("ThirdFunc" ), delay: 3000} ] 

Gui, Add, Edit, vEdit gWatchEdit
Gui, Show
Return

WatchEdit()  {
   global values
   GuiControlGet, Edit
   for k, v in values
      if RegExMatch(Edit, "^\Q" . v.input . "\E$") && i := k
         break
      
   if i  {
      obj := values[i]
      if !obj.delay
         obj.function.Call()
      else  {
         timer := obj.function
         SetTimer, % timer, % "-" . obj.delay
      }
   }
}

FirstFunc()  {
   ExitApp
}

SecondFunc()  {
   MsgBox, "gg s"
}

ThirdFunc()  {
   MsgBox, "ss g"
}

Re: AHK: Как запретить ввод ПРОБЕЛА в поле для ввода?

null@example.com (MirchikAhtung) — Sun, 15 Apr 2018 14:03:07 +0000

teadrinker Это я попробывал поставить таймер на все 3 функции :-(