Серый форум — AHK: Правка распознанного теста в LibreOffice Writer

Re: AHK: Правка распознанного теста в LibreOffice Writer

null@example.com (DD) — Thu, 09 Apr 2020 08:57:15 +0000

Юзабельно получается) С обработкой областей и кареткой пока застрял, далеко не банально.

SetBatchLines, -1
#SingleInstance Force

pic_name_width := "4" 		; ширина счётчика в названиях изображений: 0001.jpg, 0002.jpg...
WidthOrNot := "1" 		; 0 — если названия изображений не имеют ширины: 1.jpg, 2.jpg...
pic_ext := "tif" 		; расширение изображений страниц
pic_pth := "E:\SCANz\"		; папка с изображениями страниц

oSM := ComObjCreate("com.sun.star.ServiceManager")

Gui, 2:-Caption +AlwaysOnTop +Resize +HWNDhWin  ;+Lastfound 
Gui, 2:Margin, 0, 0
Gui, 2:Add, Pic, h700 w600 vGuiPic, %pic_pth%%page%.%pic_ext%     ; x96 y20
Gui, 2:Font, s10 norm
OnMessage(0x201, "WM_LBUTTONDOWN")
OnMessage(0x204, "WM_RBUTTONDOWN")

loop
{
sleep 1

global pic_ext
global pic_pth
global WidthOrNot
global pic_name_width

If WinActive("ahk_exe soffice.bin")
{
   oDesk := oSM.createInstance("com.sun.star.frame.Desktop")

   page := oDesk.CurrentComponent.CurrentController.ViewCursor.getPage
   If WidthOrNot
      page := Format("{:0" . pic_name_width . "u}", page)

   if (oldpage != page) {
      oldpage := page
      oDesk.CurrentComponent.CurrentController.ViewSettings.ZoomType := 2
      Gui, 2:Show, NA
      GuiControl, 2:, GuiPic, %pic_pth%%page%.%pic_ext%
   }
}
else
   sleep 1000
}
return

WM_LBUTTONDOWN()
{
 WM_NCLBUTTONDOWN := 0xA1, HTCAPTION := 2
 PostMessage, WM_NCLBUTTONDOWN, HTCAPTION
}

WM_RBUTTONDOWN()
{
   Menu, Tray, NoStandard
   Menu, Tray, Add, Выход, ExitApp
   Menu, Tray, Show
}

Re: AHK: Правка распознанного теста в LibreOffice Writer

null@example.com (Malcev) — Thu, 09 Apr 2020 01:21:19 +0000

Можно прокручивать pgup, pgdwn и следить за кареткой:

setbatchlines -1
oSM := ComObjCreate("com.sun.star.ServiceManager")
oDesk := oSM.createInstance("com.sun.star.frame.Desktop")
loop
{
   page := oDesk.CurrentComponent.CurrentController.ViewCursor.getPage
   if (oldpage != page)
   {
      oldpage := page
      oDesk.CurrentComponent.CurrentController.ViewSettings.ZoomType := 2
   }
   sleep 1
}

Re: AHK: Правка распознанного теста в LibreOffice Writer

null@example.com (DD) — Wed, 08 Apr 2020 23:42:16 +0000

Я понял, что вы сказали, надо попробовать.

Re: AHK: Правка распознанного теста в LibreOffice Writer

null@example.com (DD) — Wed, 08 Apr 2020 23:40:25 +0000

По-моему, если страницы непрерывно прокручиваются — это уже нерешаемо. То есть, скрипт будет отрабатывать, будто на экране целая страница, хотя на экране будут две половины двух идущих одна за другой страниц, в разном размере. И поэтому в скрипте не пропишешь, что курсор стоит в первой половине второй страницы, или во второй половине первой страницы, потому что не опознается граница между двумя страницами. В «Файл->Просмотр печати» (Ctrl+Shift+O) есть нужная функция постраничной прокрутки, но там нет возможности замен.

Re: AHK: Правка распознанного теста в LibreOffice Writer

null@example.com (Malcev) — Wed, 08 Apr 2020 22:51:19 +0000

Накладывайте события на перемещение курсора.
Если лень в это углубляться можете через ahk определять, что страница изменилась и посылать зум на всю страницу.

Re: AHK: Правка распознанного теста в LibreOffice Writer

null@example.com (DD) — Wed, 08 Apr 2020 22:21:23 +0000

В этом случае страница впишется в экран вся, но при прокрутке (либо при использовании диалога поиска-замены) этот вид будет меняться и она не будет целиком видна — видна будет и часть другой страницы. Если бы прокрутка целиком сменяла страницу, тогда появилась бы возможность относительно экрана опознавать, куда относительно этой страницы поставлен курсор, чтобы вывести ту же увеличенную область на изображении страницы.

Re: AHK: Правка распознанного теста в LibreOffice Writer

null@example.com (Malcev) — Wed, 08 Apr 2020 21:46:05 +0000

DD пишет:

Жаль, в LibreOffice нельзя настроить, чтобы страница всегда отображалась только целиком, без непрерывной прокрутки.

view->zoom->entire page

Re: AHK: Правка распознанного теста в LibreOffice Writer

null@example.com (DD) — Wed, 08 Apr 2020 19:41:46 +0000

Вот имеющийся код:

SetBatchLines, -1
#SingleInstance Force

pic_name_width := "4" 		; ширина счётчика в названиях изображений: 0001.jpg, 0002.jpg...
WidthOrNot := "1" 		; 0 — если названия изображений не имеют ширины: 1.jpg, 2.jpg...
pic_ext := "tif" 		; расширение изображений страниц
pic_pth := "E:\SCANz\"		; папка с изображениями страниц

oSM := ComObjCreate("com.sun.star.ServiceManager")

