Серый форум — AHK: Прокрутка на дробное число строк

Re: AHK: Прокрутка на дробное число строк

null@example.com (Malcev) — Wed, 03 Oct 2018 11:30:53 +0000

Почему же бесмысленной?
Вы считаете, что фаерфокс умножает на k ≈1.8±0.1, зависит от масштаба в лисе.
А у меня таких выводов нету.
Вот так у меня идет сдвиг на 4.8 линии при любом значении в реестре и масштаба в лисе.

n := 4.8

wheel_delta := 120
RegRead WheelScrollLines, HKCU\Control Panel\Desktop, WheelScrollLines
if !WheelScrollLines
   WheelScrollLines := 3
Line_Height := 120/WheelScrollLines
new_delta := Line_Height*n
f1::
f2::
if (A_ThisHotkey = "f1")
   i := -1
else
   i := 1
if (WheelScrollLines = 3) and (new_delta > wheel_delta)
   i*=2
PostMW(new_delta*i)



PostMW(delta)
{ ;http://msdn.microsoft.com/en-us/library/windows/desktop/ms645617(v=vs.85).aspx
  CoordMode, Mouse, Screen
  MouseGetPos, x, y
  Modifiers := 0x8*GetKeyState("ctrl") | 0x1*GetKeyState("lbutton") | 0x10*GetKeyState("mbutton")
              |0x2*GetKeyState("rbutton") | 0x4*GetKeyState("shift") | 0x20*GetKeyState("xbutton1")
              |0x40*GetKeyState("xbutton2")
  PostMessage, 0x20A, delta << 16 | Modifiers, y << 16 | x ,, A
}

Re: AHK: Прокрутка на дробное число строк

null@example.com (stealzy) — Wed, 03 Oct 2018 08:29:25 +0000

Вы написали код, пытающийся компенсировать их хак; у меня приблизительное описание самого хака со стороны браузера.
Кстати при изменении масштаба страницы работает? А при изменении дефолтных 3 строк прокрутки в винде?

Malcev пишет:

stealzy пишет:
PostMW(-120-72) ; так сдвинет на 4
Не на 4, а на 2.4.

Вполне допускаю что у вас замена двух PostMW(-120) и PostMW(-72) на PostMW(-120-72) и приводит к изменению прокрутки с 8 до 2.4 WheelDown.
У меня же - с 8 до 4 WheelDown.
Дальнейшую дискуссию по теме считаю бессмысленной.

Re: AHK: Прокрутка на дробное число строк

null@example.com (Malcev) — Wed, 03 Oct 2018 02:40:20 +0000

stealzy пишет:

Методом тыка, после обнаружения teadrinker'ом в 24 посте

Я у себя такое не наблюдаю, а вижу следующий алгоритм:

n := -727
wheel_delta := 120

f1::PostMW(n)
f2::
if (abs(n) <= wheel_delta)
   PostMW(n)
else
{
   count := floor(abs(n)/2/wheel_delta) + 1
   delta := abs(n)/n*wheel_delta
   loop % count
   {
      If (A_Index = count)
         delta := mod(n/2, wheel_delta)
      PostMW(delta)
   }
}


PostMW(delta)
{ ;http://msdn.microsoft.com/en-us/library/windows/desktop/ms645617(v=vs.85).aspx
  CoordMode, Mouse, Screen
  MouseGetPos, x, y
  Modifiers := 0x8*GetKeyState("ctrl") | 0x1*GetKeyState("lbutton") | 0x10*GetKeyState("mbutton")
              |0x2*GetKeyState("rbutton") | 0x4*GetKeyState("shift") | 0x20*GetKeyState("xbutton1")
              |0x40*GetKeyState("xbutton2")
  PostMessage, 0x20A, delta << 16 | Modifiers, y << 16 | x ,, A
}

stealzy пишет:

PostMW(-120-72) ; так сдвинет на 4

Не на 4, а на 2.4.

Re: AHK: Прокрутка на дробное число строк

null@example.com (stealzy) — Tue, 02 Oct 2018 20:47:20 +0000

Это псевдокод.
Методом тыка, после обнаружения teadrinker'ом в 24 посте.
Моя ошибка, я использовал строгое сравнение, заменить < на <=. Поправил.

   PostMW(-120-72) ; так сдвинет на 4

Re: AHK: Прокрутка на дробное число строк

null@example.com (Malcev) — Tue, 02 Oct 2018 18:54:25 +0000

stealzy пишет:

if (MOUSEEVENTF_WHEEL < 120 and WheelScrollLines = 3) MOUSEEVENTF_WHEEL := MOUSEEVENTF_WHEEL * k ; k ≈1.8±0.1

А откуда вы взяли эту формулу?
У меня этот код в фаерфоксе постоянно сдвигает ползунок на расстояние равное 8 посыланием wheeldown, при настройках шага в 3 линии.

f1::
loop 5
{
   PostMW(-120)
   PostMW(-72)
}
return


