Серый форум — AHK: Как реагировать на нужные слова - внутри файла txt

Re: AHK: Как реагировать на нужные слова - внутри файла txt

null@example.com (plank1433) — Sun, 26 Jul 2020 17:04:39 +0000

Спасибо большое.
Все заработало.

Re: AHK: Как реагировать на нужные слова - внутри файла txt

null@example.com (teadrinker) — Sun, 26 Jul 2020 16:03:10 +0000

Попробуйте так:

FileRead, fileContent, MyFile.txt
while RegExMatch(fileContent, "`amiO)((?:^:.+$\R?)+)\R(^[a-z]:\\.+$)", m, m ? m.Pos + m.Len : 1) {
   Loop, parse, % m[1], `n, `r
      Hotstring(A_LoopField, Func("RunFile").Bind(m[2]))
}
Return

RunFile(filePath) {
   Run, % filePath
}

Re: AHK: Как реагировать на нужные слова - внутри файла txt

null@example.com (plank1433) — Sun, 26 Jul 2020 12:57:38 +0000

Подскажите, а нельзя ли как-нибудь распознавать данные в txt вот в таком виде (с разделителем в виде строки):

:*X:Первая команда!
:*X:Команда первая!
F:\каталог файлов\3 5v.au3

:*X:Запустить программу2!
F:\каталог файлов\741.au3

(Чтобы не писать - рядом с однотипными командами - один и тот же адрес.)

Re: AHK: Как реагировать на нужные слова - внутри файла txt

null@example.com (plank1433) — Sun, 26 Jul 2020 12:44:34 +0000

Спасибо.
Все работает.

Re: AHK: Как реагировать на нужные слова - внутри файла txt

null@example.com (teadrinker) — Sat, 25 Jul 2020 23:47:02 +0000

Можно, тогда так:

FileRead, fileContent, MyFile.txt
while RegExMatch(fileContent, "`amO)^(.+)\|(.+)$", m, m ? m.Pos + m.Len : 1)
   Hotstring(m[1], Func("RunFile").Bind(m[2]))
Return

RunFile(filePath) {
   Run, % filePath
}

Re: AHK: Как реагировать на нужные слова - внутри файла txt

null@example.com (plank1433) — Sat, 25 Jul 2020 21:30:10 +0000

А может быть можно как-нибудь, перенести в txt не команду, а только путь к исполняемому файлу (который нужно запустить) ?

Чтобы вот такой вид текста был в txt:
:*X:Первая команда!|F:\каталог файлов\3 5v.au3
:*X:Команда первая!|F:\каталог файлов\3 5v.au3
:*X:Запустить программу2!|F:\каталог файлов\741.au3

В коде по-прежнему будет присутствовать команда Run
А адрес приставленный в коде - к Run - чтобы брался из txt

Re: AHK: Как реагировать на нужные слова - внутри файла txt

null@example.com (plank1433) — Sat, 25 Jul 2020 13:30:19 +0000

Понятно

Re: AHK: Как реагировать на нужные слова - внутри файла txt

null@example.com (teadrinker) — Sat, 25 Jul 2020 12:20:52 +0000

Команды и не могут находиться внутри текстового файла, они должны быть в коде скрипта, иначе не будут выполняться.

Re: AHK: Как реагировать на нужные слова - внутри файла txt

null@example.com (plank1433) — Sat, 25 Jul 2020 12:09:40 +0000

Ясно, спасибо.

Но это - только ключевые слова.
Команды Action1 и Action1 - по-прежнему находятся внутри скрипта, а не в том же самом txt
Я имею ввиду саму команду ( MsgBox, % A_ThisFunc ), а не ссылку на нее - Action1.

Re: AHK: Как реагировать на нужные слова - внутри файла txt

null@example.com (teadrinker) — Sat, 25 Jul 2020 11:21:01 +0000

Сам скрипт должен так выглядеть:

FileRead, fileContent, MyFile.txt
while RegExMatch(fileContent, "`amO)^(.+)\|(.+)$", m, m ? m.Pos + m.Len : 1)
   Hotstring(m[1], m[2])
Return

Action1() {
   MsgBox, % A_ThisFunc
}

Action2() {
   MsgBox, % A_ThisFunc
}

Re: AHK: Как реагировать на нужные слова - внутри файла txt

null@example.com (teadrinker) — Sat, 25 Jul 2020 11:16:47 +0000

Пишите ту часть, что в моём скрипте в начале, в файл:

:*X:Первая команда!|Action1
:*X:Команда первая!|Action1
:*X:Запустить программу2!|Action2

В скрипте читайте содержимое файла в переменную fileContent.

Re: AHK: Как реагировать на нужные слова - внутри файла txt

null@example.com (plank1433) — Sat, 25 Jul 2020 11:12:41 +0000

Я в самом первом сообщении именно об этом и спрашивал.

У меня есть простой классический код ahk.
Он реагирует на последовательность нажатий клавиш на клавиатуре.
Если вводится конкретное слово, то скрипт немедленно выполняет какую-то команду.

Но неудобно вводить множество команд - внутрь этого кода.
Подскажите, как заставить скрипт искать нужные слова - внутри файла txt, где записаны команды ?
То есть, чтобы работал так же, но слова-команды хранились бы отдельно - внутри файла txt.

Re: AHK: Как реагировать на нужные слова - внутри файла txt

null@example.com (teadrinker) — Sat, 25 Jul 2020 10:43:45 +0000

То, что fileContent — пишите в файле. В скрипте используйте FileRead, fileContent, MyFile.txt.

Re: AHK: Как реагировать на нужные слова - внутри файла txt

null@example.com (plank1433) — Sat, 25 Jul 2020 10:41:44 +0000

teadrinker
Здесь не написать много команд и не разбить их на категории.
Как взять эти команды из txt файла ?

Re: AHK: Как реагировать на нужные слова - внутри файла txt

null@example.com (teadrinker) — Sat, 25 Jul 2020 10:15:45 +0000

Можно использовать такой принцип:

fileContent =
(
:*X:Первая команда!|Action1
:*X:Команда первая!|Action1
:*X:Запустить программу2!|Action2
)
while RegExMatch(fileContent, "`amO)^(.+)\|(.+)$", m, m ? m.Pos + m.Len : 1)
   Hotstring(m[1], m[2])
Return

Action1() {
   MsgBox, % A_ThisFunc
}

Action2() {
   MsgBox, % A_ThisFunc
}