Серый форум — AHK: Парсинг дерева

Re: AHK: Парсинг дерева

2019-02-25T11:21:31Z

Можно отдаться полемике и порассуждать на тему того, как это условие подталкивает к тому, что в такую структуру собирал криворукий программист, привнеся в свою БД некоторую произвольность. Что тут в пору переписать логику получения данных, иначе это грозит периодическими нестыковками, или излишними проверками для понимания того, верно ли код обращается за данными, или начальным перебором, чтобы получить "карту" БД и прочее...

Для "Яблоки,Груши,Ананас" семантически подходит быть значением в такой БД, находясь в доступе по какому-нибудь "Наименования", самому быть такой ёмкостью, или не существовать вообще. И хотя, "Хозяин - барин" и мне с таким "Хозяином" "детей не растить", перфекционист во мне протестует и это скорее "крик души".

Re: AHK: Парсинг дерева

2019-02-25T00:46:15Z

KusochekDobra пишет:

то можно так

А как тут получить строку "Яблоки,Груши,Ананас"?

Re: AHK: Парсинг дерева

2019-02-24T23:56:08Z

Если заранее известно, какую глубину считать конечной для получения значений залегающих на её уровне, то можно так:


data =
(
База 1
	склад 1
		Яблоки,Груши,Ананас
		Настройки
			Размер
			Кол-во контейнеров
		Яблоки
			И тут разновидности
			в 100+ строк
		Груши
			и пошло, поехало
		Ананас
			к сожалению один, привоза не было
База 2
	склад2 
		Сливы,Киви,Апельсины
		Настройки
			Размер
			Кол-во контейнеров
)

obj := Separator_Razdelyator( StrSplit(data, "`n"), 3 )
MsgBox % obj["База 1", "склад 1", "Яблоки", 2]

ExitApp
Separator_Razdelyator(data, depth := 2) {
	obj := {}
	For i, item in data {
		item := StrReplace(item, "`t", "", level)
		if (!level) {
			obj[item] := {}
			itemLevel_1 := obj[item]
		} else if (level == depth) {
			itemLevel_%depth%.Push( item )
		} else {
			itemLevel_%level%[item] := level + 1 == depth ? [] : {}
			levelPlus := level + 1
			itemLevel_%levelPlus% := itemLevel_%level%[item]
		}
	} Return obj
}

Но если значения ожидать на разных уровнях, то тогда нужно рассчитывать маску.

Re: AHK: Парсинг дерева

2019-02-24T21:53:37Z

В общем, наверно идеального варианта нет, к каждому случаю какой-то свой лучше.

Re: AHK: Парсинг дерева

2019-02-24T21:41:34Z

Ок, тогда так можно, чтобы сохранить структуру:

data =
(
склад 1
	Яблоки,Груши,Ананас
	Настройки
		Размер
		Кол-во контейнеров
	Яблоки
		И тут разновидности
		в 100+ строк
	Груши
		и пошло, поехало
	Ананас
		к сожалению один, привоза не было
склад2 
	Сливы,Киви,Апельсины
	Настройки
		Размер
		Кол-во контейнеров
)

obj := {}
child0 := obj
Loop, parse, data, `n, `r
{
   RegExMatch(A_LoopField, "^(?`t*)(?.*)", _)
   StrReplace( _indent, A_Tab, "", level)
   prevLevel := level, level += 1
   if (A_Index > 1) {
      if !(level > prev_level)
         child%prev_prevLevel%.Push(prev_text)
      else {
         o := {}, o[prev_text] := child%prev_level% := []
         child%prev_prevLevel%.Push(o)
      }
   }
   prev_level := level, prev_prevLevel := prevLevel, prev_text := _text
}
child%prev_prevLevel%.Push(_text)

На картинке массивы от 0, в реальности от 1.
Все родственные объекты на одном уровне, вне зависимости от того, строки это, или массивы.

Re: AHK: Парсинг дерева

2019-02-24T21:37:02Z

Только пример, хоть и не правильный.

Re: AHK: Парсинг дерева

2019-02-24T21:11:11Z

Ну, я бы сказал, что здесь семантически неправильно составлен список, в одну кучу свалены перечисления и заголовки групп объектов. Правильнее было бы так:

