Серый форум — AHK: Залипание при недолгом нажатии клавиши.

Re: AHK: Залипание при недолгом нажатии клавиши.

null@example.com (__Михаил__) — Sun, 16 May 2021 00:53:44 +0000

Сварганил интерфейс с настройками:

#SingleInstance Force	;16.05.2021	http://forum.script-coding.com/viewtopic.php?id=16354
#NoEnv
SetBatchLines -1
;-----------
Global Info, Info := {}
;-----------
Gui +Caption +LastFound +SysMenu +ToolWindow +AlwaysOnTop
Gui Color, 0x997799
Gui Add, Button, vBT gSW x115 y40 w70 h23, Запуск
Gui Add, Edit, vKeys x64 y8 w120 h21, Все
Gui Add, Text, x8 y8 w50 h23 +0x200, Клавиши:
Gui Add, Edit, vDelay x72 y40 w40 h21 +Number, 2000
Gui Add, Text, x8 y40 w55 h23, Задержка:
Gui Show, w191 h66, [Авто-нажатие клавиш]
Return
;-----------
GuiEscape:
GuiClose:
ExitApp
;-----------
SW:
Gui, Submit, NoHide
If (SW := !SW){
 Info["Delay"] := Delay
 Hook := InputHook("V")
 If (Keys = "Все")
  Keys = {All}
 Hook.KeyOpt(Keys, "N")
 Hook.OnKeyDown := Func("OnKeyDown")
 Hook.OnKeyUp := Func("OnKeyUp")
 Hook.Start()
 GuiControl,, BT, Стоп
 GuiControl, Disable, Keys
 GuiControl, Disable, Delay
}
Else{
 Hook.Stop()
 GuiControl,, BT, Запуск
 GuiControl, Enable, Keys
 GuiControl, Enable, Delay
}
Return
;-----------
OnKeyDown(Hook, vk, sc) {
 if !Info[vk . sc]
  Info[vk . sc] := A_TickCount
 else if (!Info.timer && A_TickCount - Info[vk . sc] > Info.delay) {
  Timer := Info.timer := Func("SendKey").Bind( Format("vk{:x}sc{:x}", vk, sc) )
  SetTimer, % Timer, 30
  SoundBeep
 }
}

OnKeyUp(Hook, vk, sc) {
 if !Info.timer
  Info[vk . sc] := ""
 else {
  if !Info.once
   Info.once := true
  else {
   Timer := Info.timer
   SetTimer, % Timer, Delete
   Info[vk . sc] := Info.once := Info.timer := ""
   Sleep, 30
   Send % "{" . Format("vk{:x}sc{:x}", vk, sc) . " Up}"
  }
 }
}

SendKey(key){
 Send {%key% Down}
}

;-----------
F4:: ExitApp
F6:: Reload

Re: AHK: Залипание при недолгом нажатии клавиши.

null@example.com (teadrinker) — Sun, 16 May 2021 00:07:47 +0000

Не вижу особого геморроя. Когда вместо того, чтобы делать переменную глобальной, она передаётся через параметр, то сразу понятно, откуда она взялась и как тут появилась. Когда код большой, это может быть критично.

Re: AHK: Залипание при недолгом нажатии клавиши.

null@example.com (__Михаил__) — Sun, 16 May 2021 00:03:32 +0000

Снова отсылка на то, что глобальные переменные = зло?
Но тут лишний геморрой с установкой массива 'Info' в функции.

Re: AHK: Залипание при недолгом нажатии клавиши.

null@example.com (teadrinker) — Sat, 15 May 2021 23:53:11 +0000

Немного подправил код, переменная sticky лишней оказалась.
Bind здесь используется для того, чтобы передать лишний параметр в OnKeyDown и OnKeyUp. Изначально там по три параметра:

The function is passed the following parameters: InputHook, VK, SC

Я с помощью Bind передаю ещё один — объект Info, в который записываются данные. Параметры, передаваемые с помощью Bind, помещаются перед остальными параметрами:

OnKeyUp(Info, Hook, vk, sc)

Вместо этого можно было бы объявить объект Info глобальным.

Re: AHK: Залипание при недолгом нажатии клавиши.

null@example.com (__Михаил__) — Sat, 15 May 2021 23:38:32 +0000

