Серый форум — AHK, GUI: Как вывести по верх всех окон изображение.

Re: AHK, GUI: Как вывести по верх всех окон изображение.

null@example.com (nonamefromukraine) — Sun, 05 Dec 2021 13:47:11 +0000

А можно как-то две картинки сразу вывести?
upd: Извините, решил

Re: AHK, GUI: Как вывести по верх всех окон изображение.

null@example.com (KusochekDobra) — Wed, 10 Apr 2019 15:26:46 +0000

Последний вариант отлично работает. Спасибо за хороший пример!

Re: AHK, GUI: Как вывести по верх всех окон изображение.

null@example.com (serzh82saratov) — Wed, 10 Apr 2019 14:26:41 +0000

Извиняюсь, без констант, и определения что сообщение - движение мышью.

#SingleInstance, Force
#NoEnv
SetBatchLines, -1
CoordMode, Mouse, Screen 

#Include 

If !pToken := Gdip_Startup()
{
	MsgBox, 48, gdiplus error!, Gdiplus failed to start. Please ensure you have gdiplus on your system
	ExitApp
}
OnExit, Exit

Width := 20, Height := 20
WS_EX_LAYERED := 0x80000, WS_EX_TRANSPARENT := 0x20
Gui, New, % "-Caption +AlwaysOnTop +ToolWindow +hwndhGui +E" . Format("{:#x}", WS_EX_LAYERED|WS_EX_TRANSPARENT)
Gui, Show, NA
hwnd1 := hGui 

hbm := CreateDIBSection(Width, Height)
hdc := CreateCompatibleDC()
obm := SelectObject(hdc, hbm)
G := Gdip_GraphicsFromHDC(hdc)
Gdip_SetSmoothingMode(G, 4)
pBrush := Gdip_BrushCreateSolid(0x70ff0000)
Gdip_FillEllipse(G, pBrush, 0, 0, 20, 20)
Gdip_DeleteBrush(pBrush) 
Gdip_DeleteGraphics(G)
DeleteObject(hbm)  
DeleteObject(obm)  

OnMessage(0x00FF, "InputHandler")
RegisterRawInputDevices(1, 2) 
Return 

Esc::
Exit: 
	DeleteDC(hdc)
	Gdip_Shutdown(pToken)
	ExitApp
	
InputHandler(wParam, lParam) { 
	Global
	MouseGetPos, xx, yy 
	UpdateLayeredWindow(hwnd1, hdc, xx, yy, Width, Height) 
	; Gui, % hwnd1 ": +AlwaysOnTop"
}

RegisterRawInputDevices(usagePage, usage) {
    static RIDEV_INPUTSINK := 0x00000100
    VarSetCapacity(rawDevice, 8 + A_PtrSize)
    NumPut(usagePage,       rawDevice, 0, "UShort")
    NumPut(usage,           rawDevice, 2, "UShort")
    NumPut(RIDEV_INPUTSINK, rawDevice, 4, "UInt")
    NumPut(A_ScriptHWND,    rawDevice, 8, "UPtr")

    if !DllCall("RegisterRawInputDevices"
        , "Ptr", &rawDevice
        , "UInt", 1
        , "UInt", 8 + A_PtrSize)
    {
        throw "Failed to register for HID Device"
    }
}

Re: AHK, GUI: Как вывести по верх всех окон изображение.

null@example.com (serzh82saratov) — Wed, 10 Apr 2019 13:48:45 +0000

serzh82saratov пишет:

Я бы ещё на HID попробовал отследить,

Хотя тут палка о двух концах. С хуком без таймера - гарантия что окно будет всегда рядом с курсором, но просадки повлияют на соответствие движений мышью и курсора. И случается что с хуком (тем более мышиным) происходят затыки, вплоть до блокировки ввода.
С HID просадки повлияют на соответствие позиции курсора и окна.

Re: AHK, GUI: Как вывести по верх всех окон изображение.

null@example.com (serzh82saratov) — Wed, 10 Apr 2019 13:41:10 +0000

Последний нормально работает?

Re: AHK, GUI: Как вывести по верх всех окон изображение.

null@example.com (KusochekDobra) — Wed, 10 Apr 2019 13:38:11 +0000

serzh82saratov пишет:

Я бы ещё на HID попробовал отследить

Буду Вам благодарен за пример!

Re: AHK, GUI: Как вывести по верх всех окон изображение.

null@example.com (serzh82saratov) — Wed, 10 Apr 2019 13:15:33 +0000

Ну и hook тут неправильно использовать. Перехват тут не нужен, ожидание в хуке не есть хорошо, хотя и так "успевает":

#SingleInstance, Force
#NoEnv
SetBatchLines, -1

#Include 

If !pToken := Gdip_Startup()
{
	MsgBox, 48, gdiplus error!, Gdiplus failed to start. Please ensure you have gdiplus on your system
	ExitApp
}
OnExit, Exit

Width := 20, Height := 20
WS_EX_LAYERED := 0x80000, WS_EX_TRANSPARENT := 0x20
Gui, New, % "-Caption +AlwaysOnTop +ToolWindow +hwndhGui +E" . Format("{:#x}", WS_EX_LAYERED|WS_EX_TRANSPARENT)
Gui, Show, NA
hwnd1 := hGui 

