Серый форум — AKH: Сортировка массива.

Re: AKH: Сортировка массива.

null@example.com (teadrinker) — Thu, 28 Mar 2019 20:56:17 +0000

Ну вот, оказывается всё не так уж сложно.

Re: AKH: Сортировка массива.

null@example.com (Phoenixxx_Czar) — Thu, 28 Mar 2019 20:50:21 +0000

Что-то типа этого вышло в итоге:

sortArray(array, key := "", desc := 1, string := 0)
{
	str := "", d1 := Chr(1), d2 := Chr(2)
	for k, v in array
		str .= (str = "" ? "" : d1) . (key ? v[key] : v) . d2 . k

	Sort, str, % (desc ? "R" : "") (string ? "" : "N") "D" . d1
	newArr := []
	Loop, parse, str, % d1
		newArr.Push(array[ RegExReplace(A_LoopField, ".+" . d2) ])
	return newArr
}

Re: AKH: Сортировка массива.

null@example.com (Phoenixxx_Czar) — Thu, 28 Mar 2019 20:42:10 +0000

Не думал что он подойдет, то есть просто заменить "v[key]" на "v" и дело в шляпе?

Re: AKH: Сортировка массива.

null@example.com (teadrinker) — Thu, 28 Mar 2019 17:27:12 +0000

Так а в чём трудность прменить тот же принцип для более простого случая?

Re: AKH: Сортировка массива.

null@example.com (Phoenixxx_Czar) — Thu, 28 Mar 2019 14:59:02 +0000

А что насчет простого массива?

array := [13, 4, 1, 58, 25]

Я находил код, но он слишком громоздкий и изменял основной массив (что-то по типу byRef).

SortArray(Array, Order := "A")
{
	;Order A: Ascending, D: Descending, R: Reverse
	MaxIndex := ObjMaxIndex(Array)
	If (Order == "R")
	{
		count := 0
		Loop, % MaxIndex
			ObjInsert(Array, ObjRemove(Array, MaxIndex - count++))
		Return
	}
	Partitions := "|" ObjMinIndex(Array) "," MaxIndex
	Loop
	{
		comma := InStr(this_partition := SubStr(Partitions, InStr(Partitions, "|", False, 0)+1), ",")
		spos := pivot := SubStr(this_partition, 1, comma-1) , epos := SubStr(this_partition, comma+1)
		if (Order == "A")
		{
			Loop, % epos - spos
			{
				if (Array[pivot] > Array[A_Index+spos])
					ObjInsert(Array, pivot++, ObjRemove(Array, A_Index+spos))
			}
		}
		else
		{
			Loop, % epos - spos
			{
				if (Array[pivot] < Array[A_Index+spos])
					ObjInsert(Array, pivot++, ObjRemove(Array, A_Index+spos))
			}
		}
		Partitions := SubStr(Partitions, 1, InStr(Partitions, "|", False, 0)-1)
		if (pivot - spos) > 1    ;if more than one elements
			Partitions .= "|" spos "," pivot-1        ;the left partition
		if (epos - pivot) > 1    ;if more than one elements
			Partitions .= "|" pivot+1 "," epos        ;the right partition
	}
	Until !Partitions
}

Re: AKH: Сортировка массива.

null@example.com (teadrinker) — Fri, 22 Mar 2019 21:44:47 +0000

Вот так корректнее:

arr := [ {id: 43, isAFK: 1, nick: "Thiago_Montesdeoca", rankNum:  2}
       , {id: 40, isAFK: 0, nick: "kukumba"           , rankNum: 10}
       , {id:  5, isAFK: 1, nick: "blackboss"         , rankNum:  3} ]
key := "rankNum"

str := "", d1 := Chr(1), d2 := Chr(2)
for k, v in arr
   str .= (str = "" ? "" : d1) . v[key] . d2 . k

Sort, str, % "D" . d1
newArr := []
Loop, parse, str, % d1
   newArr.Push(arr[ RegExReplace(A_LoopField, ".+" . d2) ])

for k, v in newArr
   MsgBox, % v.nick

Re: AKH: Сортировка массива.

null@example.com (teadrinker) — Fri, 22 Mar 2019 16:49:48 +0000

Здесь.

Re: AKH: Сортировка массива.

null@example.com (Phoenixxx_Czar) — Fri, 22 Mar 2019 16:46:29 +0000

Где можно прочитать про точку? Не раз замечал ее присутствие, но думал это проделки PHP .

Re: AKH: Сортировка массива.

null@example.com (teadrinker) — Fri, 22 Mar 2019 16:45:22 +0000

Sort, str, % "RD" . d

После точки пробел нужен. Или по-другому:

Sort, str, RD%d%

Re: AKH: Сортировка массива.

null@example.com (Phoenixxx_Czar) — Fri, 22 Mar 2019 16:37:37 +0000

Что-то не получается у меня добавить "R", как и куда правильно ее добавить?
Пробовал и с пробелом и без, не дало результатов.

Sort, str, % "D" .d "R"
Sort, str, % "D" .d " R"
Sort, str, % "RD" .d
Sort, str, % "R D" .d

Re: AKH: Сортировка массива.

null@example.com (teadrinker) — Fri, 22 Mar 2019 16:23:47 +0000

Так смотрите хелп по Sort, там всё есть.

Re: AKH: Сортировка массива.

null@example.com (Phoenixxx_Czar) — Fri, 22 Mar 2019 16:15:33 +0000

teadrinker, а можно как-то обратную сортировку? (DESC)

Re: AKH: Сортировка массива.

null@example.com (Malcev) — Fri, 22 Mar 2019 15:35:58 +0000

Phoenixxx_Czar пишет:

Можно какой-то пример?

Готового примера нет, а писать лень.

Re: AKH: Сортировка массива.

null@example.com (teadrinker) — Fri, 22 Mar 2019 15:35:56 +0000

Я так и не понял, зачем нужно было в JSON переводить.

arr := [ {id: 43, isAFK: 1, nick: "Thiago_Montesdeoca", rankNum:  2}
       , {id: 40, isAFK: 0, nick: "kukumba"           , rankNum: 10}
       , {id:  5, isAFK: 1, nick: "blackboss"         , rankNum:  3} ]
key := "rankNum"

str := "", d := Chr(1)
for k, v in arr
   str .= (str = "" ? "" : d) . v[key] . "~" . k

Sort, str, % "D" . d
newArr := []
Loop, parse, str, % d
   newArr.Push(arr[ RegExReplace(A_LoopField, ".+~") ])

for k, v in newArr
   MsgBox, % v.nick

Это строчная сортировка. Для числовой добавьте N к опциям Sort.

Re: AKH: Сортировка массива.

null@example.com (Phoenixxx_Czar) — Fri, 22 Mar 2019 15:14:15 +0000

AHK массива.