В целом, разбирая логику вашего кода становится понятно что и как устроено.
Разве что про '.Bind' хотелось бы узнать побольше.

Re: AHK: Залипание при недолгом нажатии клавиши.

null@example.com (teadrinker) — Sat, 15 May 2021 23:28:30 +0000

__Михаил__, давайте по порядку, я так не понимаю, на что отвечать. Что первое не понятно?

Re: AHK: Залипание при недолгом нажатии клавиши.

null@example.com (__Михаил__) — Sat, 15 May 2021 23:10:03 +0000

teadrinker
Как применить я понял сразу - '{All}' мне известно давно, ещё когда изучал этот тип перехвата в своей теме.
Другое дело, что используется таймер, но через использование объекта / функции. Да ещё и '.Bind' который я так понимаю указывает параметры для вызова в функции что будет выполняться.
Чтобы собрать такую конструкцию нужно понимать как это всё работает, только вот где про это нормально написано? В стандартной справке есть один пример, да и то через Класс.

Re: AHK: Залипание при недолгом нажатии клавиши.

null@example.com (__Михаил__) — Sat, 15 May 2021 22:47:12 +0000

SHOX
Рассчитано только для клавиш мыши (ЛКМ и ПКМ).

Re: AHK: Залипание при недолгом нажатии клавиши.

null@example.com (teadrinker) — Sat, 15 May 2021 21:40:48 +0000

Рад помочь!

Re: AHK: Залипание при недолгом нажатии клавиши.

null@example.com (SHOX) — Sat, 15 May 2021 21:38:55 +0000

teadrinker Очень благодарен! Спасибо.

Re: AHK: Залипание при недолгом нажатии клавиши.

null@example.com (teadrinker) — Sat, 15 May 2021 21:29:28 +0000

Замените {All} на клавишу/список клавиш, которые нужны, как описано здесь. Например, для клавиш a, b, и c так:

Hook.KeyOpt("abc", "N")

Re: AHK: Залипание при недолгом нажатии клавиши.

null@example.com (SHOX) — Sat, 15 May 2021 21:17:27 +0000

__Михаил__ Спасибо большое за попытку но к сожалению как то не работает.
teadrinker Спасибо. Ваш код работает как нужно. Единственно можно как-то его применить к определенной кнопке а не на всю клавиатуру сразу?

Re: AHK: Залипание при недолгом нажатии клавиши.

null@example.com (teadrinker) — Sat, 15 May 2021 20:42:12 +0000

Просто запустите скрипт, откройте блокнот, удерживайте любую печатную клавишу в течение двух секунд (до сигнала SoundBeep).

Re: AHK: Залипание при недолгом нажатии клавиши.

null@example.com (__Михаил__) — Sat, 15 May 2021 20:23:17 +0000

Слишком сложно для понимания.

Re: AHK: Залипание при недолгом нажатии клавиши.

null@example.com (teadrinker) — Sat, 15 May 2021 20:06:40 +0000

Для клавиатуры так можно:

Info := {delay: 2000}

Hook := InputHook("V")
Hook.KeyOpt("{All}", "N")
Hook.OnKeyDown := Func("OnKeyDown").Bind(Info)
Hook.OnKeyUp := Func("OnKeyUp").Bind(Info)
Hook.Start()
Return

OnKeyDown(Info, Hook, vk, sc) {
   if !Info[vk . sc]
      Info[vk . sc] := A_TickCount
   else if (!Info.timer && A_TickCount - Info[vk . sc] > Info.delay) {
      Timer := Info.timer := Func("SendKey").Bind( Format("vk{:x}sc{:x}", vk, sc) )
      SetTimer, % Timer, 30
      SoundBeep
   }
}

OnKeyUp(Info, Hook, vk, sc) {
   if !Info.timer
      Info[vk . sc] := ""
   else {
      if !Info.once
         Info.once := true
      else {
         Timer := Info.timer
         SetTimer, % Timer, Delete
         Info[vk . sc] := Info.once := Info.timer := ""
         Sleep, 30
         Send % "{" . Format("vk{:x}sc{:x}", vk, sc) . " Up}"
      }
   }
}

SendKey(key) {
   Send {%key% Down}
}