hbm := CreateDIBSection(Width, Height)
hdc := CreateCompatibleDC()
obm := SelectObject(hdc, hbm)
G := Gdip_GraphicsFromHDC(hdc)
Gdip_SetSmoothingMode(G, 4)
pBrush := Gdip_BrushCreateSolid(0x80ff0000)
Gdip_FillEllipse(G, pBrush, 0, 0, 20, 20)
Gdip_DeleteBrush(pBrush) 
Gdip_DeleteGraphics(G)
DeleteObject(hbm)  
DeleteObject(obm)  

CallBack := RegisterCallback("MouseHook")
hook := SetWindowsHookEx(14, CallBack)
Return 

Esc::
Exit:
	if hook
		UnhookWindowsHookEx(hook)
	Gdip_Shutdown(pToken)
	DeleteDC(hdc)
	ExitApp

MouseHook(nCode, wParam, lParam) {
    Global hwnd1, hdc, Width, Height
    if (nCode >= 0) {
        xx := NumGet(lParam+0, 0, "Int")
        yy := NumGet(lParam+0, 4, "Int")
        UpdateLayeredWindow(hwnd1, hdc, xx, yy, Width, Height) 
		; Gui, % hwnd1 ": +AlwaysOnTop"
    } Return CallNextHookEx(nCode, wParam, lParam)
}

SetWindowsHookEx(idHook, pfn) {
   Return DllCall("SetWindowsHookEx", "int", idHook, "Ptr", pfn, "Ptr", DllCall("GetModuleHandle", "Ptr", 0, "Ptr"), "UInt", 0)
}
CallNextHookEx(nCode, wParam, lParam, hHook = 0) {
   Return DllCall("CallNextHookEx", "Ptr", hHook, "int", nCode, "Ptr", wParam, "Ptr", lParam)
}
UnhookWindowsHookEx(hHook) {
   Return DllCall("UnhookWindowsHookEx", "Ptr", hHook)
}

Таймер в хуке часто сбрасывается, и окно и не двигается до менее интенсивных движений. Я бы ещё на HID попробовал отследить, это всё таки сообщение, ему задержки не страшны.

Re: AHK, GUI: Как вывести по верх всех окон изображение.

null@example.com (serzh82saratov) — Wed, 10 Apr 2019 13:09:33 +0000

Для начала так.

#SingleInstance, Force
#NoEnv
SetBatchLines, -1

#Include 

If !pToken := Gdip_Startup()
{
	MsgBox, 48, gdiplus error!, Gdiplus failed to start. Please ensure you have gdiplus on your system
	ExitApp
}
OnExit, Exit

Width := 20, Height := 20
WS_EX_LAYERED := 0x80000, WS_EX_TRANSPARENT := 0x20
Gui, New, % "-Caption +AlwaysOnTop +ToolWindow +hwndhGui +E" . Format("{:#x}", WS_EX_LAYERED|WS_EX_TRANSPARENT)
Gui, Show, NA
hwnd1 := hGui 

hbm := CreateDIBSection(Width, Height)
hdc := CreateCompatibleDC()
obm := SelectObject(hdc, hbm)
G := Gdip_GraphicsFromHDC(hdc)
Gdip_SetSmoothingMode(G, 4)
pBrush := Gdip_BrushCreateSolid(0x80ff0000)
Gdip_FillEllipse(G, pBrush, 0, 0, 20, 20)
Gdip_DeleteBrush(pBrush) 
Gdip_DeleteGraphics(G)
DeleteObject(hbm)  
DeleteObject(obm)  

CallBack := RegisterCallback("MouseHook")
hook := SetWindowsHookEx(14, CallBack)
Return

DrawMyPic:
	UpdateLayeredWindow(hwnd1, hdc, xx, yy, Width, Height) 
Return

Esc::
Exit:
	if hook
		UnhookWindowsHookEx(hook)
	Gdip_Shutdown(pToken)
	DeleteDC(hdc)
	ExitApp

MouseHook(nCode, wParam, lParam) {
    Global xx, yy
    Critical 1000
    if (nCode >= 0) {
        xx := NumGet(lParam+0, 0, "Int")
        yy := NumGet(lParam+0, 4, "Int")
        SetTimer, DrawMyPic, -1
    } Return CallNextHookEx(nCode, wParam, lParam)
}

SetWindowsHookEx(idHook, pfn) {
   Return DllCall("SetWindowsHookEx", "int", idHook, "Ptr", pfn, "Ptr", DllCall("GetModuleHandle", "Ptr", 0, "Ptr"), "UInt", 0)
}
CallNextHookEx(nCode, wParam, lParam, hHook = 0) {
   Return DllCall("CallNextHookEx", "Ptr", hHook, "int", nCode, "Ptr", wParam, "Ptr", lParam)
}
UnhookWindowsHookEx(hHook) {
   Return DllCall("UnhookWindowsHookEx", "Ptr", hHook)
}

Re: AHK, GUI: Как вывести по верх всех окон изображение.

