Серый форум — AHK: получить координаты мышки как в AhkSpy

Re: AHK: получить координаты мышки как в AhkSpy

2021-08-10T12:27:29Z

Предыдущий вариант.

Re: AHK: получить координаты мышки как в AhkSpy

2021-08-10T08:35:22Z

teadrinker так тоже работает, как предпочтительней? Что быстрее работает и меньше нагружает пк?

Re: AHK: получить координаты мышки как в AhkSpy

2021-08-10T08:29:49Z

Эти кнопки не являются контролами. Можно так:

~LButton::
   CoordMode, Mouse
   MouseGetPos, X, Y
   AccObj := AccObjectFromPoint(child)
   Pos := AccLocation(AccObj, child)
   ToolTip, % "X: " . X - Pos.x . " Y:" . Y - Pos.y
   Return

AccObjectFromPoint(ByRef _idChild_ = "", x = "", y = "") {
   static VT_DISPATCH := 9, F_OWNVALUE := 1, h := DllCall("LoadLibrary", "Str", "oleacc", "Ptr")
   
   AccObject := 0
   (x = "" || y = "") ? DllCall("GetCursorPos", "Int64P", pt) : pt := x & 0xFFFFFFFF | y << 32
   VarSetCapacity(varChild, 8 + 2*A_PtrSize, 0)
   if	DllCall("oleacc\AccessibleObjectFromPoint", "Int64", pt, "PtrP", pAcc, "Ptr", &varChild) = 0
      _idChild_ := NumGet(varChild, 8, "UInt"), AccObject := ComObject(VT_DISPATCH, pAcc, F_OWNVALUE)
   Return AccObject
}

AccLocation(Acc, ChildId := 0, ByRef Position := "") {
   static type := (VT_BYREF := 0x4000) | (VT_I4 := 3)
   try Acc.accLocation( ComObject(type, &x := 0), ComObject(type, &y := 0)
                      , ComObject(type, &w := 0), ComObject(type, &h := 0), ChildId )
   catch
      Return
   _x := NumGet(x, "int"), _y := NumGet(y, "int"), _w = NumGet(w, "int"), _h := NumGet(h, "int")
   Position := "x" . _x . " y" . _y . " w" . _w . " h" . _h
   Return {x: _x, y: _y, w: _w, h: _h}
}

Re: AHK: получить координаты мышки как в AhkSpy

2021-08-10T08:28:33Z

teadrinker спасибо ещё раз, чуть подправил ваш вариант, перешел - на ahk_id и получил то, что хотел.

mButton::
   CoordMode, Mouse
   MouseGetPos, x, y,ahk_id, hCtrl, 2
   WinGetPos, xCtrl, yCtrl,,, ahk_id %ahk_id%
   ToolTip, % "X: " . x - xCtrl . " Y:" . y - yCtrl "`n" "x:" x "`n" "xctrl:" xctrl "`n" "hCtrl:" hCtrl "`n" "ahk_id:" ahk_id
   Return

Re: AHK: получить координаты мышки как в AhkSpy

2021-08-10T08:15:03Z

MouseGetPos, x, y,, hCtrl, 2

hCtrl выдаёт пустое значение над кнопками.

Re: AHK: получить координаты мышки как в AhkSpy

2021-08-10T08:12:15Z

Проверил, xCtrl над кнопками выдаёт пустое значение, в другой области окна получает значение.
DetectHiddenWindows, on не помогает.

Re: AHK: получить координаты мышки как в AhkSpy

2021-08-10T07:42:43Z

teadrinker да, вы правы, не полностью повторил ваш код - в тултип вывел координаты с wingetpos.
Если полностью повторить ваш вариант, то в тултипе пустые координаты.

Re: AHK: получить координаты мышки как в AhkSpy

2021-08-10T07:05:32Z

Этот код показывает именно положение курсора относительно верхнего левого угла контрола, над которым он находится.

Re: AHK: получить координаты мышки как в AhkSpy

2021-08-10T06:54:09Z

teadrinker Спасибо, так получил размер другой области - уже существенный прогресс, но мне нужно положение курсора мышки в этой области, чтобы знать над какой кнопкой мышка находится.

Re: AHK: получить координаты мышки как в AhkSpy

2021-08-10T00:38:11Z

Попробуйте так:

~LButton::
   CoordMode, Mouse
   MouseGetPos, x, y,, hCtrl, 2
   WinGetPos, xCtrl, yCtrl,,, ahk_id %hCtrl%
   ToolTip, % "X: " . x - xCtrl . " Y:" . y - yCtrl
   Return

AHK: получить координаты мышки как в AhkSpy

2021-08-09T23:27:24Z

Здравствуйте, в окне есть 2 области с разными ahk_id, AhkSpy определяет позицию мышки в соответствии положения мышки в области.
Но когда я использую mousegetpos, то получаю координаты позиции в соответствии с полным размером окна.
CoordMode, Mouse, Client ничего не меняет. Стандартный Active Window Info также не меняет координаты для разных методов CoordMode.
Как получить координаты мышки как в AhkSpy а именно - как в скрине х = 25?