PostMW(delta)
{ ;http://msdn.microsoft.com/en-us/library/windows/desktop/ms645617(v=vs.85).aspx
  CoordMode, Mouse, Screen
  MouseGetPos, x, y
  Modifiers := 0x8*GetKeyState("ctrl") | 0x1*GetKeyState("lbutton") | 0x10*GetKeyState("mbutton")
              |0x2*GetKeyState("rbutton") | 0x4*GetKeyState("shift") | 0x20*GetKeyState("xbutton1")
              |0x40*GetKeyState("xbutton2")
  PostMessage, 0x20A, delta << 16 | Modifiers, y << 16 | x ,, A

Re: AHK: Прокрутка на дробное число строк

null@example.com (teadrinker) — Tue, 02 Oct 2018 18:10:47 +0000

Ну всё-таки не совсем предсказуемо.

Re: AHK: Прокрутка на дробное число строк

null@example.com (stealzy) — Tue, 02 Oct 2018 16:56:36 +0000

Gecko обрабатывает особым образом:

if (MOUSEEVENTF_WHEEL <= 120 and WheelScrollLines = 3)
	MOUSEEVENTF_WHEEL := MOUSEEVENTF_WHEEL * k ; k ≈1.8±0.1, зависит от масштаба в лисе

F1::Wheel(-3) ; равна прокрутке от {WheelDown} ≈ k*3 ≈ 6
F2::Wheel(-3.05) ; равна прокрутке от нажатия {Down} ≈ 3
F3::Wheel(-5.95) ;  равна прокрутке от {WheelDown} ≈ 6
F4::Send {WheelDown}

Wheel(lines) {
	RegRead WheelScrollLines, HKCU\Control Panel\Desktop, WheelScrollLines
	LINE_HEIGHT := 120/WheelScrollLines ; LINE_HEIGHT := 40 for Edit
	WHEEL_DELTA := lines*LINE_HEIGHT
	DllCall("mouse_event", uint, MOUSEEVENTF_WHEEL:=0x800, int, dx:=0 ,int, dy:=0, uint, WHEEL_DELTA, int, 0)
}

В Sublime F1 будет прокручивать на 3 строки при любых значениях WheelScrollLines.
В лисе формула будет как в коде выше, но не совсем точно.
В контролах Edit значение WheelScrollLines также обозначает минимальный квант прокрутки (по умолчанию 3), но там LINE_HEIGHT := 40 не зависит от значения записи в реестре.

Re: AHK: Прокрутка на дробное число строк

null@example.com (Malcev) — Tue, 02 Oct 2018 16:51:54 +0000

Больше 3 фаерфокс не обрабатывает.
Поэтому так можно:

f1::
MOUSEEVENTF_WHEEL := 0x800, LINE_HEIGHT := 40
WHEEL_DELTA := 3*LINE_HEIGHT, dx := 0, dy := 0, dir := -1
DllCall("mouse_event", uint, dwFlags := MOUSEEVENTF_WHEEL, int, dx ,int, dy, uint, dir*WHEEL_DELTA, int, 0)
sleep 10
WHEEL_DELTA := 1.8*LINE_HEIGHT, dx := 0, dy := 0, dir := -1
DllCall("mouse_event", uint, dwFlags := MOUSEEVENTF_WHEEL, int, dx ,int, dy, uint, dir*WHEEL_DELTA, int, 0)

Re: AHK: Прокрутка на дробное число строк

null@example.com (teadrinker) — Tue, 02 Oct 2018 16:05:56 +0000

Да, вот так у меня прокручивает страницу в FF ровно на такое же расстояние, как один поворот колеса. Но если сделать коэффициент 4.8, почему-то прокручивает на меньшее расстояние.

Re: AHK: Прокрутка на дробное число строк

null@example.com (Malcev) — Tue, 02 Oct 2018 15:26:28 +0000

Вот 120:

f1::
MOUSEEVENTF_WHEEL := 0x800, LINE_HEIGHT := 40
WHEEL_DELTA := 3*LINE_HEIGHT, dx := 0, dy := 0, dir := -1
DllCall("mouse_event", uint, dwFlags := MOUSEEVENTF_WHEEL, int, dx ,int, dy, uint, dir*WHEEL_DELTA, int, 0)

Re: AHK: Прокрутка на дробное число строк

null@example.com (teadrinker) — Tue, 02 Oct 2018 15:19:46 +0000

Malcev пишет:

Предсказуемо

Не-а. Запускаю MS Spy, выбираю WM_MOUSEWHEEL для окна FF. Дискретно прокручиваю колесо мыши, получаю zDelta: -120, запускаю код — получаю zDelta: -192. Всё математически правильно, но прокручивается на меньшее расстояние.

Re: AHK: Прокрутка на дробное число строк

null@example.com (Malcev) — Tue, 02 Oct 2018 14:54:41 +0000

Предсказуемо.
Тут подробно описано:
https://www.codeproject.com/Articles/15 … pplication

Re: AHK: Прокрутка на дробное число строк

null@example.com (teadrinker) — Tue, 02 Oct 2018 14:34:24 +0000

Пробовал PhpStorm — тоже только на кратное 3 поворачивает, плавная прокрутка есть. В общем, работает в каких-то приложениях, в некоторых — непредсказуемо.

Re: AHK: Прокрутка на дробное число строк

null@example.com (teadrinker) — Tue, 02 Oct 2018 14:20:03 +0000

А как вы в FF определили точное число строк?

Re: AHK: Прокрутка на дробное число строк

null@example.com (stealzy) — Tue, 02 Oct 2018 14:15:15 +0000

Да, я проверял, 4.8*40 = 4.8 строки, если совершить это действие 5 раз выйдет прокрутка ровно на 24 строки.
Но это sublime, а что в браузере...