Серый форум — AHK: Поиск файлов по списку из текстового файла

Re: AHK: Поиск файлов по списку из текстового файла

null@example.com (teadrinker) — Fri, 12 Mar 2021 15:08:23 +0000

Ещё короче:

Files := ""
FileRead, ExludeList, ExludeList.txt

Loop, Files, %SourceDir%\*, R
   if !RegExMatch(ExludeList, "m`a)^\Q" . A_LoopFileName . "\E$")
      Files .= A_LoopFileName . "`n"
   
MsgBox, % Files

Re: AHK: Поиск файлов по списку из текстового файла

null@example.com (BlackCat) — Fri, 12 Mar 2021 13:52:34 +0000

teadrinker ... кстати, сразу видно Мастера - у Вас код короче получился
Спасибо!

Re: AHK: Поиск файлов по списку из текстового файла

null@example.com (BlackCat) — Fri, 12 Mar 2021 13:45:16 +0000

teadrinker ОК, понял.
Благодарю за работу и помощь!
Буду копать далее ...

Re: AHK: Поиск файлов по списку из текстового файла

null@example.com (teadrinker) — Fri, 12 Mar 2021 13:28:23 +0000

BlackCat пишет:

Ничего универсального для чтения всех кодировок придумать невозможно?

Нет, кодировка текстового файла определяется только по BOM, если её нет, то считается, что кодировка ANSI.

Re: AHK: Поиск файлов по списку из текстового файла

null@example.com (teadrinker) — Fri, 12 Mar 2021 13:23:28 +0000

Для данного случая подойдёт и cp 1251, точнее это скорее всего ANSI, но иногда требуется сохранить Unicode-символы, которых нет в ANSI, в таких случаях и нужна кодировка UTF-8. Например, такой скрипт сохранить в ANSI не получится:

MsgBox, ø ¼ š

Поэтому просто поставьте по умолчанию кодировку UTF-8 с BOM.

Re: AHK: Поиск файлов по списку из текстового файла

null@example.com (BlackCat) — Fri, 12 Mar 2021 12:41:56 +0000

teadrinker, ну да, так и есть!
Для написания скриптов AHK использую Notepad++ со всеми интересными мне плагинами и подсветкой синтаксиса AHK
По-умолчанию он создает текстовые файлы в кодировке UTF-8 БЕЗ BOM
Тогда какой смысл использовать кодировку UTF-8 с BOM, если можно просто зафигачить весь список в кодировку 1251 - файл, созданный средствами винды???
... конечно, можно в настойках Notepad++ установить нужную кодировку для новых файлов, но .... лень, да и не каждый захочет или поймет, как это сделать ... в любом случае должна присутствовать "страховка от дурака".
Ничего универсального для чтения всех кодировок придумать невозможно? - В этом вопросе я пока zero.

Re: AHK: Поиск файлов по списку из текстового файла

null@example.com (teadrinker) — Fri, 12 Mar 2021 10:14:43 +0000

BlackCat пишет:

русские названия не воспринимает

Если не воспринимает, значит кодировка списка была UTF-8-RAW, то-есть без BOM. Измените на UTF-8 с BOM или добавьте явно кодировку в скрипт первой строчкой:

FileEncoding, UTF-8

и всё будет ок.

Re: AHK: Поиск файлов по списку из текстового файла

null@example.com (BlackCat) — Fri, 12 Mar 2021 07:53:18 +0000

teadrinker, хорошая попытка, но такая же фигня - русские названия не воспринимает.
Т.е., если в списке есть файл, напр. "Новый текстовый документ.txt" и он есть в директории поиска, то он все-равно отображается в msgbox.
Суть проблемы понял - изменил кодировку файла списка с UTF-8 на виндовую 1251 и все заработало.
Но все-равно спасибо за помощь!

Re: AHK: Поиск файлов по списку из текстового файла

null@example.com (teadrinker) — Thu, 11 Mar 2021 21:54:51 +0000

Думаю, так должно сработать:

Exclude := {}, Files := ""
FileRead, ExludeList, ExludeList.txt

Loop, parse, ExludeList, `n, `r
   Exclude[A_LoopField] := ""

Loop, Files, %SourceDir%\*, R
   if !Exclude.HasKey(A_LoopFileName)
      Files .= A_LoopFileName . "`n"
   
MsgBox, % Files

Re: AHK: Поиск файлов по списку из текстового файла

null@example.com (BlackCat) — Thu, 11 Mar 2021 18:34:14 +0000

В общем, на исключение файлов из поиска, имена которых находятся в текстовом файле, работает этот код:

ExludeList := "ExludeList.txt"

Exlude := []
Loop read, % ExludeList
	{
	Exlude.push(A_LoopReadLine)
	}
	
Loop % SourceDir "\*", 0, 1
	{
	Found := 0
	For Each, Filename in Exlude
	If (Filename = A_LoopFileName){
		Found := 1
		}
	If (!Found){
		Files .= A_LoopFileName "`n"
		}
	}
	
MsgBox % Files

Может кому пригодится.
Единственный недостаток - почему-то не понимает кириллицу, хотя текстовой файл списка в UTF-8

Re: AHK: Поиск файлов по списку из текстового файла

null@example.com (BlackCat) — Wed, 10 Mar 2021 17:24:49 +0000

Alectric благодарю за ответ, но результат тот же, что и с моим кодом.

Re: AHK: Поиск файлов по списку из текстового файла

null@example.com (Alectric) — Wed, 10 Mar 2021 17:11:12 +0000

Цикловые переменные (A_Loop* или A_Index) действительны в пределах только одного цикла (то есть в пределах фигурных скобок). Чтобы использовать их во "вложенном" цикле - нужно присвоить их содержимой другой переменной и использовать ее.

List := "List.txt"

Loop read, % List
  {
  tmpvar:=A_LoopReadLine
  Loop % SourceDir "\*", 0, 1
    {
    If (A_LoopFileName != tmpvar) {
      Files .= A_LoopFileName "`n"
      }
    }
  }
  
msgbox % Files

Код не проверял, просто для примера.

AHK: Поиск файлов по списку из текстового файла

null@example.com (BlackCat) — Wed, 10 Mar 2021 07:36:40 +0000

Добрый день всем!
Пытаюсь сделать скрипт, который будет искать файлы, имена которых находятся в текстовом файле.
Повод: это универсальный метод поиска нужных директорий и фалов, т.к. гораздо быстрее отредактировать текстовой файл, чем редактировать весь скрипт.
К тому же, он может быть скомпилирован в *.exe файл, который не поддается редактированию штатными средствами.
К примеру, файл списка "List.txt" содержит следующие имена файлов:

EULA.txt
ListDevices.txt
setup.cfg
setup.exe

Такой код для поиска имеющихся в списке файлов работает:

List := "List.txt"

Loop read, % List
	{
	Loop % SourceDir "\*", 0, 1
		{
		If (A_LoopFileName = A_LoopReadLine){
			Files .= A_LoopFileName "`n"
			}
		}
	}
	
msgbox % Files

Следующая конструкция, которая по идее должна исключить эти файлы из поиска, не работает:

List := "List.txt"

Loop read, % List
	{
	Loop % SourceDir "\*", 0, 1
		{
		If (A_LoopFileName != A_LoopReadLine) {
			Files .= A_LoopFileName "`n"
			}
		}
	}
	
msgbox % Files

Не подскажете, в чем причина и как правильно сделать срипт, который будет исключать из поиска файлы в списке?
Признателен за любую помощь!