Malcev пишет:

Кому-то удобно читать подобный код?

Если аккуратнее написать, то вполне, если привычно.

Acc_ObjectFromPoint(ByRef _idChild_ = "", x = "", y = "") {
	If DllCall("oleacc\AccessibleObjectFromPoint"
	, "Int64", x = "" || y = "" ? 0 * DllCall("GetCursorPos", "Int64*", pt) + pt : x & 0xFFFFFFFF | y << 32
	, "Ptr* ", pacc, "Ptr", VarSetCapacity(varChild, 8 + 2 * A_PtrSize, 0) * 0 + &varChild) = 0
		Return ComObjEnwrap(9, pacc, 1), _idChild_ := NumGet(varChild, 8, "UInt")
}

Но можно и так.

Acc_ObjectFromPoint(ByRef _idChild_ = "", x = "", y = "") {
	VarSetCapacity(varChild, 8 + 2 * A_PtrSize, 0)
	If (x = "" || y = "")  
		DllCall("GetCursorPos", "Int64*", pt)
	Else 
		pt := x & 0xFFFFFFFF | y << 32
	If DllCall("oleacc\AccessibleObjectFromPoint", "Int64", pt, "Ptr* ", pacc, "Ptr", &varChild) = 0
		Return ComObjEnwrap(9, pacc, 1), _idChild_ := NumGet(varChild, 8, "UInt") 
}

Ты бы также написал?

Я бы написал, как во втором варианте.
Ну и вообще комплексный код я бы описывал подробно с комментариями и отсылками - так, как описываются функции в исходниках автохотки.
Там описания больше, чем кода.
Потому что пройдет время, всё позабудется, и на понимание алгоритма своего кода без описания можно потратить больше времени, чем написать его заново.

MsgBox
Start := A_TickCount
loop 200000
	f1()
MsgBox % A_TickCount - Start "`n с кавычками" 

Start := A_TickCount
loop 200000
	f2()
MsgBox % A_TickCount - Start "`n с * и +" 

Start := A_TickCount
loop 200000
	f3()
MsgBox % A_TickCount - Start "`n с If Else " 

f1() { 
	(1 = 1 ? ("", DllCall("GetCursorPos", "Int64*", pt)) . pt : 0)
	, (1 = 1 ? ("", DllCall("GetCursorPos", "Int64*", pt)) . pt : 0)
	, (1 = 1 ? ("", DllCall("GetCursorPos", "Int64*", pt)) . pt : 0)
	, (1 = 1 ? ("", DllCall("GetCursorPos", "Int64*", pt)) . pt : 0) 
	, (1 = 1 ? ("", DllCall("GetCursorPos", "Int64*", pt)) . pt : 0)   
}

f2() { 
	(1 = 1 ? 0*DllCall("GetCursorPos","Int64*",pt)+pt : 0)
	, (1 = 1 ? 0*DllCall("GetCursorPos","Int64*",pt)+pt : 0)
	, (1 = 1 ? 0*DllCall("GetCursorPos","Int64*",pt)+pt : 0)
	, (1 = 1 ? 0*DllCall("GetCursorPos","Int64*",pt)+pt : 0)
	, (1 = 1 ? 0*DllCall("GetCursorPos","Int64*",pt)+pt : 0)
} 


f3() { 
	If (1 = 1)
		DllCall("GetCursorPos", "Int64*", pt)
	Else 
		MsgBox
	If (1 = 1)
		DllCall("GetCursorPos", "Int64*", pt)
	Else 
		MsgBox
	If (1 = 1)
		DllCall("GetCursorPos", "Int64*", pt)
	Else 
		MsgBox
	If (1 = 1)
		DllCall("GetCursorPos", "Int64*", pt)
	Else 
		MsgBox
	If (1 = 1)
		DllCall("GetCursorPos", "Int64*", pt)
	Else 
		MsgBox
}

