Серый форум — AHK: При вызове Gui перестает работать переназначенная клавиша

Re: AHK: При вызове Gui перестает работать переназначенная клавиша

null@example.com (serzh82saratov) — Mon, 27 Jul 2020 17:37:15 +0000

mkone112 пишет:

если зажать Enter и понажимать SC24-27 - будет периодически проскакивать enter

У меня такого нет.

Re: AHK: При вызове Gui перестает работать переназначенная клавиша

null@example.com (mkone112) — Mon, 27 Jul 2020 16:28:34 +0000

serzh82saratov
Происходит при быстром нажатии несколько раз. Это еще более заметно, если добавить другие клавиши в блок

#if EnterTime

Пример:


;если зажать Enter и понажимать SC24-27 - будет периодически проскакивать enter
#if EnterTime
SC21:: MyGuiFunction() 
SC24::Left
SC25::Up
SC26::Down
SC27::Right
Enter Up::
	if A_TickCount - EnterTime - (EnterTime := 0) < 300 
		Send {Enter}
	Return 
#if !EnterTime
Enter:: EnterTime := A_TickCount 
#if

Вот так вроде работает:


#if GetKeyState("Enter", "P")
    SC12:: MyGuiFunction()
#if


#if EnterTime
Enter Up::
  if (A_TickCount - EnterTime - (EnterTime := 0) < 300 && A_PriorKey == "Enter")
    Send {Enter}
  return
#if


#if !EnterTime
Enter:: EnterTime := A_TickCount 
#if

Re: AHK: При вызове Gui перестает работать переназначенная клавиша

null@example.com (serzh82saratov) — Mon, 27 Jul 2020 15:58:18 +0000

mkone112 пишет:

А этот вариант периодически посылает Enter при нажатии Enter & F

У меня такого нет.

Re: AHK: При вызове Gui перестает работать переназначенная клавиша

null@example.com (mkone112) — Mon, 27 Jul 2020 15:18:39 +0000

serzh82saratov
Я что-то поторопился, этот вариант тоже посылает Enter при отпускании после удержания более 0.3с


#SingleInstance, force 

$Enter::
    ; остальной код
    KeyWait, Enter
    if (A_PriorKey == "Enter" && A_TimeSinceThisHotkey < 300)
            Send {Enter}
    ; остальной код
return
Enter & SC12::MyGuiFunction() 

z::MyGuiFunction()

MyGuiFunction()  {

  Global MyEdit
  Gui, +LastFound
  GuiHWND := WinExist()           ;--get handle to this gui..

  Gui, Add , Text  ,        , Enter value
  Gui, Add , Edit  , vMyEdit,
  Gui, Add , Button, Default, OK
  Gui, Show
  WinWaitClose, ahk_id %GuiHWND%  ;--waiting for gui to close
  return ReturnCode               ;--returning value

  ButtonOK:
    GuiControlGet, ReturnCode, , MyEdit
    Gui, Destroy
  return

  GuiEscape:
  GuiClose:
    ReturnCode = -1
    Gui, Destroy
  return
}

А этот вариант периодически посылает Enter при нажатии Enter & F

Так ещё попробуйте.


#if EnterTime
SC21:: MyGuiFunction() 

Enter Up::
	if A_TickCount - EnterTime - (EnterTime := 0) < 300 
		Send {Enter}
	Return 
#if !EnterTime
Enter:: EnterTime := A_TickCount 
#if

#SingleInstance, force 

#if EnterTime
SC21:: MyGuiFunction() 

Enter Up::
  if A_TickCount - EnterTime - (EnterTime := 0) < 300 
    Send {Enter}
  Return 
#if !EnterTime
Enter:: EnterTime := A_TickCount 
#if 

MyGuiFunction()  {

  Global MyEdit
  Gui, +LastFound
  GuiHWND := WinExist()           ;--get handle to this gui..

  Gui, Add , Text  ,        , Enter value
  Gui, Add , Edit  , vMyEdit,
  Gui, Add , Button, Default, OK
  Gui, Show
  WinWaitClose, ahk_id %GuiHWND%  ;--waiting for gui to close
  return ReturnCode               ;--returning value

  ButtonOK:
    GuiControlGet, ReturnCode, , MyEdit
    Gui, Destroy
  return

  GuiEscape:
  GuiClose:
    ReturnCode = -1
    Gui, Destroy
  return
}

Re: AHK: При вызове Gui перестает работать переназначенная клавиша

null@example.com (serzh82saratov) — Sun, 26 Jul 2020 15:07:19 +0000

Так ещё попробуйте.


#if EnterTime
SC21:: MyGuiFunction() 

Enter Up::
	if A_TickCount - EnterTime - (EnterTime := 0) < 300 
		Send {Enter}
	Return 
#if !EnterTime
Enter:: EnterTime := A_TickCount 
#if

Re: AHK: При вызове Gui перестает работать переназначенная клавиша

null@example.com (mkone112) — Sun, 26 Jul 2020 14:57:06 +0000

serzh82saratov
Я немного доработал ваше решение и все вроде-бы работает. Большое спасибо!


#SingleInstance, force 

$Enter::
    ; остальной код
    KeyWait, Enter
    if (A_PriorKey == "Enter" && A_TimeSinceThisHotkey < 300)
            Send {Enter}
    ; остальной код
return
Enter & SC12::MyGuiFunction() 

z::MyGuiFunction()

