Серый форум — AHK: Деление строки по словами

Re: AHK: Деление строки по словами

null@example.com (Phoenixxx_Czar) — Tue, 26 Mar 2019 22:31:19 +0000

Это действительно круто получилось! Спасибо.

Re: AHK: Деление строки по словами

null@example.com (teadrinker) — Tue, 26 Mar 2019 21:47:00 +0000

str := "Lorem ipsum dolor sit amet consectetur, adipisicing elit. Quaerat placeat consequatur itaque quia explicabo magnam molestias! Rerum mollitia dolores suscipit. Alias cupiditate nesciunt doloribus, eaque sint quaerat sed, ullam unde non architecto soluta exercitationem. Aperiam facere, dolorum molestias ipsum illo expedita earum cupiditate, alias exercitationem quas iure recusandae nobis quidem!"
for k, v in splitStringLimit(str, 80)
   msgbox, % v

splitStringLimit(text, limit)
{
   out := []
   while RegExMatch(text, "xO)(?<=\s|^) ( ([^`r`n]){1," . limit . "} | (?2)+? ) (\s|$)", match, match ? match.Pos + match.Len : 1)
      out.Push(match[1])
   Return out
}

Re: AHK: Деление строки по словами

null@example.com (belyankin12) — Tue, 26 Mar 2019 20:14:37 +0000

Когда у меня была задача вывести на экран пользователя все команды которые доступны для его ввода (командный процессор с СМма) я сделал вот так:


for k in CMD.List {
	if (A_Index = 1) {
		str .=  k 
	} else {
		str .= ", " k ""
	}
}
		
sarr := StrSplit(str, ", ")
for k, v in sarr {
	if (A_Index = 1) {
		st .= "Доступные команды: " v ""
		continue
	}
	
	if (Strsplit(st).MaxIndex() + Strsplit(v).MaxIndex() <= 120) {
		st .= ", " v ""
	} else {
		addmessagetochatwindow2("{ff0000}", "[AHK]: {FFFAFA}" . st . "")
		st := ""
		st .= v
	}
}
addmessagetochatwindow2("{ff0000}", "[AHK]: {FFFAFA}" . st . ".")

Тоже давненько делал но выглядит вроде бы привлекательнее. Если добавить тернарных операторов, а каждый addmessagetochatwindow2 заменить на создание исходного массива то думаю будет нормально.

Re: AHK: Деление строки по словами

null@example.com (Phoenixxx_Czar) — Tue, 26 Mar 2019 19:38:41 +0000

str := "Lorem ipsum dolor sit amet consectetur, adipisicing elit. Quaerat placeat consequatur itaque quia explicabo magnam molestias! Rerum mollitia dolores suscipit. Alias cupiditate nesciunt doloribus, eaque sint quaerat sed, ullam unde non architecto soluta exercitationem. Aperiam facere, dolorum molestias ipsum illo expedita earum cupiditate, alias exercitationem quas iure recusandae nobis quidem!"
for k, v in splitStringLimit(str, 80)
	msgbox, % v

Re: AHK: Деление строки по словами

null@example.com (Phoenixxx_Czar) — Tue, 26 Mar 2019 19:33:55 +0000

Есть предложение/строка, допустим она длинной 350 символов, а нам нужно разделить эту большую строку по 80 символов. Данная функция именно для этого. (Она не обрезает слова, именно для этого там сплит строки по пробелам.)

Re: AHK: Деление строки по словами

null@example.com (teadrinker) — Tue, 26 Mar 2019 19:08:39 +0000

Я не понял, что делает limit:

obj := splitStringLimit("C:\Program Files\AutoHotkey\AutoHotkey.exe /ErrorStdOut D:\OneDrive\Scripts\_Разработка\New7.ahk", 1)
for k, v in obj
   MsgBox, % v

splitStringLimit(text, limit)
{
   out := []
   index := 1

   if text Contains % "``n"
   {
      for k, v in StrSplit(text, "``n")
      {
         for key, value in splitStringLimit(v, limit)
            out[index] := value, index++
      }
      return out
   }

   for k, v in StrSplit(text, A_Space)
   {
      if (A_Index == 1)
         out[index] := v
      Else
      {
         if (StrLen(out[index] " " v) <= limit)
            out[index] .= " " v
         Else
            index++, out[index] := v
      }
   }
   return out
}

AHK: Деление строки по словами

null@example.com (Phoenixxx_Czar) — Tue, 26 Mar 2019 18:36:13 +0000

Давненько делал себе функцию, которая делит строку по словам. Хотелось бы ее как-то оптимизировать чтоль.

splitStringLimit(text, limit)
{
	out := []
	index := 1

	if text Contains % "``n"
	{
		for k, v in StrSplit(text, "``n")
		{
			for key, value in splitStringLimit(v, limit)
				out[index] := value, index++
		}
		return out
	}

	for k, v in StrSplit(text, A_Space)
	{
		if (A_Index == 1)
			out[index] := v
		Else
		{
			if (StrLen(out[index] " " v) <= limit)
				out[index] .= " " v
			Else
				index++, out[index] := v
		}
	}
	return out
}