Серый форум — AHK: GUI_Shell.Explorer

Re: AHK: GUI_Shell.Explorer

null@example.com (inseption86) — Sat, 04 Apr 2020 14:54:45 +0000

teadrinker

Спасибо!!

WB.document.getElementsByClassName("r-covid-19__date js-covid-date")[0].hidden := 1

Re: AHK: GUI_Shell.Explorer

null@example.com (teadrinker) — Sat, 04 Apr 2020 14:32:04 +0000

У меня и так белый. Вот так у меня выглядит более похоже на то, что на сайте:

URL := "https://www.rbc.ru/society/03/04/2020/5e2fe9459a79479d102bada6"

Gui,Add, ActiveX, w750 h450 vWB, about:
ComObjConnect(WB, new wbEvent)
WB.silent := true
WB.Navigate(URL)
return

GuiClose:
WB := ""
ExitApp 

class wbEvent
{
   __Call(Name, Params*) {
      static processed
      WB := Params.Pop()
      if node := WB.document.querySelector(".r-covid-19") {
         ComObjConnect(WB)
         ; WB.Stop()
         if !processed {
            processed := true
            coll := WB.document.body.children
            Loop % coll.length {
               elem := coll[A_Index - 1]
               elem.style.visibility := "hidden"
            }
            WB.document.body.style.background := "white"
            style := node.style
            style.position := "fixed"
            style.left := style.top := 0
            style.width := "750px"
            style.height := "450px"
            style.visibility := "visible"
            style.background := "url(https://s.rbk.ru/files_static/edd/2020/covid-19/15/images/bg_2x.png) no-repeat top right"
            style.backgroundSize := "240px 240px"
            Gui, Show
         }
      }         
   }
}

inseption86 пишет:

убрать дату и время

Это вам задача для самостоятельного изучения.

Re: AHK: GUI_Shell.Explorer

null@example.com (inseption86) — Fri, 03 Apr 2020 18:34:03 +0000

А как фон на белый, как на сайте? и убрать дату и время

Re: AHK: GUI_Shell.Explorer

null@example.com (teadrinker) — Fri, 03 Apr 2020 16:12:23 +0000

Лучше так, по-моему, без WB.Stop()

URL := "https://www.rbc.ru/society/03/04/2020/5e2fe9459a79479d102bada6"

Gui,Add, ActiveX, w600 h500 vWB, about:
ComObjConnect(WB, new wbEvent)
WB.silent := true
WB.Navigate(URL)
return

GuiClose:
WB := ""
ExitApp 

class wbEvent
{
   __Call(Name, Params*) {
      static processed
      WB := Params.Pop()
      if node := WB.document.querySelector(".r-covid-19") {
         ComObjConnect(WB)
         if !processed {
            processed := true
            coll := WB.document.body.children
            Loop % coll.length {
               elem := coll[A_Index - 1]
               elem.style.visibility := "hidden"
            }
            style := node.style
            style.position := "fixed"
            style.left := style.top := 0
            style.width := "600px"
            style.height := "500px"
            style.visibility := "visible"
            Gui, Show
         }
      }         
   }
}

Re: AHK: GUI_Shell.Explorer

null@example.com (inseption86) — Fri, 03 Apr 2020 15:33:04 +0000

teadrinker

Ооо, спасибо!

Re: AHK: GUI_Shell.Explorer

null@example.com (teadrinker) — Fri, 03 Apr 2020 15:21:21 +0000

Примерно так:

URL := "https://www.rbc.ru/society/03/04/2020/5e2fe9459a79479d102bada6"

Gui,Add, ActiveX, w600 h500 vWB, about:
ComObjConnect(WB, new wbEvent)
WB.silent := true
WB.Navigate(URL)
return

GuiClose:
WB := ""
ExitApp 

class wbEvent
{
   __Call(Name, Params*) {
      static cloned
      WB := Params[Params.MaxIndex()]
      if node := WB.document.querySelector(".r-covid-19") {
         WB.Stop()
         ComObjConnect(WB)
         if !cloned {
            cloned := true
            coll := WB.document.body.children
            Loop % coll.length {
               elem := coll[A_Index - 1]
               elem.style.visibility := "hidden"
            }
            style := node.style
            style.position := "fixed"
            style.left := style.top := 0
            style.width := "600px"
            style.height := "500px"
            style.visibility := "visible"
            Gui, Show
         }
      }         
   }
}

У меня, правда, этот сайт иногда просто не загружается в ActiveX.

AHK: GUI_Shell.Explorer

null@example.com (inseption86) — Fri, 03 Apr 2020 13:06:16 +0000

Добрый день! Подскажите, пож-та, как отобразить в GUI только определённый ( document.getElementsByClassName("r-covid-19 js-covid inited")[0] ) элемент?


#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
#SingleInstance force
#Persistent

URL := "https://www.rbc.ru/society/03/04/2020/5e2fe9459a79479d102bada6"

Gui,Add, ActiveX, w1080 h840 vWB, Shell.Explorer
Gui, Show

WB.Navigate(URL)

while (wb.busy || wb.readyState <> 4)
     sleep 500

return

GuiClose:
WB := ""
ExitApp