Серый форум — AHK: неправильно работает код при русской раскладке клавиатуры

Re: AHK: неправильно работает код при русской раскладке клавиатуры

2021-10-27T10:17:19Z

teadrinker, работает, спасибо!

Re: AHK: неправильно работает код при русской раскладке клавиатуры

2021-10-27T10:15:59Z

__Михаил__ увы, не сработало

Re: AHK: неправильно работает код при русской раскладке клавиатуры

2021-10-26T21:43:59Z

На первых порах можно использовать без понимания. Нужно только получать объект Excel.Application

Excel := Excel_Get()

Excel_Get(WinTitle := "ahk_class XLMAIN") {
   ControlGet, hwnd, hwnd,, Excel71, %WinTitle%
   if !hwnd
      return
   Window := AccObjectFromWindow(hwnd, -16)
   Loop {
      try Application := Window.Application
      catch
         ControlSend, Excel71, {esc}, %WinTitle%
   } Until !!Application
   return Application
}

AccObjectFromWindow(hWnd, idObject = 0)
{
   static IID_IDispatch   := "{00020400-0000-0000-C000-000000000046}"
        , IID_IAccessible := "{618736E0-3C3D-11CF-810C-00AA00389B71}"
        , OBJID_NATIVEOM  := 0xFFFFFFF0, VT_DISPATCH := 9, F_OWNVALUE := 1
        , h := DllCall("LoadLibrary", "Str", "oleacc", "Ptr")
        
   VarSetCapacity(IID, 16), idObject &= 0xFFFFFFFF
   DllCall("ole32\CLSIDFromString", "Str", idObject = OBJID_NATIVEOM ? IID_IDispatch : IID_IAccessible, "Ptr", &IID)
   if DllCall("oleacc\AccessibleObjectFromWindow", "Ptr", hWnd, "UInt", idObject, "Ptr", &IID, "PtrP", pAcc) = 0
      Return ComObjEnwrap(VT_DISPATCH, pAcc, F_OWNVALUE)
}

и использовать его.
Ознакомьтесь, пожалуйста, с правилами. Обратите внимание на точки в конце предложений и правила цитирования. Я отредактировал ваш пост.

Re: AHK: неправильно работает код при русской раскладке клавиатуры

2021-10-26T21:34:51Z

teadrinker пишет:

По идее ^c должно работать, если у вас последняя версия AHK.

Да, версия старая. Нужно чтобы работало именно на старой версии, с установкой новой версии почему-то возникают проблемы.

teadrinker пишет:

А вообще лучше так:

Уххх, ну прям хардкор какой-то. Понять бы еще это.
Завтра, как попробую - отпишусь.

Re: AHK: неправильно работает код при русской раскладке клавиатуры

2021-10-26T21:16:16Z

А вообще лучше так:

MsgBox, % GetSelectedCellText()      

GetSelectedCellText() {
   if !IsObject( Excel := Excel_Get() ) {
      MsgBox, Failed to get Excel Application object!
      return
   }
   Return Excel.Selection.Cells[1].text
}

Excel_Get(WinTitle := "ahk_class XLMAIN") {
   ControlGet, hwnd, hwnd,, Excel71, %WinTitle%
   if !hwnd
      return
   Window := AccObjectFromWindow(hwnd, -16)
   Loop {
      try Application := Window.Application
      catch
         ControlSend, Excel71, {esc}, %WinTitle%
   } Until !!Application
   return Application
}

AccObjectFromWindow(hWnd, idObject = 0)
{
   static IID_IDispatch   := "{00020400-0000-0000-C000-000000000046}"
        , IID_IAccessible := "{618736E0-3C3D-11CF-810C-00AA00389B71}"
        , OBJID_NATIVEOM  := 0xFFFFFFF0, VT_DISPATCH := 9, F_OWNVALUE := 1
        , h := DllCall("LoadLibrary", "Str", "oleacc", "Ptr")
        
   VarSetCapacity(IID, 16), idObject &= 0xFFFFFFFF
   DllCall("ole32\CLSIDFromString", "Str", idObject = OBJID_NATIVEOM ? IID_IDispatch : IID_IAccessible, "Ptr", &IID)
   if DllCall("oleacc\AccessibleObjectFromWindow", "Ptr", hWnd, "UInt", idObject, "Ptr", &IID, "PtrP", pAcc) = 0
      Return ComObjEnwrap(VT_DISPATCH, pAcc, F_OWNVALUE)
}

Re: AHK: неправильно работает код при русской раскладке клавиатуры

2021-10-26T21:01:34Z

По идее ^c должно работать, если у вас последняя версия AHK.

Re: AHK: неправильно работает код при русской раскладке клавиатуры

2021-10-26T20:21:40Z

__Михаил__ попробую, завтра напишу по результатам.
Я еще нашел такой вариант:

Send ^{vk43}

Re: AHK: неправильно работает код при русской раскладке клавиатуры

2021-10-26T18:01:24Z

Попробуйте так:

Send, ^{c}

AHK: неправильно работает код при русской раскладке клавиатуры

2021-10-26T17:55:58Z

Задача скопировать в буфер выделенную мышкой ячейку в excel. При англ. раскладке все отлично. Но при русской - сочетание alt+x срабатывает, однако скрипт вводит в ячейку символ 'c' и неудачно её копирует (ErrorLevel).
Как исправить?
Код:


!x::
	kd1 := ""
	Clipboard =         ;Сделать Буфер обмена пустым
	Send, ^c
	ClipWait, 2
	if ErrorLevel <> 0
	{
		MsgBox, Попытка скопировать текст в буфер обмена неудачна.
		Return
	}
	
	cl = %clipboard%
return