Серый форум — AHK: Вырезание строки из файла

Re: AHK: Вырезание строки из файла

null@example.com (teadrinker) — Wed, 30 Jan 2019 23:03:44 +0000

serzh82saratov пишет:

Но сначала читаю `r`n как `n.

Если файл с `n, перезаписываешь с `r`n — некорректно.
Лучше так, без всяких фокусов:

countStrings := 3
text =
(
1 строка
2 строка
3 строка
4 строка
5 строка
)

Loop % countStrings {
   text := MoveStringsToEnd(text, 1, moved)
   MsgBox, Запустить: %moved%
}
MsgBox, % "Новый файл:`n`n" text
Return

MoveStringsToEnd(text, count, ByRef moved) {
   RegExMatch(text, "sO)((?:[^`n`r]+(\R)){" . count . "})(.*)", match)
   Return match[1] != "" ? match[3] . match[2] . (moved := RegExReplace(match[1], "\R$")) : text
}

Re: AHK: Вырезание строки из файла

null@example.com (serzh82saratov) — Wed, 30 Jan 2019 22:42:42 +0000

Так поймёте:

countStrings := 3
text =
(
1 строка
2 строка
3 строка
4 строка
5 строка
) 
newText := MoveStringsToEnd(text, countStrings, part)
Loop, Parse, part, `n
	MsgBox, % "Запустить: " A_LoopField
MsgBox, % "Новый файл:`n`n" newText
Return

MoveStringsToEnd(text, count, byref part, d := "`n") {
	p := InStr(text, d, 0, 1, count)
	Return p ? SubStr(text, p+1) d (part := SubStr(text, 1, p-1)) : text
}

teadrinker
Но сначала читаю `r`n как `n.

Re: AHK: Вырезание строки из файла

null@example.com (trezubec) — Wed, 30 Jan 2019 21:55:17 +0000

Так, спасибо вроде разобрался, но только не совсем подходит под мои задачи, нужно чтобы каждую строку по одной выдавал в MsgBox, а не все сразу. Сам файл перезаписывается как надо! Уже большое спасибо за это! Но повторюсь, тут дело в том, что каждая строка это exe по сути, и он будет запускаться с помощью Run, поэтому и нужно чтобы скрипт AHK сместил первые три строки например вниз, но в тоже время и запустил их 01.exe, 02.exe, 03.exe

Re: AHK: Вырезание строки из файла

null@example.com (teadrinker) — Wed, 30 Jan 2019 21:37:39 +0000

А, не обратил внимания. Так переписываешь файл с `n на `r`n.

Re: AHK: Вырезание строки из файла

null@example.com (serzh82saratov) — Wed, 30 Jan 2019 21:28:02 +0000

Думаешь FileOpen с "rw`n" не на все случаи?

Re: AHK: Вырезание строки из файла

null@example.com (teadrinker) — Wed, 30 Jan 2019 21:22:58 +0000

А откуда ты взял, что d = "`n"?

Re: AHK: Вырезание строки из файла

null@example.com (serzh82saratov) — Wed, 30 Jan 2019 21:11:41 +0000

trezubec


#SingleInstance Force
#NoEnv
#Persistent

FileName = %A_ScriptFullPath%
File := FileOpen(FileName, "rw`n")
File.Pos := 0
FileStr := File.Read()   
File.Length := 0
MsgBox % FileStr   
newText := MoveStringsToEnd(FileStr, 10)
MsgBox % newText 
File.Write(newText)
File.Close()
Return

MoveStringsToEnd(text, count, d := "`n") {
	p := InStr(text, d, 0, 1, count) 
	Return p ? SubStr(text, p+1) d SubStr(text, 1, p-1) : text
}

Re: AHK: Вырезание строки из файла

null@example.com (serzh82saratov) — Wed, 30 Jan 2019 21:02:49 +0000

RegEx наверное тоже не нужен.

countStrings := 4
text =
(
1 строка
2 строка
3 строка
4 строка
5 строка
) 
newText := MoveStringsToEnd(text, countStrings)
MsgBox, % newText
Return

MoveStringsToEnd(text, count, d := "`n") {
	p := InStr(text, d, 0, 1, count) 
	Return p ? SubStr(text, p+1) d SubStr(text, 1, p-1) : text
}

Re: AHK: Вырезание строки из файла

null@example.com (serzh82saratov) — Wed, 30 Jan 2019 20:57:01 +0000

teadrinker
countStrings := 1 пробовал.

Re: AHK: Вырезание строки из файла

null@example.com (trezubec) — Wed, 30 Jan 2019 20:54:53 +0000

teadrinker
Прошу прощения что я баран )) Но можно ли привести на моем примере с файлом, я не совсем понял куда я должен в скрипт вписать название файла )

Re: AHK: Вырезание строки из файла

null@example.com (teadrinker) — Wed, 30 Jan 2019 20:27:40 +0000

Для этого Loop вовсе не нужен.

countStrings := 3
text =
(
1 строка
2 строка
3 строка
4 строка
5 строка
)
newText := MoveStringsToEnd(text, countStrings)
MsgBox, % newText
Return

MoveStringsToEnd(text, count) {
   RegExMatch(text, "O)([^`n`r]+(\R|$)??){" . count . "}", match)
   Return match ? RegExReplace( SubStr(text, match.Len + StrLen(match[2]) + 1), "\R*$", match[2] . match[0],, 1 ) : text
}

AHK: Вырезание строки из файла

null@example.com (trezubec) — Wed, 30 Jan 2019 13:09:21 +0000

Уважаемые гуру, помогите пожалуйста с кодом.
Он наверное безобразный, т.к. я частями его собрал с разных тем форумов.

Вот что получилось

FILE = Список.txt

FileRead, out, %FILE%
loop, parse, out, `n, `r
{
	CNT_STROK:=a_index ; - запись в CNT_STROK количество строк
	If (A_LoopField != "")
		Num++
}
FileReadLine, line, %FILE%, 1

Loop, read, %FILE%, tempfile.txt
{
   IfNotInString, A_LoopReadLine, %line%, FileAppend, %A_LoopReadLine%`n
}

FileMove, tempfile.txt, %FILE%, 1
}

Список в файле это название профилей браузера, каждая из строк будет потом запускать браузер с нужным профилем, это я постараюсь сам реализовать.

К вам я за помощью по коду, если не затруднит, подскажите, как переделать код так, чтобы в цикле можно было указать количество строк для вырезания, например Loop, 3, т.е. три строки первые строки вырезаем и смещаем их в тот же файл, но в конец, и после каждого пройденного цикла, выдавал MsgBox с названием вырезанной строки..

Можно ли переделать данный код под эту задачу? Буду очень признателен за Вашу помощь!