Серый форум — AHK: неправильно работает код при русской раскладке клавиатуры

Re: AHK: неправильно работает код при русской раскладке клавиатуры

null@example.com (CyberGudini) — Wed, 27 Oct 2021 10:17:19 +0000

teadrinker, работает, спасибо!

Re: AHK: неправильно работает код при русской раскладке клавиатуры

null@example.com (CyberGudini) — Wed, 27 Oct 2021 10:15:59 +0000

__Михаил__ увы, не сработало

Re: AHK: неправильно работает код при русской раскладке клавиатуры

null@example.com (teadrinker) — Tue, 26 Oct 2021 21:43:59 +0000

На первых порах можно использовать без понимания. Нужно только получать объект Excel.Application

Excel := Excel_Get()

Excel_Get(WinTitle := "ahk_class XLMAIN") {
   ControlGet, hwnd, hwnd,, Excel71, %WinTitle%
   if !hwnd
      return
   Window := AccObjectFromWindow(hwnd, -16)
   Loop {
      try Application := Window.Application
      catch
         ControlSend, Excel71, {esc}, %WinTitle%
   } Until !!Application
   return Application
}

AccObjectFromWindow(hWnd, idObject = 0)
{
   static IID_IDispatch   := "{00020400-0000-0000-C000-000000000046}"
        , IID_IAccessible := "{618736E0-3C3D-11CF-810C-00AA00389B71}"
        , OBJID_NATIVEOM  := 0xFFFFFFF0, VT_DISPATCH := 9, F_OWNVALUE := 1
        , h := DllCall("LoadLibrary", "Str", "oleacc", "Ptr")
        
   VarSetCapacity(IID, 16), idObject &= 0xFFFFFFFF
   DllCall("ole32\CLSIDFromString", "Str", idObject = OBJID_NATIVEOM ? IID_IDispatch : IID_IAccessible, "Ptr", &IID)
   if DllCall("oleacc\AccessibleObjectFromWindow", "Ptr", hWnd, "UInt", idObject, "Ptr", &IID, "PtrP", pAcc) = 0
      Return ComObjEnwrap(VT_DISPATCH, pAcc, F_OWNVALUE)
}

и использовать его.
Ознакомьтесь, пожалуйста, с правилами. Обратите внимание на точки в конце предложений и правила цитирования. Я отредактировал ваш пост.

Re: AHK: неправильно работает код при русской раскладке клавиатуры

null@example.com (CyberGudini) — Tue, 26 Oct 2021 21:34:51 +0000

teadrinker пишет:

По идее ^c должно работать, если у вас последняя версия AHK.

Да, версия старая. Нужно чтобы работало именно на старой версии, с установкой новой версии почему-то возникают проблемы.

teadrinker пишет:

А вообще лучше так:

Уххх, ну прям хардкор какой-то. Понять бы еще это.
Завтра, как попробую - отпишусь.

Re: AHK: неправильно работает код при русской раскладке клавиатуры

null@example.com (teadrinker) — Tue, 26 Oct 2021 21:16:16 +0000

А вообще лучше так:

MsgBox, % GetSelectedCellText()      

GetSelectedCellText() {
   if !IsObject( Excel := Excel_Get() ) {
      MsgBox, Failed to get Excel Application object!
      return
   }
   Return Excel.Selection.Cells[1].text
}

Excel_Get(WinTitle := "ahk_class XLMAIN") {
   ControlGet, hwnd, hwnd,, Excel71, %WinTitle%
   if !hwnd
      return
   Window := AccObjectFromWindow(hwnd, -16)
   Loop {
      try Application := Window.Application
      catch
         ControlSend, Excel71, {esc}, %WinTitle%
   } Until !!Application
   return Application
}

AccObjectFromWindow(hWnd, idObject = 0)
{
   static IID_IDispatch   := "{00020400-0000-0000-C000-000000000046}"
        , IID_IAccessible := "{618736E0-3C3D-11CF-810C-00AA00389B71}"
        , OBJID_NATIVEOM  := 0xFFFFFFF0, VT_DISPATCH := 9, F_OWNVALUE := 1
        , h := DllCall("LoadLibrary", "Str", "oleacc", "Ptr")
        
   VarSetCapacity(IID, 16), idObject &= 0xFFFFFFFF
   DllCall("ole32\CLSIDFromString", "Str", idObject = OBJID_NATIVEOM ? IID_IDispatch : IID_IAccessible, "Ptr", &IID)
   if DllCall("oleacc\AccessibleObjectFromWindow", "Ptr", hWnd, "UInt", idObject, "Ptr", &IID, "PtrP", pAcc) = 0
      Return ComObjEnwrap(VT_DISPATCH, pAcc, F_OWNVALUE)
}

Re: AHK: неправильно работает код при русской раскладке клавиатуры

null@example.com (teadrinker) — Tue, 26 Oct 2021 21:01:34 +0000

По идее ^c должно работать, если у вас последняя версия AHK.

Re: AHK: неправильно работает код при русской раскладке клавиатуры

null@example.com (CyberGudini) — Tue, 26 Oct 2021 20:21:40 +0000

__Михаил__ попробую, завтра напишу по результатам.
Я еще нашел такой вариант:

Send ^{vk43}

Re: AHK: неправильно работает код при русской раскладке клавиатуры

null@example.com (__Михаил__) — Tue, 26 Oct 2021 18:01:24 +0000

Попробуйте так:

Send, ^{c}

AHK: неправильно работает код при русской раскладке клавиатуры

null@example.com (CyberGudini) — Tue, 26 Oct 2021 17:55:58 +0000

Задача скопировать в буфер выделенную мышкой ячейку в excel. При англ. раскладке все отлично. Но при русской - сочетание alt+x срабатывает, однако скрипт вводит в ячейку символ 'c' и неудачно её копирует (ErrorLevel).
Как исправить?
Код:


!x::
	kd1 := ""
	Clipboard =         ;Сделать Буфер обмена пустым
	Send, ^c
	ClipWait, 2
	if ErrorLevel <> 0
	{
		MsgBox, Попытка скопировать текст в буфер обмена неудачна.
		Return
	}
	
	cl = %clipboard%
return