Серый форум — AHK: Изображение поверх окна и взаимодействие с ним.

Re: AHK: Изображение поверх окна и взаимодействие с ним.

null@example.com (Morux2112) — Wed, 05 May 2021 19:17:32 +0000

teadrinker, большое спасибо.

Re: AHK: Изображение поверх окна и взаимодействие с ним.

null@example.com (teadrinker) — Wed, 05 May 2021 17:26:30 +0000

Можно так:

#UseHook
X_Text := 500
Y_Text := 300
fontName := "Calibri"
fontSize := 64
fontColor := 0x4682B4

Gui, Text: New, +LastFound +Owner -Caption +AlwaysOnTop +E0x20
Gui, Margin, 0, 0
Gui, Font, s%fontSize% q4 c%fontColor%, %fontName%
Gui, Color, FFFFFF
WinSet, Transcolor, FFFFFF
Gui, Add, Text
Return

F1::
   if (t := !t) {
      Hook := InputHook()
      Hook.KeyOpt("{All}", "N")
      Hook.OnKeyDown := Func("OnKeyDown").Bind(X_Text, Y_Text, fontSize, fontName)
      Hook.Start()
   }
   else {
      Gui, Text:Show, Hide
      Hook.Stop()
   }
   Return

Esc:: ExitApp

OnKeyDown(X_Text, Y_Text, fontSize, fontName, Hook, vk, sc) {
   text := Hook.Input
   if (text = "") {
      Gui, Text:Show, Hide
      Return
   }
   Gui, New
   Gui, Font, s%fontSize% q4, %fontName%
   Gui, Add, Text,, % text
   GuiControlGet, Pos, Pos, Static1
   Gui, Destroy
   
   Gui, Text: Default
   GuiControl, Move, Static1, w%PosW% h%PosH%
   GuiControl,, Static1, % text
   Gui, Show, NA x%X_Text% y%Y_Text% w%PosW% h%PosH%
}

По F1 переключение в режим записи на экране.

Re: AHK: Изображение поверх окна и взаимодействие с ним.

null@example.com (Morux2112) — Wed, 05 May 2021 16:29:06 +0000

teadrinker, только сейчас появилась возможность протестировать ahk. Возможно ли печатать текст, не выводя gui окно?

Re: AHK: Изображение поверх окна и взаимодействие с ним.

null@example.com (teadrinker) — Tue, 04 May 2021 16:17:49 +0000

Не стоит ради одной строчки цитировать весь предыдущий пост, используйте кнопку «Ответить».

Morux2112 пишет:

А на счёт "перескакивания" на следующую строчку, на определённые координаты?

Я не очень представляю, как вы видите работу скрипта, но если требуется на экране удерживать текст в разных координатах, придётся создать ещё одно окно, такое как Gui, Text, и показывать его в нужном месте.

Re: AHK: Изображение поверх окна и взаимодействие с ним.

null@example.com (Morux2112) — Tue, 04 May 2021 15:52:34 +0000

Благодарю. А на счёт "перескакивания" на следующую строчку, на определённые координаты?

Re: AHK: Изображение поверх окна и взаимодействие с ним.

null@example.com (teadrinker) — Tue, 04 May 2021 13:06:51 +0000

Вот простой пример, как можно интерактивно писать текст на экране:

X_Text := 500
Y_Text := 500
fontName := "Calibri"
fontSize := 64
fontColor := 0x4682B4

Gui, Text: New, +LastFound +Owner -Caption +AlwaysOnTop +E0x20
Gui, Margin, 0, 0
Gui, Font, s%fontSize% q4 c%fontColor%, %fontName%
Gui, Color, FFFFFF
WinSet, Transcolor, FFFFFF
Gui, Add, Text

Gui, New,, Enter your text here
Gui, Add, Edit, w300 h100 gWriteText
Gui, Show, x0 y0
Return

GuiClose:
   ExitApp

WriteText:
   GuiControlGet, Edit1
   if (Edit1 = "") {
      Gui, Text:Show, Hide
      Return
   }
   Gui, New
   Gui, Font, s%fontSize% q4, %fontName%
   Gui, Add, Text,, % Edit1
   GuiControlGet, Pos, Pos, Static1
   Gui, Destroy
   Gui, Text: Default
   GuiControl, Move, Static1, w%PosW% h%PosH%
   GuiControl,, Static1, % Edit1
   Gui, Show, NA x%X_Text% y%Y_Text% w%PosW% h%PosH%
   Return

Правда, качество отрисовки не идеальное. Чтобы его улучшить, нужно использовать GDIPlus с помощью библиотеки Gdip.ahk.

Re: AHK: Изображение поверх окна и взаимодействие с ним.

null@example.com (Morux2112) — Mon, 03 May 2021 12:41:57 +0000

teadrinker, исправил

Re: AHK: Изображение поверх окна и взаимодействие с ним.

null@example.com (teadrinker) — Mon, 03 May 2021 10:23:12 +0000

А ссылку всё-таки не хотите поправить?

Re: AHK: Изображение поверх окна и взаимодействие с ним.

null@example.com (Morux2112) — Mon, 03 May 2021 10:20:27 +0000

Вопрос стоит в том, как выводить текст в определённых координатах, напечатанный в реальном времени, и при нажатии на ентер переходит на следующие координаты, где так же печатается текст.

Re: AHK: Изображение поверх окна и взаимодействие с ним.

null@example.com (teadrinker) — Sun, 02 May 2021 21:53:13 +0000

Вот теперь правильно, можете оформить, как положено.

Re: AHK: Изображение поверх окна и взаимодействие с ним.

null@example.com (teadrinker) — Sun, 02 May 2021 21:45:38 +0000

На этом форуме в ссылках scriptcoding через дефис. Вы её вручную, что ли писали? Можно было скопировать-вставить.

Re: AHK: Изображение поверх окна и взаимодействие с ним.

null@example.com (Morux2112) — Sun, 02 May 2021 21:45:32 +0000

Morux2112 пишет:

Например, на выведенном изображении нажал на определённое место для ввода какого-то текста. После нажатия уже можно спокойно вводить нужный текст.

Еще можно так: после активации нужно вводить текст в одно место, после нажатия на ентер - переходит к следующему.

Re: AHK: Изображение поверх окна и взаимодействие с ним.

null@example.com (Morux2112) — Sun, 02 May 2021 21:42:44 +0000

teadrinker, странно, вставляю ссылку на тему с этого же форума, но ведёт непонятно куда. Вставил в скобки.

Re: AHK: Изображение поверх окна и взаимодействие с ним.

null@example.com (teadrinker) — Sun, 02 May 2021 21:29:29 +0000

Morux2112, ваша ссылка непонятно куда ведёт.

AHK: Изображение поверх окна и взаимодействие с ним.

null@example.com (Morux2112) — Sun, 02 May 2021 20:59:32 +0000

Доброй ночи. Нашел такую тему. Там сказано, как вывести изображение на экран поверх других окон. Но, можно ли сделать так, чтобы выводилось определённое изображение, высвечивался курсор и ты уже мог с ним взаимодействовать. Например, на выведенном изображении нажал на определённое место для ввода какого-то текста. После нажатия уже можно спокойно вводить нужный текст. В принципе реализовать вышеперечисленное не сложно, но есть пару момент. Как сделать, чтобы при вводе текста он сразу же отображался на изображении? И как вывести курсор, например, во время игры?