Серый форум — AHK: DllCall() и GetKeyboardState

Re: AHK: DllCall() и GetKeyboardState

null@example.com (serzh82saratov) — Sun, 24 May 2020 21:02:21 +0000

Хотя для пары значений подойдёт.
Работает намного шустрее чем:


		Loop 256
		{
			If NumGet(&KeyState, A_Index, "UChar") >> 7
				break
		}

+ открыть спойлер


VarSetCapacity(KeyState, 256, 0)

Loop
{ 
	DllCall("AttachThreadInput", Ptr, DllCall("GetWindowThreadProcessId", Ptr, WinExist("A"), UInt, 0)
	, UInt, DllCall("GetCurrentThreadId"), UInt, 1) 
	DllCall("GetKeyboardState", Ptr, &KeyState)
	
	press := DllCall("msvcrt\memchr", "ptr", &KeyState, "UChar", 0x80, "UInt", 256, "Cdecl UInt") 
		|| DllCall("msvcrt\memchr", "ptr", &KeyState, "UChar", 0x81, "UInt", 256, "Cdecl UInt") ? 1 : 0 
		
	ToolTip % press
	Sleep 1
}

Re: AHK: DllCall() и GetKeyboardState

null@example.com (serzh82saratov) — Sun, 24 May 2020 20:39:21 +0000

teadrinker
Тебе это наверняка известно, просто я впервые наткнулся, когда надо найти первое совпадение нужного значения байта.
Но в этом случае это не поможет.


VarSetCapacity(match, 256, 0) 
NumPut(0x80, match, 8, "UChar")

f := DllCall("msvcrt\memchr", "ptr", &match, "Int", 0x80, "Int", 256, "Cdecl UInt")
MsgBox % (f - &match) < 0 ? "not match" : "match"

Re: AHK: DllCall() и GetKeyboardState

null@example.com (teadrinker) — Sun, 24 May 2020 18:18:42 +0000

По-моему нельзя. Можно было бы, если бы была возможность произвести логическое "и" между двумя такими байтовыми массивами:

VarSetCapacity(match, 256, 0x80)
VarSetCapacity(KeyState, 256, 0)

но вроде в winapi это не поддерживается.

Re: AHK: DllCall() и GetKeyboardState

null@example.com (serzh82saratov) — Sun, 24 May 2020 15:14:03 +0000

Разобрался, младший бит переключается у не переключателей с каждым нажатием, и не имеет для них смысла. Состояние клавиши находится в старшем бите.
Тогда ещё раз вопрос, возможно без перебора узнать что в каком то из байтов в старшем бите есть единица?

+ открыть спойлер


SetFormat, IntegerFast, h
VarSetCapacity(KeyState, 256, 0)

Loop
{
	Tip =
	ThreadID := DllCall("GetWindowThreadProcessId", Ptr, WinExist("A"), UInt, 0)
	DllCall("AttachThreadInput", Ptr, ThreadID
						  , UInt, DllCall("GetCurrentThreadId")
						  , UInt, 1) 
	DllCall("GetKeyboardState", Ptr, &KeyState)
	
	Loop 256
		Tip .= (v := NumGet(&KeyState, A_Index, "UChar")) >> 7 ? GetKeyName("vk" A_Index) " " v "   " A_Index  "`n"  : ""
	ToolTip %  Tip  
	Sleep 11
}

Re: AHK: DllCall() и GetKeyboardState

null@example.com (serzh82saratov) — Sun, 24 May 2020 13:54:53 +0000

Лично для меня описание неоднозначно.
Если " < 0 ? GetKeyName" заменить на " != 0 ? GetKeyName", то будут видны все ключи.
И не ясно почему для некоторых клавиш появляются некие значения, после нажатия отпускания они могут исчезнуть...

Убрал под спойлер, так как ТС вроде сам хочет разобраться.

+ открыть спойлер


SetFormat, IntegerFast, h
VarSetCapacity(KeyState, 256, 0)

Loop
{
	Tip =
	ThreadID := DllCall("GetWindowThreadProcessId", Ptr, WinExist("A"), UInt, 0)
	DllCall("AttachThreadInput", Ptr, ThreadID
						  , UInt, DllCall("GetCurrentThreadId")
						  , UInt, 1) 
	DllCall("GetKeyboardState", Ptr, &KeyState)
	
	Loop 256
		Tip .= (v := NumGet(&KeyState, A_Index, "Char")) < 0 ? GetKeyName("vk" A_Index) " " v "  " A_Index  "`n"  : ""
	ToolTip %  Tip  
	Sleep 11
}

Re: AHK: DllCall() и GetKeyboardState

null@example.com (dmitry-semin) — Fri, 22 May 2020 04:05:47 +0000

