Серый форум — AHK: array flat

Re: AHK: array flat

null@example.com (teadrinker) — Mon, 05 Apr 2021 21:21:27 +0000

Вот так с указанием уровня вложенности:

FlatArray(arr, depth := 0xFFFFFFFF) {
   if (depth = 0)
      Return arr
   Loop % len := arr.Count() {
      i := len - A_Index + 1
      if IsObject(arr[i])
         arr.InsertAt(i, FlatArray(arr.RemoveAt(i), depth - 1)*)
   }
   Return arr
}

Re: AHK: array flat

null@example.com (teadrinker) — Mon, 05 Apr 2021 19:30:13 +0000

Если нужно раскрывать независимо от уровня вложенности, то так:

arr := [1, 2, [3, 4, [5, 6, [7, 8]]]]
arrayFlat(arr)
for k, v in arr
   str .= (str ? ", " : "") . v
MsgBox, % str

arrayFlat(arr) {
   Loop % len := arr.Count() {
      i := len - A_Index + 1
      if IsObject(item := arr[i]) {
         arr.RemoveAt(i)
         arr.InsertAt(i, arrayFlat(item)*)
      }
   }
   Return arr
}

AHK: array flat

null@example.com (Phoenixxx_Czar) — Mon, 05 Apr 2021 15:28:17 +0000

Пытаюсь сделать из массива:

[1, 2, [1, 3]]

Массив:

[1, 2, 1, 3]

Но что-то я подтупливаю:

arrayFlat(arr)
{
	newArr := []

	for i, v in arr
	{
		newArr.Push(IsObject(v) ? arrayFlat(v) : v)
	}

	return newArr
}

UPD: Получилось что-то такое, как можно улучшить?

arrayFlat(arr, result := "")
{
	if (!result)
	{
		result := []
	}

	for k, v in arr
	{
		if (isObject(v))
		{
			arrayFlat(v, result)
		}
		else
		{
			result.Push(v)
		}
	}

	return result
}