Acc_ObjectFromPoint(ByRef _idChild_ = "", x = "", y = "") {
	If DllCall("oleacc\AccessibleObjectFromPoint"
	, "Int64", x = "" || y = "" ? ("", DllCall("GetCursorPos", "Int64*", pt)) . pt : x & 0xFFFFFFFF | y << 32
	, "Ptr* ", pacc, "Ptr", VarSetCapacity(varChild, 8 + 2 * A_PtrSize, 0) * 0 + &varChild) = 0
		Return ComObjEnwrap(9, pacc, 1), _idChild_ := NumGet(varChild, 8, "UInt")
}

Но тут не принципиально. И надо знать особенности парсера интерпретатора. Или провести простой тест.

Start := A_TickCount
loop 1000000
	вызов функции
MsgBox % A_TickCount - Start

Acc_ObjectFromPoint(ByRef _idChild_ = "", x = "", y = "") {
	If DllCall("oleacc\AccessibleObjectFromPoint", "Int64", x==""||y==""?0*DllCall("GetCursorPos","Int64*",pt)+pt:x&0xFFFFFFFF|y<<32
		, "Ptr*", pacc, "Ptr", VarSetCapacity(varChild,8+2*A_PtrSize,0)*0+&varChild)=0
		Return ComObjEnwrap(9,pacc,1), _idChild_:=NumGet(varChild,8,"UInt")
}

или это?

Acc_ObjectFromPoint(ByRef _idChild_ = "", x = "", y = "") {
	VarSetCapacity(varChild, 8 + 2 * A_PtrSize, 0)
	If (x = "" || y = "")  
		DllCall("GetCursorPos", "Int64*", pt)
	Else 
		pt := x & 0xFFFFFFFF | y << 32
	If DllCall("oleacc\AccessibleObjectFromPoint", "Int64", pt, "Ptr* ", pacc, "Ptr", &varChild) = 0
		Return ComObjEnwrap(9, pacc, 1), _idChild_ := NumGet(varChild, 8, "UInt") 
}

что вернет функция ?

Пустоту.

я тут слышал мнение, что чем короче написан код, тем быстрее он будет выполняться.

Не всегда, от алгоритма зависит. Например Min() переберёт и отсортирует список, StrSplit() переберёт список и создаст массив, и это можно записать в одну короткую строку. Так что в первую очередь надо понимать что написано, а не из скольки символов состоит.

Кому-то удобно читать подобный код?

Если аккуратнее написать, то вполне, если привычно.

Acc_ObjectFromPoint(ByRef _idChild_ = "", x = "", y = "") {
	If DllCall("oleacc\AccessibleObjectFromPoint"
	, "Int64", x = "" || y = "" ? 0 * DllCall("GetCursorPos", "Int64*", pt) + pt : x & 0xFFFFFFFF | y << 32
	, "Ptr* ", pacc, "Ptr", VarSetCapacity(varChild, 8 + 2 * A_PtrSize, 0) * 0 + &varChild) = 0
		Return ComObjEnwrap(9, pacc, 1), _idChild_ := NumGet(varChild, 8, "UInt")
}

Но можно и так.

Acc_ObjectFromPoint(ByRef _idChild_ = "", x = "", y = "") {
	VarSetCapacity(varChild, 8 + 2 * A_PtrSize, 0)
	If (x = "" || y = "")  
		DllCall("GetCursorPos", "Int64*", pt)
	Else 
		pt := x & 0xFFFFFFFF | y << 32
	If DllCall("oleacc\AccessibleObjectFromPoint", "Int64", pt, "Ptr* ", pacc, "Ptr", &varChild) = 0
		Return ComObjEnwrap(9, pacc, 1), _idChild_ := NumGet(varChild, 8, "UInt") 
}

Ты бы также написал?

В данном случае создаётся излишне одна переменная, только если x y указаны, или убирается умножение и сложение если не указаны (там можно было и без них).

("", DllCall("GetCursorPos", "Int64*", pt)) . pt

Но когда результаты выражений сохраняются в переменную чтобы далее однажды применится, то это в целом не очень гуд, но это не про этот пример.