Re: AHK: Привязка скрипта ко времени OC Windows

null@example.com (Foma) — Sun, 23 May 2021 11:55:38 +0000

Ну, тут бы ещё защиту от повторного срабатывания. А то он будет мигать почти минуту. Вот так будет 4 секунды сигнализировать.

Loop
	{
	If A_Min = 45
	If (A_Sec < 5)
		{
		Tooltip, Сейчас 45 минут!
		Sleep, 1000
		Tooltip
		}
	Sleep, 20
	}

Re: AHK: Привязка скрипта ко времени OC Windows

null@example.com (ypppu) — Sun, 23 May 2021 11:18:40 +0000

Loop
{
If A_Min = 45
	{
	Tooltip, Сейчас 45 минут!
	Sleep, 1000
	Tooltip
	}
Else Sleep, 1000
}

AHK: Привязка скрипта ко времени OC Windows

null@example.com (dimkacum) — Sun, 23 May 2021 10:04:59 +0000

Здравствуйте можно ли привязать скрипт ко времени OC Windows?
Если да то каким образом это можно реализовать?
Мне просто нужно чтоб не зависимости от времени если на часах будет 45 минут, то он должен делать какое то действие.
Код который находится ниже увидел у вас на форуме но не могу понять как он работает.


#SingleInstance Force
#Persistent
#NoEnv

Times := ["01:00","00:59:50"] 
NewTimer(Times)
Return

NewTimer(Arr)  {
	For k, value in Arr
		odds := DifferenceTime(value)
		, (!Min || Min > odds) 
		&& (Min := odds, Time := value) 
	hFunc := Func("Timer").Bind(Time, Arr)
	SetTimer, % hFunc, % -Min
	TrayTip, % "Следующий в:", % "`n" Time "`n`nЧерез:`n`n" FormatTime(Min) 
}

Timer(Time, List)  {
	MsgBox, , , % Time, 1
	NewTimer(List)
}

DifferenceTime(Time)  {
	T := StrSplit(Time, ":")
    Time := Time2 := A_YYYY A_MM A_DD T[1] T[2] (T[3] ? T[3] : "00")
    EnvSub, Time, A_Now, Second
    Time := (Time * 1000) - A_MSec
    If Time >= 0
        Return Time
    Time2 += 1, days
    EnvSub, Time2, A_Now, Second
    Return (Time2 * 1000) - A_MSec
}

FormatTime(Time)  {
	Rest := Mod(Time, 3600000)
	Hours := Format("{:02}", Time // 3600000)
	Min := Format("{:02}", Rest // 60000)
	Sec := Format("{:02}", Mod(Rest, 60000) // 1000)
	MSec := Format("{:03}", Mod(Rest, 1000)) 
	Return Hours ":" Min ":" Sec "," MSec
}

Серый форум — AHK: Привязка скрипта ко времени OC Windows

Re: AHK: Привязка скрипта ко времени OC Windows

Re: AHK: Привязка скрипта ко времени OC Windows

AHK: Привязка скрипта ко времени OC Windows