Gui, -Caption +AlwaysOnTop ;+Lastfound 
Gui, Margin, 0, 0
Gui, Add, Pic, h700 w600 vGuiPic, %pic_pth%%page%.%pic_ext%     ; x96 y20
OnMessage(0x201, "WM_LBUTTONDOWN")

loop
{
sleep 30

global pic_ext
global pic_pth
global WidthOrNot
global pic_name_width

If WinActive("ahk_exe soffice.bin")
{
   oDesk := oSM.createInstance("com.sun.star.frame.Desktop")
   page := oDesk.CurrentComponent.CurrentController.frame.layoutmanager.getElement("private:resource/statusbar/statusbar").RealInterface.AccessibleContext.getAccessibleChild(0).Text

   page := RegExReplace(page, "s)^[^\d]*(\d+) .*", "$1")
   If WidthOrNot
      page := Format("{:0" . pic_name_width . "u}", page)
   ;tooltip %pic_pth%%page%.%pic_ext%

   If NOT (pg_tmp = page) {
      Gui, Show, NA
      GuiControl,, GuiPic, %pic_pth%%page%.%pic_ext%
      pg_tmp := page
   }
}
else
   sleep 1000
}
return

WM_LBUTTONDOWN()
{
 WM_NCLBUTTONDOWN := 0xA1, HTCAPTION := 2
 PostMessage, WM_NCLBUTTONDOWN, HTCAPTION
}

Re: AHK: Правка распознанного теста в LibreOffice Writer

null@example.com (DD) — Wed, 08 Apr 2020 19:28:34 +0000

Жаль, в LibreOffice нельзя настроить, чтобы страница всегда отображалась только целиком, без непрерывной прокрутки. Иначе можно было бы в зависимости от клика в определенной области экрана, показывать ту же часть на изображении страницы.

Re: AHK: Правка распознанного теста в LibreOffice Writer

null@example.com (Malcev) — Wed, 08 Apr 2020 02:53:42 +0000

Так как у вас работает с 2 ошибками, то это

oArray := ComObjArray(0xC, 2) ;VT_VARIANT := 0xC
oDoc := oDesk.CurrentComponent("private:factory/simpress", "_blank", 0, Array)

можно заменить на это:

oDoc := oDesk.CurrentComponent()

Да и нет смысла каждый раз новый ком объект создавать, достаточно будет так:

oSM := ComObjCreate("com.sun.star.ServiceManager")
oDesk := oSM.createInstance("com.sun.star.frame.Desktop")
f1:: msgbox % oDesk.CurrentComponent.CurrentController.frame.layoutmanager.getElement("private:resource/statusbar/statusbar").RealInterface.AccessibleContext.getAccessibleChild(0).Text

Re: AHK: Правка распознанного теста в LibreOffice Writer

null@example.com (DD) — Wed, 08 Apr 2020 02:43:24 +0000

А-а, вот оно, спасибо

1::
oSM := ComObjCreate("com.sun.star.ServiceManager")
oDesk := oSM.createInstance("com.sun.star.frame.Desktop")
oArray := ComObjArray(0xC, 2) ;VT_VARIANT := 0xC
oDoc := oDesk.CurrentComponent("private:factory/simpress", "_blank", 0, Array)

msgbox % oDoc.CurrentController.frame.layoutmanager.getElement("private:resource/statusbar/statusbar").RealInterface.AccessibleContext.getAccessibleChild(0).Text
return

Re: AHK: Правка распознанного теста в LibreOffice Writer

null@example.com (Malcev) — Wed, 08 Apr 2020 02:38:57 +0000

Если вы внимательно почитаете примеры кодов по вашим же ссылкам, то поймете как подсоединяться к открытому документу.

Re: AHK: Правка распознанного теста в LibreOffice Writer

null@example.com (DD) — Wed, 08 Apr 2020 02:17:19 +0000

Что-то наклевывается). Вот так получается создать/открыть новый документ и получить инфу о страницах, — а надо бы получать из уже открытого —

1::
oSM := ComObjCreate("com.sun.star.ServiceManager")
oDesk := oSM.createInstance("com.sun.star.frame.Desktop")
oArray := ComObjArray(0xC, 2) ;VT_VARIANT := 0xC
oDoc := oDesk.loadComponentFromURL("private:factory/swriter", "_blank", 0, oArray)

msgbox % oDoc.CurrentController.frame.layoutmanager.getElement("private:resource/statusbar/statusbar").RealInterface.AccessibleContext.getAccessibleChild(0).Text
return

Re: AHK: Правка распознанного теста в LibreOffice Writer

null@example.com (Malcev) — Wed, 08 Apr 2020 01:46:26 +0000

Не то ищите.
Вам нужно получить объектную модель документа.
После чего получить нужную часть статус бара:

msgbox % oDoc.CurrentController.frame.layoutmanager.getElement("private:resource/statusbar/statusbar").RealInterface.AccessibleContext.getAccessibleChild(0).Text

Re: AHK: Правка распознанного теста в LibreOffice Writer

null@example.com (DD) — Tue, 07 Apr 2020 20:59:31 +0000

Смотрел примеры работы с этим api:

https://www.autohotkey.com/boards/viewt … mp;t=26570
https://www.autohotkey.com/boards/viewt … mp;t=23885

С api.libreoffice.org отобрал скорее всего относящиеся к номеру страницы команды:

sun::star::ui::dialogs::XWizardPage
sun::star::drawing::PageShape
sun::star::text::textfield

которые в скрипте надо записывать через точку:

sun.star.ui.dialogs.XWizardPage
sun.star.drawing.PageShape
sun.star.text.textfield

В итоге как запускать скрипт, чтобы в вывод попала активная страница?

1::
page := ComObjCreate("com.sun.star.drawing.PageShape")
MsgBox, % page
return