склад 1
	Список фруктов
		Яблоки,Груши,Ананас
	Настройки
		Размер
		Кол-во контейнеров
	Яблоки
		И тут разновидности
		в 100+ строк
	Груши
		и пошло, поехало
	Ананас
		к сожалению один, привоза не было

	Какой-нибудь объект, содержащий другую необходимую информацию о складе
		что-то внутри
	Размер
		500кв км.
	Кол-во контейнеров
		...
склад2 
	и.т.д

Re: AHK: Парсинг дерева

2019-02-24T20:56:05Z

Опять же, была задача написать парсер, который бы выполнял свою работу без нареканий. А то, что в нашем случае "Актюбинская область" представляется в виде значения - это уже другой вопрос. Давайте приведу еще один пример.
Допустим, список фруктов на складах.

склад 1
	Яблоки,Груши,Ананас
	Настройки
		Размер
		Кол-во контейнеров
	Яблоки
		И тут разновидности
		в 100+ строк
	Груши
		и пошло, поехало
	Ананас
		к сожалению один, привоза не было

	Какой-нибудь объект, содержащий другую необходимую информацию о складе
		что-то внутри
	Размер
		500кв км.
	Кол-во контейнеров
		...
склад2 
	и.т.д

Что у нас здесь? А здесь у нас в объекте сами склады с порядковым номером. И в каждом из них в ячейке 1 будет находится список фруктов.
С вашим бы скриптом, вместо ячейки 1 был бы пустой объект с названием "Яблоки,Груши,Ананас". И как бы я узнал, что здесь фрукт, а что не фрукт?

Re: AHK: Парсинг дерева

2019-02-24T20:20:46Z

MandarinKa02 пишет:

отредактировал код в посте 36.

Теперь работает. В чём я тут вижу проблему:

"Акмолинская область" и "Актюбинская область" по идее родственные объекты, а представлены по-разному, да и порядок нарушен.

MandarinKa02 пишет:

Не понял, что вы имеете ввиду?

Ну, например было

МИР
	Казахстан
		Акмолинская область
			Акколь
			Степногорск
			Степняк
			Щучинск
		Актюбинская область
		Алматинская область
			Есик
			Жаркент
			Алматы
	РФ
		Ленинградская область
			Павловск
			Гатчина

а потом в этот файл будут добавлены новые строки:

МИР
	Казахстан
		Акмолинская область
			Акколь
			Степногорск
			Степняк
			Щучинск
		Актюбинская область
			Актобе
			Хромтау
			Шалкар
			Эмба
		Алматинская область
			Есик
			Жаркент
			Алматы
	РФ
		Ленинградская область
			Павловск
			Гатчина

Так вот в моём предыдущем варианте путь к "Актюбинская область" в старом и новом тексте будет одинаков, а в вашем нет.

Re: AHK: Парсинг дерева

2019-02-24T20:02:14Z

teadrinker, отредактировал код в посте 36.
Вам вариант ничем не плох, не подходит под мои нужды.

teadrinker пишет:

возможного расширения исходного текста хорош

Не понял, что вы имеете ввиду?

Re: AHK: Парсинг дерева

2019-02-24T19:53:29Z

MandarinKa02 пишет:

Да и возможно, это бы ухудшило производительность.

А чем плох мой предыдущий вариант, где все строки — объекты? Он и в плане возможного расширения исходного текста хорош.

Re: AHK: Парсинг дерева

2019-02-24T19:51:02Z

MandarinKa02 пишет:

teadrinker, поправил.

Не работает:

data =
(
МИР
	Казахстан
		Акмолинская область
			Акколь
			Степногорск
			Степняк
			Щучинск
		Актюбинская область
		Алматинская область
			Есик
			Жаркент
			Алматы
	РФ
		Ленинградская область
			Павловск
			Гатчина
)

obj := NEI.Parse(data)
MsgBox, % obj["МИР", "Казахстан", "Алматинская область", 3]

