Option Explicit

Sub NonConditionalFormatting()
' Slightly modified version of http://www.experts-exchange.com/Software/Office_Productivity/Office_Suites/MS_Office/Excel/Q_24179503.html
Dim cel As Range
Dim boo As Boolean
Dim frmla As String
Dim i As Long
Dim v As Variant
Dim w As Variant
Application.ScreenUpdating = False
'For Each cel In ActiveSheet.UsedRange  'Remove conditional formatting from entire worksheet
For Each cel In Selection   'Remove conditional formatting from selected cells
    If cel.FormatConditions.Count > 0 Then
        cel.Activate
        With cel.FormatConditions
            For i = 1 To .Count
                frmla = .Item(i).Formula1
                frmla = UnlocaleFormula(frmla)
                If Left(frmla, 1) = "=" Then
                    v = Application.Evaluate(frmla)
                    On Error Resume Next
                        w = v
                        w = v(1)
                    On Error GoTo 0
                    boo = IIf(IsError(w), False, CBool(w))
                Else
                    Select Case .Item(i).Operator
                    Case xlEqual  ' =
                        frmla = cel & "=" & .Item(i).Formula1
                    Case xlNotEqual
                        frmla = cel & "<>" & .Item(i).Formula1
                    Case xlBetween
                        frmla = "AND(" & .Item(i).Formula1 & "<=" & cel & "," & cel & "<=" & .Item(i).Formula2 & ")"
                    Case xlNotBetween
                        frmla = "OR(" & .Item(i).Formula1 & ">" & cel & "," & cel & ">" & .Item(i).Formula2 & ")"
                    Case xlLess
                        frmla = cel & "<" & .Item(i).Formula1
                    Case xlLessEqual
                        frmla = cel & "<=" & .Item(i).Formula1
                    Case xlGreater
                        frmla = cel & ">" & .Item(i).Formula1
                    Case xlGreaterEqual
                        frmla = cel & ">=" & .Item(i).Formula1
                    End Select
                    boo = Application.Evaluate(frmla)
                End If
                If boo Then
                    cel.Font.ColorIndex = .Item(i).Font.ColorIndex
                    cel.Interior.ColorIndex = .Item(i).Interior.ColorIndex
                    Exit For
                End If
            Next i
            .Delete
        End With
    End If
Next cel
Application.ScreenUpdating = True
End Sub
                    
Public Function UnlocaleFormula(ByVal Formula As String) As String
    With ThisWorkbook.Worksheets(1).Range("IU1")
        .FormulaLocal = Formula
        UnlocaleFormula = .Formula
        .ClearContents
    End With
End Function

path =* .xlsx
Xl := ComObjCreate("Excel.Application")
Xl.Workbooks.Open(Path)
Xl.Visible := true

xl.Worksheets(1).Range("A1:A10").FormatConditions.Delete