Серый форум — AHK : Информация о файле

Re: AHK : Информация о файле

null@example.com (teadrinker) — Wed, 13 Jun 2018 23:38:11 +0000

Да, действительно, через GDI+ быстрее. Но мой вариант зато без сторонних библиотек.

Re: AHK : Информация о файле

null@example.com (Malcev) — Wed, 13 Jun 2018 23:07:02 +0000

teadrinker пишет:

Ну, если уж по-умному, и как быстрее,

Замерил скорости (13 mb небитый jpg):

LoadPicture(imageFilePath, "GDI+") - 200 ms
LoadPicture(imageFilePath) - 700 ms
Gdip_CreateBitmapFromFile("c:\myImage.jpg") - 30 ms

Файлы:
https://ru.files.fm/u/59dw8vw8

Re: AHK : Информация о файле

null@example.com (teadrinker) — Wed, 13 Jun 2018 23:00:32 +0000

У меня даже не на чем попробовать.

Re: AHK : Информация о файле

null@example.com (Malcev) — Wed, 13 Jun 2018 22:51:45 +0000

А битый файл зрительно можно и не отличить.
Например битый jpg без видимых битых пикселов может прекрасно открываться в пейнте.
Кстати, с опцией GDI+ открывает.

hBitmap := LoadPicture(imageFilePath, "GDI+")

Re: AHK : Информация о файле

null@example.com (teadrinker) — Wed, 13 Jun 2018 22:48:33 +0000

Да и ну их, эти битые файлы, кому они нужны.

Re: AHK : Информация о файле

null@example.com (Malcev) — Wed, 13 Jun 2018 22:44:18 +0000

Неа, LoadPicture с битыми файлами не работает.

Re: AHK : Информация о файле

null@example.com (teadrinker) — Wed, 13 Jun 2018 22:42:13 +0000

Ну, если уж по-умному, и как быстрее, то лучше так:

filePath := "D:\Images\MyPicture.png"
if oSize := GetImageSize(filePath)
   MsgBox, % oSize.W . "`n" oSize.H

GetImageSize(imageFilePath)  {
   if !hBitmap := LoadPicture(imageFilePath)  {
      MsgBox, Не удалось получить hBitmap
      Return
   }
   VarSetCapacity(BITMAP, size := 4*4 + A_PtrSize*2, 0)
   DllCall("GetObject", Ptr, hBitmap, Int, size, Ptr, &BITMAP)
   DllCall("DeleteObject", Ptr, hBitmap)
   Return { W: NumGet(BITMAP, 4, "UInt"), H: NumGet(BITMAP, 8, "UInt") }
}

Re: AHK : Информация о файле

null@example.com (Malcev) — Wed, 13 Jun 2018 22:35:59 +0000

Я бы таким способом не пользовался, так как картинка может в гуи не загрузиться (например из-за битого кодека).
Надёжней и быстрее так:

pToken := Gdip_StartUp()
pBitmap := Gdip_CreateBitmapFromFile("c:\myImage.jpg")
Gdip_GetImageDimensions(pBitmap, w, h)
Gdip_DisposeImage(pBitmap)
Gdip_ShutDown(pToken)
MsgBox, % "Width: " w " Height: " h

Re: AHK : Информация о файле

null@example.com (teadrinker) — Wed, 13 Jun 2018 22:00:06 +0000

Проще всего так:

filePath := "D:\Images\MyPicture.png"
oSize := GetImageSize(filePath)
MsgBox, % oSize.W . "`n" oSize.H
ExitApp

GetImageSize(imageFilePath)  {
   Gui, New
   Gui, Add, Pic,, % imageFilePath
   GuiControlGet, Pic, Pos, Static1
   Gui, Destroy
   Return { W: PicW, H: PicH }
}

AHK : Информация о файле

null@example.com (qqlexa) — Wed, 13 Jun 2018 21:23:50 +0000

Хочется узнать можно ли определить размер картинки, в пикселях.