class NEI {
	Parse(input) {

		obj:=[]
		curObj:=obj,objStack:=[],objStack.Push(curObj)

		curTab:=prevLine:=prevTab:=-1
		Loop, Parse, input, `n, `r
		{
			if(!RegExMatch(A_LoopField, "^(?`t*)(?.*)", _) || !_line || RegExMatch(_line,"^(\s{0,})\/\/")) ;empty line or "//" 
				Continue
			StrReplace(_tab, A_Tab, "", tab)
			if(curTab=-1) {
				curTab:=0,prevLine:=_line
				if(prevTab:=tab) ;line starts with TAB and has't obj-parent
					return -1
				Continue
			} if(tab-curTab<0) { ;prev level
				;msgbox % prevLine "`n" _line "`n" prevTab "`n" tab "`n" curTab
				;curObj.Push(prevLine)
				loop % Abs(tab-prevTab)
					objStack.Pop() ;remove last object
				;curTab:=prevTab
				curObj:=objStack[objStack.MaxIndex()]
			}

			if(tab=prevTab) ;curr level
				curObj.Push(prevLine)
			else if(tab>prevTab) ;new level
				curObj[prevLine]:=[]
				,curObj:=curObj[prevLine]
				,objStack.Push(curObj)
				,curTab:=prevTab+1
			else if(prevTab-tab>1)
				curObj[_line]:=[],curObj:=curObj[_line],objStack.Push(curObj)
			prevLine:=_line,prevTab:=tab
		} curObj.Push(prevLine)
		return obj
	}
	Dump(obj,tab=0) {
		if(!isObject(obj))
			return -1
		out:=""
		for i,v in obj {
			if(isObject(v))
				out.=this._mult_tab(tab) i "`n" this.Dump(v,tab+1)
			out.=this._mult_tab(tab) v (A_Index=obj.MaxIndex()?"":"`n")
		} return out
	}
	_mult_tab(i) {
		out:=""
		loop % i
			out.=A_Tab
		return out
	}
}

Re: AHK: Парсинг дерева

2019-02-24T19:50:39Z

teadrinker пишет:

Можно, но может путаница получиться. Придётся как-то отличать ключ со ссылкой от остальных ключей.

Был вариант каждому объекту(т.е. экземпляру класса) задавать переменную parent(экземпляр класса родителя) и data(тот самый объект в котором содержаться спарсенные данные) и уже с этим как-то пробовать. Но не в этот раз. Да и возможно, это бы ухудшило производительность.

teadrinker пишет:

alekserus258, идите в задницу.

А что, так можно было?

Re: AHK: Парсинг дерева

2019-02-24T19:43:10Z

teadrinker, поправил.

+ открыть спойлер


class NEI {
	Parse(input) {

		obj:=[]
		curObj:=obj,objStack:=[],objStack.Push(curObj)

		curTab:=prevLine:=prevTab:=-1
		Loop, Parse, input, `n, `r
		{
			if(!RegExMatch(A_LoopField, "^(?`t*)(?.*)", _) || !_line || RegExMatch(_line,"^(\s{0,})\/\/")) ;empty line or "//" 
				Continue
			StrReplace(_tab, A_Tab, "", tab)
			if(curTab=-1) {
				curTab:=0,prevLine:=_line
				if(prevTab:=tab) ;line starts with TAB and has't obj-parent
					return -1
				Continue
			} if(tab-curTab<0) { ;prev level
				curObj.Push(prevLine)
				loop % Abs(tab-prevTab)
					objStack.Pop() ;remove last object
				curObj:=objStack[objStack.MaxIndex()]
			}

			if(tab=prevTab && tab-curTab>=0) ;curr level && already added in line 20
				curObj.Push(prevLine)
			else if(tab>prevTab) ;new level
				curObj[prevLine]:=[]
				,curObj:=curObj[prevLine]
				,objStack.Push(curObj)
				,curTab:=prevTab+1
			else if(prevTab-tab>1)
				curObj[_line]:=[],curObj:=curObj[_line],objStack.Push(curObj)
			prevLine:=_line,prevTab:=tab
		} curObj.Push(prevLine)
		return obj
	}
	Dump(obj,tab=0) {
		if(!isObject(obj))
			return -1
		out:=""
		for i,v in obj {
			if(isObject(v))
				out.=this._mult_tab(tab) i "`n" this.Dump(v,tab+1)
			out.=this._mult_tab(tab) v (A_Index=obj.MaxIndex()?"":"`n")
		} return out
	}
	_mult_tab(i) {
		out:=""
		loop % i
			out.=A_Tab
		return out
	}
}

teadrinker пишет:

всё, у чего есть вложенные строки, должно быть ключами, а всё, у чего нет, значениями

Именно.

Re: AHK: Парсинг дерева

2019-02-24T19:42:43Z

Можно, но может путаница получиться. Придётся как-то отличать ключ со ссылкой от остальных ключей.