Option Explicit

Dim objFSO

Dim objVideo
Dim objAudio

Dim strVideoFile
Dim strAudioFile

Dim objWshShell
Dim objRegExp

Dim dtNow
Dim strResultName


If WScript.Arguments.Count = 2 Then
	With WScript.CreateObject("Scripting.FileSystemObject")
		Set objVideo = WScript.CreateObject("Scripting.Dictionary")
		Set objAudio = WScript.CreateObject("Scripting.Dictionary")
		
		With objVideo
			.CompareMode = vbTextCompare
			
			.Add "mov", "mov"
			.Add "mp4", "mp4"
			.Add "mts", "mts"
		End With
		
		With objAudio
			.CompareMode = vbTextCompare
			
			.Add "mp3", "mp3"
			.Add "wav", "wav"
			.Add "aac", "aac"
		End With
		
		If objVideo.Exists(.GetExtensionName(WScript.Arguments.Item(0))) And _
			objAudio.Exists(.GetExtensionName(WScript.Arguments.Item(1))) Or _
			objVideo.Exists(.GetExtensionName(WScript.Arguments.Item(1))) And _
			objAudio.Exists(.GetExtensionName(WScript.Arguments.Item(0))) Then
			
			If objVideo.Exists(.GetExtensionName(WScript.Arguments.Item(0))) Then
				strVideoFile = .GetAbsolutePathName(WScript.Arguments.Item(0))
				strAudioFile = .GetAbsolutePathName(WScript.Arguments.Item(1))
			Else
				strVideoFile = .GetAbsolutePathName(WScript.Arguments.Item(1))
				strAudioFile = .GetAbsolutePathName(WScript.Arguments.Item(0))
			End If
			
			If .FileExists(strVideoFile) Then
				If .FileExists(strAudioFile) Then
					If StrComp(.GetParentFolderName(strVideoFile), .GetParentFolderName(strAudioFile), vbTextCompare) = 0 Then
						Set objWshShell = WScript.CreateObject("WScript.Shell")
						objWshShell.CurrentDirectory = .GetParentFolderName(strVideoFile)
						
						Set objRegExp = WScript.CreateObject("VBScript.RegExp")
						objRegExp.Pattern = "^(.+_)\d{8}_\d{6}$"
						
						If objRegExp.Test(.GetBaseName(strVideoFile)) Then
							strResultName = objRegExp.Replace(.GetBaseName(strVideoFile), "$1" & FormatOwnDateTime(Now())) & ".mp4"
						Else
							strResultName = .GetBaseName(strVideoFile) & "_" & FormatOwnDateTime(Now()) & ".mp4"
						End If
						
						Set objRegExp = Nothing
						
						objWshShell.Run """ffmpeg.exe"" -i """ & strVideoFile & """ -i """ & strAudioFile & """ -c:v copy -map 0:v:0 -map 1:a:0 -shortest """ & strResultName & """", 1, True
						Set objWshShell = Nothing
					Else
						WScript.Echo "Need appear source video file [" & strVideoFile & "] near source audio file [" & strAudioFile & "]."
						WScript.Quit 5
					End If
				Else
					WScript.Echo "Can't find source audio file [" & strAudioFile & "]."
					WScript.Quit 4
				End If
			Else
				WScript.Echo "Can't find source video file [" & strVideoFile & "]."
				WScript.Quit 3
			End If
		Else
			WScript.Echo "Need one source video file (" & Join(objVideo.Keys) & ") and one source audio file (" & Join(objAudio.Keys) & ")."
			WScript.Quit 2
		End If
		
		objAudio.RemoveAll
		objVideo.RemoveAll
		
		Set objAudio = Nothing
		Set objVideo = Nothing
	End With
Else
	WScript.Echo "Usage: cscript.exe //nologo """ & WScript.ScriptName & """ <Source video file> <Source audio file>"
	WScript.Quit 1
End If

WScript.Quit 0
'=============================================================================

'=============================================================================
Function StrZeroPad(intValue, intCount)
	StrZeroPad = Right(String(intCount, "0") & CStr(intValue), intCount)
End Function
'=============================================================================

'=============================================================================
Function FormatOwnDateTime(dtNow)
	FormatOwnDateTime = _
		StrZeroPad(Year(  dtNow), 4) & _
		StrZeroPad(Month( dtNow), 2) & _
		StrZeroPad(Day(   dtNow), 2) & _
		"_" & _
		StrZeroPad(Hour(  dtNow), 2) & _
		StrZeroPad(Minute(dtNow), 2) & _
		StrZeroPad(Second(dtNow), 2)
End Function
'=============================================================================