null@example.com (serzh82saratov) — Wed, 10 Apr 2019 12:43:17 +0000

Окно во весь экран заново переписывать, конечно тормозит.

Re: AHK, GUI: Как вывести по верх всех окон изображение.

null@example.com (KusochekDobra) — Wed, 10 Apr 2019 11:27:54 +0000

Подскажите пожалуйста, как сделать так, чтобы такое изображение следовало за курсором?
Моя попытка сильно жрёт процессор и постоянно дёргается:


#SingleInstance, Force
#NoEnv
SetBatchLines, -1

#Include 

If !pToken := Gdip_Startup()
{
	MsgBox, 48, gdiplus error!, Gdiplus failed to start. Please ensure you have gdiplus on your system
	ExitApp
}
OnExit, Exit

Width := A_ScreenWidth, Height := A_ScreenHeight
WS_EX_LAYERED := 0x80000, WS_EX_TRANSPARENT := 0x20
Gui, New, % "-Caption +AlwaysOnTop +ToolWindow +hwndhGui +E" . Format("{:#x}", WS_EX_LAYERED|WS_EX_TRANSPARENT)
Gui, Show, NA

hwnd1 := hGui

CallBack := RegisterCallback("MouseHook")
hook := SetWindowsHookEx(14, CallBack)
Return

DrawMyPic:
	hbm := CreateDIBSection(Width, Height)
	hdc := CreateCompatibleDC()
	obm := SelectObject(hdc, hbm)
	G := Gdip_GraphicsFromHDC(hdc)
	Gdip_SetSmoothingMode(G, 4)
	pBrush := Gdip_BrushCreateSolid(0x80ff0000)
	Gdip_FillEllipse(G, pBrush, xx-10, yy-10, 20, 20)
	Gdip_DeleteBrush(pBrush)
	UpdateLayeredWindow(hwnd1, hdc, 0, 0, Width, Height)
	SelectObject(hdc, obm)
	DeleteObject(hbm)
	DeleteDC(hdc)
	Gdip_DeleteGraphics(G)
Return

Esc::
Exit:
	if hook
		UnhookWindowsHookEx(hook)
	Gdip_Shutdown(pToken)
	ExitApp

MouseHook(nCode, wParam, lParam) {
    Global xx, yy
    Critical 1000
    if (nCode >= 0) {
        xx := NumGet(lParam+0, 0, "Int")
        yy := NumGet(lParam+0, 4, "Int")
        SetTimer, DrawMyPic, -1
    } Return CallNextHookEx(nCode, wParam, lParam)
}

SetWindowsHookEx(idHook, pfn) {
   Return DllCall("SetWindowsHookEx", "int", idHook, "Ptr", pfn, "Ptr", DllCall("GetModuleHandle", "Ptr", 0, "Ptr"), "UInt", 0)
}
CallNextHookEx(nCode, wParam, lParam, hHook = 0) {
   Return DllCall("CallNextHookEx", "Ptr", hHook, "int", nCode, "Ptr", wParam, "Ptr", lParam)
}
UnhookWindowsHookEx(hHook) {
   Return DllCall("UnhookWindowsHookEx", "Ptr", hHook)
}

Re: AHK, GUI: Как вывести по верх всех окон изображение.

null@example.com (Malcev) — Fri, 20 Jul 2018 13:26:25 +0000

Возможно у меня был глюк в системе, но в Win10 этого не удалось повторить.
На счет Вин7 этот недостаток остался (он есть только при активации окна мышью).

Re: AHK, GUI: Как вывести по верх всех окон изображение.

null@example.com (teadrinker) — Fri, 20 Jul 2018 12:27:12 +0000

Первое, честно говоря, не понял, у меня всё нормально, да и нужно ли так заморачиваться. В любом случае, если есть окно, которое AlwaysOnTop, такие окна будут конкурировать.
На десятке у меня тоже нормально работает, при закрытии пропадает. Там это событие специально обрабатывается — EVENT_OBJECT_DESTROY.

Re: AHK, GUI: Как вывести по верх всех окон изображение.

null@example.com (Malcev) — Fri, 20 Jul 2018 11:42:59 +0000

teadrinker, в твоём коде из 8 поста не всегда соблюдается условие "Нужно вывести изображение по верх всех окон."
1) Сдвигаем окно блокнота так, чтобы картинка "AHK" была над кнопкой Start.
2) Нажимаем кнопку Start.
3) Активируем окно блокнота.
В результате кнопка Start будет поверх картинки "AHK" при активированном блокноте.
А на Win10 вообще глючит - при закрытии блокнота картинка остантся.

Re: AHK, GUI: Как вывести по верх всех окон изображение.

null@example.com (teadrinker) — Fri, 20 Jul 2018 10:21:07 +0000

Нет, просто если делаешь скрипт только для себя, то можно применять эту фичу.

Re: AHK, GUI: Как вывести по верх всех окон изображение.

null@example.com (serzh82saratov) — Fri, 20 Jul 2018 10:10:00 +0000

В таких случаях можно делать проверку ОС, хоть у кого то будет работать как должно.