Option Explicit

Const adTypeBinary			= 1
Const adSaveCreateOverWrite = 2

Dim i, oGoogleSpeech, strText

Set oGoogleSpeech = new cGoogleSpeech

'Создание объекта Stream для записи файлов на диск
With CreateObject("ADODB.Stream")
	.Type = adTypeBinary
	For i = 1 to 7
		'Перебор всех дней недели и получение их текстового наименования
		strText = WeekdayName(i)
		'Запрос к Google Speech для получения аудио файла и возврат результата в Stream
		.Open
		.Write oGoogleSpeech.TextToAudioStream(strText,"ru")
		'Сохранение файлов с именами дней недели
		.SaveToFile strText & ".mp3", adSaveCreateOverWrite
		.Close
	Next
End With

'Класс модуль для выполнения запросов к сервису google translate
Class cGoogleSpeech
	Private oHtmlDoc
	Private Sub Class_Initialize()
		'Создание объекта HTMLDocument для использования движка JavaScript и его функции encodeURIComponent
		Set oHtmlDoc = CreateObject("htmlfile")
		'Инициализация движка JS
		oHtmlDoc.script.execScript ";"
	End Sub
	'Функция кодирование URI
	Private Function EncodeURI(Text)
		EncodeURI = Replace(oHtmlDoc.Script.encodeURIComponent(Text),"%20","+")
	End Function
	'Функция получения байт массива аудио записи в mp3
	Function TextToAudioStream(Text, Language)
		With CreateObject("WinHttp.WinHttpRequest.5.1")
			'Смена User-Agent, чтобы Google не отсекал запросы
			.Option(0) = "Api request"
			.Open "GET", "https://translate.google.com/translate_tts?ie=UTF-8&client=tw-ob&q=" + EncodeURI(Text) + "&tl=" & EncodeURI(Language), False
			.Send
			if .Status <> 200 Then Err.Raise vbObjectError + 1, TypeName(Me), "Failed to request google api ! Response status: " & .Status & " " & .StatusText
			'Возврат байт массива из функции
			TextToAudioStream = .ResponseBody
		End With
	End Function
End Class