MyGuiFunction()  {

  Global MyEdit
  Gui, +LastFound
  GuiHWND := WinExist()           ;--get handle to this gui..

  Gui, Add , Text  ,        , Enter value
  Gui, Add , Edit  , vMyEdit,
  Gui, Add , Button, Default, OK
  Gui, Show
  WinWaitClose, ahk_id %GuiHWND%  ;--waiting for gui to close
  return ReturnCode               ;--returning value

  ButtonOK:
    GuiControlGet, ReturnCode, , MyEdit
    Gui, Destroy
  return

  GuiEscape:
  GuiClose:
    ReturnCode = -1
    Gui, Destroy
  return
}

Re: AHK: При вызове Gui перестает работать переназначенная клавиша

null@example.com (mkone112) — Sun, 26 Jul 2020 14:29:31 +0000

serzh82saratov пишет:

Так вы объясните в чём для вас это функционально выражается, я тоже вижу что отличается.

В первом варианте, при зажатии Enter более чем на 0.3сек - Enter не посылается.
Во втором - Enter посылается при сколь угодно долгом удержании.

Re: AHK: При вызове Gui перестает работать переназначенная клавиша

null@example.com (mkone112) — Sun, 26 Jul 2020 14:26:05 +0000

teadrinker пишет:

Можно без KeyWait, например:

Если несколько раз нажать Enter & f то посылается Enter.

Re: AHK: При вызове Gui перестает работать переназначенная клавиша

null@example.com (serzh82saratov) — Sun, 26 Jul 2020 14:02:01 +0000

mkone112 пишет:

Не эквивалентно этому:

Так вы объясните в чём для вас это функционально выражается, я тоже вижу что отличается.

teadrinker пишет:

Интересный приём, не знал такого.

Он периодически всплывает на форуме, но запоминается плохо из за своей неочивидности.

Re: AHK: При вызове Gui перестает работать переназначенная клавиша

null@example.com (mkone112) — Sun, 26 Jul 2020 13:34:18 +0000

serzh82saratov пишет:

Так не проще?

По идее это:

Enter:: Enter

Не эквивалентно этому:

$SC1C::
    KeyWait, Enter
    if (A_PriorKey == "Enter" && A_TimeSinceThisHotkey < 300)
        Send {Enter}
return

Re: AHK: При вызове Gui перестает работать переназначенная клавиша

null@example.com (mkone112) — Sun, 26 Jul 2020 13:32:25 +0000

teadrinker пишет:

f — это не SC12, это sc21.

У меня Colemak

Re: AHK: При вызове Gui перестает работать переназначенная клавиша

null@example.com (teadrinker) — Sun, 26 Jul 2020 11:54:41 +0000

Хотя в справке он упоминается.

Re: AHK: При вызове Gui перестает работать переназначенная клавиша

null@example.com (teadrinker) — Sun, 26 Jul 2020 11:37:16 +0000

Интересный приём, не знал такого.

Re: AHK: При вызове Gui перестает работать переназначенная клавиша

null@example.com (serzh82saratov) — Sun, 26 Jul 2020 11:24:46 +0000

Так не проще?


#SingleInstance, force 

Enter:: Enter
Enter & SC21::MyGuiFunction() 

z::MyGuiFunction()

MyGuiFunction()  {

  Global MyEdit
  Gui, +LastFound
  GuiHWND := WinExist()           ;--get handle to this gui..

  Gui, Add , Text  ,        , Enter value
  Gui, Add , Edit  , vMyEdit,
  Gui, Add , Button, Default, OK
  Gui, Show
  WinWaitClose, ahk_id %GuiHWND%  ;--waiting for gui to close
  return ReturnCode               ;--returning value

  ButtonOK:
    GuiControlGet, ReturnCode, , MyEdit
    Gui, Destroy
  return

  GuiEscape:
  GuiClose:
    ReturnCode = -1
    Gui, Destroy
  return
}

Re: AHK: При вызове Gui перестает работать переназначенная клавиша

null@example.com (teadrinker) — Sun, 26 Jul 2020 11:08:03 +0000

Можно без KeyWait, например:


#SingleInstance, force
single_press_time := 300

info := {}, timer := Func("WaitEnter").Bind(info)
; Enter посылается только при одиночном зажатии менее чем на 300мс
$Enter::
    if !info.start {
        info.start := A_TickCount
        SetTimer, % timer, 10
    }
return

; Enter & F вызывают Gui, и после этого Enter не работает
#if GetKeyState("Enter", "P")
    SC21::MyGuiFunction()
#if

; Но при вызове Gui по нажатию z Enter работает
z::MyGuiFunction()

WaitEnter(info) {
    global single_press_time
    if !GetKeyState("Enter", "P") {
        SetTimer,, Delete
        if (A_TickCount - info.start < single_press_time)
            Send {Enter}
        info.start := ""
    }
}

MyGuiFunction()  {

  Global MyEdit
  Gui, +LastFound
  GuiHWND := WinExist()           ;--get handle to this gui..

  Gui, Add , Text  ,        , Enter value
  Gui, Add , Edit  , vMyEdit,
  Gui, Add , Button, Default, OK
  Gui, Show
  WinWaitClose, ahk_id %GuiHWND%  ;--waiting for gui to close
  return ReturnCode               ;--returning value

  ButtonOK:
    GuiControlGet, ReturnCode, , MyEdit
    Gui, Destroy
  return

  GuiEscape:
  GuiClose:
    ReturnCode = -1
    Gui, Destroy
  return
}

f — это не SC12, это sc21.