Спасибо большое всем, кто отписался в теме. Пойду учить мат.часть.
1) Я полагал что полученный массив в функции можно будет просмотреть c помощью For-loop, чтобы понять, что внутри такого массива ключ, а что значения. Вот то, что я ожидал увидеть внутри:
ключ значение
0x41 0
0x42 1
0x43 0
0x44 1
0x45 0
0x46 1
0x47 0
2) Если я помещаю код внутрь цикла содержимое массива меняется самопроизвольно. Я ожидал, что изменения будут только при на нажатии мной клавиш во время выполнения цикла.
3) если я нажимаю левую кнопку мыши в окне скрипта, то статус "Не все нули" : "Все нули" меняется от каждого нажатия, но не от клавиатуры. Как будто тугл.


#Persistent
#SingleInstance force
if not (A_IsAdmin or RegExMatch(full_command_line, " /restart(?!\S)"))
{
try
{
if A_IsCompiled
Run *RunAs "%A_ScriptFullPath%" /restart
else
Run *RunAs "%A_AhkPath%" /restart "%A_ScriptFullPath%"
}
ExitApp
}
#InstallKeybdHook
#InstallMouseHook
#UseHook

VarSetCapacity(lpKeyState, 512, 0)

loop 
{
Result := DllCall("GetKeyboardState", "Ptr", &lpKeyState)
ToolTip,
(
% lpKeyState ? "Не все нули" : "Все нули"
)
}
return

В любом случае спасибо за помощь.

Re: AHK: DllCall() и GetKeyboardState

null@example.com (serzh82saratov) — Thu, 21 May 2020 13:17:03 +0000

Нет, там периодически печатные клавиши меняют состояния.

Re: AHK: DllCall() и GetKeyboardState

null@example.com (teadrinker) — Thu, 21 May 2020 12:26:37 +0000

serzh82saratov
Ну, не знаю, может предварительно все toggle-клавиши в ноль установить, не пробовал.

Re: AHK: DllCall() и GetKeyboardState

null@example.com (teadrinker) — Thu, 21 May 2020 12:23:41 +0000

dmitry-semin

Если описание параметра начинается с P или с lp — это значит, что ожидается указатель, адрес какого-либо буфера в памяти. В AHK такой буфер можно создать с помощью VarSetCapacity. В DllCall это будет тип данных "Ptr":

DllCall("GetKeyboardState", "Ptr", &buff)

где buff — это предварительно созданный буфер.

Re: AHK: DllCall() и GetKeyboardState

null@example.com (serzh82saratov) — Thu, 21 May 2020 08:56:20 +0000

teadrinker
Спасибо.
Забыл что там находятся не только нажатые клавиши, узнать без перебора что какое то из значений меньше нуля не получится?

Re: AHK: DllCall() и GetKeyboardState

null@example.com (Malcev) — Thu, 21 May 2020 02:09:28 +0000

А разве функция ждет Byte?
Она ждет ссылку на массив байтов.
Как его создавать написано в справке по dllcall.

Re: AHK: DllCall() и GetKeyboardState

null@example.com (dmitry-semin) — Thu, 21 May 2020 01:23:39 +0000

Исправил саму функцию (не исправил, а попытался).

Result := DllCall("GetKeyboardState" , "UChar", lpKeyState, "int")

int потому, что

An Int should also be used for each BOOL argument expected by a function (a BOOL value should be either 1 or 0).

Char потому, что

An unsigned character (UChar) can be used with functions that expect a BYTE.

На самом деле пробовал этот вариант уже. Он не работает.
Я вижу, что мое понимание DllCall на нулевом уровне, но я хотел бы все-таки научится.

Re: AHK: DllCall() и GetKeyboardState

null@example.com (teadrinker) — Thu, 21 May 2020 00:05:01 +0000

Легко:

VarSetCapacity(empty, 256, 0)
VarSetCapacity(state, 256, 0) 

NumPut(-128, state, 0x10 , "Char")

b := DllCall("msvcrt\memcmp", "Ptr", &empty, "Ptr", &state, "Ptr", 256)
MsgBox % b ? "Не все нули" : "Все нули"

Re: AHK: DllCall() и GetKeyboardState

null@example.com (serzh82saratov) — Wed, 20 May 2020 23:47:49 +0000

teadrinker
Забегу немного вперёд, а можно без перебора узнать что в переменной не только нули?


VarSetCapacity(state, 256, 0) 

NumPut(-128, state, 0x10 , "Char")  

Loop % VarSetCapacity(state)
	If NumGet(&state, A_Index, "Char") < 0 && (b := 1)
		break
		
MsgBox % b ? "Не все нули" : "Все нули"

Re: AHK: DllCall() и GetKeyboardState

null@example.com (teadrinker) — Wed, 20 May 2020 11:03:17 +0000

Почти всё верно, только почему вы решили, что значение result будет зависеть от статуса одной клавиши? Это просто показатель успешного или неуспешного выполнения всей функции.

Result := DllCall("GetKeyboardState" , PBYTE, lpKeyState, "BOOL")

Говорите, прочитали документацию по DllCall, тогда что такое у вас PBYTE и BOOL? Почему одно в кавычках, другое — нет? Читайте внимательно раздел Types of Arguments and Return Values.