Серый форум — AHK: ActiveX из AutoHotkey

Re: AHK: ActiveX из AutoHotkey

null@example.com (teadrinker) — Sun, 11 Oct 2020 14:43:14 +0000

Немного упростил.

Re: AHK: ActiveX из AutoHotkey

null@example.com (teadrinker) — Fri, 09 Oct 2020 20:51:19 +0000

Ещё интересный вариант с созданием callback-функции из BoundFunc-объекта:

BoundObj := Func("JoinStrings").Bind(Ret := [])
Clbk := new BoundFuncCallback(BoundObj, 2, "Fast")

DllCall(Clbk.addr, "Str", "Hello, ", "Str", "World!")
MsgBox, % Ret[1]

JoinStrings(Ret, pStr1, pStr2) {
   Ret[1] := StrGet(pStr1) . StrGet(pStr2)
   Return true ; при вызове через адрес можно вернуть только число
}

class BoundFuncCallback
{
   __New(BoundFuncObj, paramCount, options := "") {
      this.pInfo := Object( {BoundObj: BoundFuncObj, paramCount: paramCount} )
      this.addr := RegisterCallback(this.__Class . "._Callback", options, paramCount, this.pInfo)
   }
   __Delete() {
      ObjRelease(this.pInfo)
      DllCall("GlobalFree", "Ptr", this.addr, "Ptr")
   }
   _Callback(Params*) {
      Info := Object(A_EventInfo), Args := []
      Loop % Info.paramCount
         Args.Push( NumGet(Params + A_PtrSize*(A_Index - 2)) )
      Return Info.BoundObj.Call(Args*)
   }
}

Re: AHK: ActiveX из AutoHotkey

null@example.com (Malcev) — Thu, 08 Oct 2020 04:21:35 +0000

А, понял.
Спасибо!

Re: AHK: ActiveX из AutoHotkey

null@example.com (teadrinker) — Thu, 08 Oct 2020 04:10:23 +0000

vScalar — не статическая.

Re: AHK: ActiveX из AutoHotkey

null@example.com (Malcev) — Thu, 08 Oct 2020 04:06:18 +0000

Не вижу разницы:

value := 1.000000000000011
msgbox % numget(_cvScalar(), 0, "double") == value

_cvScalar()
{
   static value := 1.000000000000011
   VarSetCapacity(vScalar, 8, 0)
   NumPut(value, vScalar, 0, "double")
   return &vScalar
}

Re: AHK: ActiveX из AutoHotkey

null@example.com (YMP) — Thu, 08 Oct 2020 03:33:12 +0000

Malcev пишет:

Helgef, писал, что так нельзя возвращать адрес в локальных функциях.
Local variables are for use only when the function executes. You have no guarantees after the function returns.

Так у меня же не просто локальная, а статическая переменная. Они сохраняются между вызовами функции, для того и предназначены.

Re: AHK: ActiveX из AutoHotkey

null@example.com (YMP) — Thu, 08 Oct 2020 03:29:23 +0000

serzh82saratov пишет:

Разве это не про значение по умолчанию?
Если не указано, то UInt.

Нет, там вполне однозначно, по-моему. Если возврата нет, он пустой или пустая строка, тогда возвращается 0. Иначе функция должна возвращать целое.

Re: AHK: ActiveX из AutoHotkey

null@example.com (Malcev) — Thu, 08 Oct 2020 00:08:26 +0000

YMP пишет:

Возвращение строки ещё вот так работает:
addr := RegisterCallback("MyFunc")
MsgBox, % DllCall(addr, "Str")

MyFunc() {
    static test := "test"
    Return &test
}

Helgef, писал, что так нельзя возвращать адрес в локальных функциях.

Local variables are for use only when the function executes. You have no guarantees after the function returns. For example, this will fail,

value := 1.000000000000011
msgbox % numget(_cvScalar(value), 0, "double") == value

_cvScalar(value)
{
   VarSetCapacity(vScalar, 8, 0)
   NumPut(value, vScalar, 0, "double")
   return &vScalar
}

It fails because when the function returns, it stores an empty string at the address you return, overwriting the first (two) byte(s) with the zero terminator.
You can use byref,

Re: AHK: ActiveX из AutoHotkey

null@example.com (teadrinker) — Wed, 07 Oct 2020 20:04:26 +0000

Проще всего через HeapAlloc/HeapReAlloc.

Re: AHK: ActiveX из AutoHotkey

null@example.com (serzh82saratov) — Wed, 07 Oct 2020 19:57:39 +0000

То есть в коде 43 надо по хорошему перед StrPut проверять размер данных, и если они больше буфера, то увеличивать буфер, если меньше, то оставлять буфер как есть.

Re: AHK: ActiveX из AutoHotkey

null@example.com (teadrinker) — Wed, 07 Oct 2020 19:31:32 +0000

Это было бы так, если бы мы изменяли её содержимое, присваивая другое значение через var := "newValue". В таком случае, если новое значение требует большей вместимости, указатель на переменную может измениться.

var := "a" 
ptr1 := &var
var := "abcd"
ptr2 := &var
MsgBox, % ptr1 "`n" ptr2

Re: AHK: ActiveX из AutoHotkey

null@example.com (serzh82saratov) — Wed, 07 Oct 2020 19:22:01 +0000

Note: the variable will auto-expand if the script assigns it a larger value later.

Так она разве не автоматически увеличивается под содержимое? На практике вроде всегда всё влезает.

Since this function is often called simply to ensure the variable has a certain minimum capacity

Re: AHK: ActiveX из AutoHotkey

null@example.com (teadrinker) — Wed, 07 Oct 2020 19:11:05 +0000

serzh82saratov пишет:

А почему размер 256 а не 1?

А почему должен быть 1? Размер должен быть как минимум равен содержимому. Если меньше, то нет гарантии, что данные сохранятся, или не испортят чего-нибудь другого при записи.

Re: AHK: ActiveX из AutoHotkey

null@example.com (serzh82saratov) — Wed, 07 Oct 2020 19:06:33 +0000

Malcev пишет:

Посмотрел справку - твой код у меня так работает.

ahkReady тут видимо не причём. Так отлично работает. Значит дело было только в "неправильном" вызове DllCall.


script = 
( %
	VarSetCapacity(buff, 1, 0)
	Loop 
	{
	    r := DllCall(addr, "int", A_Index, "int", 22, "Ptr", &buff)
		MsgBox, % NumGet(buff, "Float") "``n" StrGet(&buff + 8) 
	}
)   
AhkCom := ComObjCreate("AutoHotkey.Script") 
AhkCom.ahkassign("addr", RegisterCallback("MyFunc")) 
AhkCom.ahktextdll(script) 
Return
	
MyFunc(p1, p2, pBuff) {
    NumPut(p1 / p2, pBuff + 0, "Float")
    StrPut("Hello, World!", pBuff + 8)
    Return true
}

Re: AHK: ActiveX из AutoHotkey

null@example.com (serzh82saratov) — Wed, 07 Oct 2020 18:00:55 +0000

teadrinker пишет:

VarSetCapacity(buff, 256, 0)

А почему размер 256 а не 1?