<![CDATA[Серый форум — AHK: Copy, Paste, назначенные на боковые кнопки мыши не видят объекты]]> https://forum.script-coding.com/viewtopic.php?id=16691 Thu, 28 Oct 2021 16:00:48 +0000 PunBB <![CDATA[Re: AHK: Copy, Paste, назначенные на боковые кнопки мыши не видят объекты]]> https://forum.script-coding.com/viewtopic.php?pid=150280#p150280 Вот теперь четко, спасибо! Код из #7 работает так как надо. Теперь попробую еще погонять его в разных окнах и условиях потом напишу, если будут шероховатости.

]]> Thu, 28 Oct 2021 16:00:48 +0000 https://forum.script-coding.com/viewtopic.php?pid=150280#p150280 <![CDATA[Re: AHK: Copy, Paste, назначенные на боковые кнопки мыши не видят объекты]]> https://forum.script-coding.com/viewtopic.php?pid=150279#p150279 Добавил к коду из #5 строку


XButton1:: send {LCtrl Down}V{LCtrl Up}

теперь копирует объекты в том количестве сколько выделено, т.е. правильно, вставить по XButton1, естественно не получается и все также нет теперь работы с текстом.

]]> Thu, 28 Oct 2021 15:56:57 +0000 https://forum.script-coding.com/viewtopic.php?pid=150279#p150279 <![CDATA[Re: AHK: Copy, Paste, назначенные на боковые кнопки мыши не видят объекты]]> https://forum.script-coding.com/viewtopic.php?pid=150278#p150278 alpap пишет:

вставляется только один последний объект

Так не должно быть, у меня вставляется всё выделенное.

alpap пишет:

теперь не работает с текстом

Чтобы работало и с файлами, и с текстом, можно так:

XButton2::
   if fileList := Explorer_GetSelection()
      PutFilesIntoClipboard(fileList)
   else
      Send ^c
   Return
XButton1:: Send ^v

Explorer_GetSelection() {
   WinGetClass, winClass, % "ahk_id" . hWnd := WinExist("A")
   if !(winClass ~= "^(Progman|WorkerW|(Cabinet|Explore)WClass)$")
      Return
   
   shellWindows := ComObjCreate("Shell.Application").Windows
   if (winClass ~= "Progman|WorkerW")  ; IShellWindows::Item:    https://goo.gl/ihW9Gm
                                       ; IShellFolderViewDual:   https://goo.gl/gnntq3
      shellFolderView := shellWindows.Item( ComObject(VT_UI4 := 0x13, SWC_DESKTOP := 0x8) ).Document
   else {
      for window in shellWindows       ; ShellFolderView object: https://is.gd/eyZ4zG
         if (hWnd = window.HWND) && (shellFolderView := window.Document)
            break
   }
   for item in shellFolderView.SelectedItems
      result .= (result = "" ? "" : "`n") . item.Path
   Return result
}

PutFilesIntoClipboard(fileList) {
   static GHND := 0x42, CF_HDROP := 0xF
   fileList := Trim( RegExReplace(fileList, "\R", "`n"), " `t`r`n" ), RegExReplace(fileList, "\R", "", count)
   VarSetCapacity(DROPFILES, size := 20 + StrLen(fileList) + count + 2, 0)
   NumPut(20, DROPFILES)
   prevLen := 0
   Loop, parse, fileList, `n
      prevLen += StrPut(A_LoopField, &DROPFILES + 20 + prevLen + A_Index - 1, StrLen(A_LoopField), "CP0")
   hMem := DllCall("GlobalAlloc", "UInt", GHND, "Ptr", size, "Ptr")
   pData := DllCall("GlobalLock", "Ptr", hMem, "Ptr")
   DllCall("RtlMoveMemory", "Ptr", pData, "Ptr", &DROPFILES, "Ptr", size)
   DllCall("GlobalUnlock", "Ptr", hMem)
   DllCall("OpenClipboard", "Ptr", 0)
   DllCall("SetClipboardData", "UInt", CF_HDROP, "Ptr", hMem)
   DllCall("CloseClipboard")
}
]]> Thu, 28 Oct 2021 15:52:44 +0000 https://forum.script-coding.com/viewtopic.php?pid=150278#p150278 <![CDATA[Re: AHK: Copy, Paste, назначенные на боковые кнопки мыши не видят объекты]]> https://forum.script-coding.com/viewtopic.php?pid=150277#p150277 Так XButton2 копирует файлы и/или папки, но если вставить, то вставляется только один последний объект (выделяем "aaa1", "aaa2", копируем, вставляем в новое место, на выходе - только "aaa2"). И так включилась противоположная проблема - теперь не работает с текстом.

]]> Thu, 28 Oct 2021 15:46:29 +0000 https://forum.script-coding.com/viewtopic.php?pid=150277#p150277 <![CDATA[Re: AHK: Copy, Paste, назначенные на боковые кнопки мыши не видят объекты]]> https://forum.script-coding.com/viewtopic.php?pid=150275#p150275 Попробуйте так:

XButton2:: PutFilesIntoClipboard( Explorer_GetSelection() )

Explorer_GetSelection() {
   WinGetClass, winClass, % "ahk_id" . hWnd := WinExist("A")
   if !(winClass ~= "^(Progman|WorkerW|(Cabinet|Explore)WClass)$")
      Return
   
   shellWindows := ComObjCreate("Shell.Application").Windows
   if (winClass ~= "Progman|WorkerW")  ; IShellWindows::Item:    https://goo.gl/ihW9Gm
                                       ; IShellFolderViewDual:   https://goo.gl/gnntq3
      shellFolderView := shellWindows.Item( ComObject(VT_UI4 := 0x13, SWC_DESKTOP := 0x8) ).Document
   else {
      for window in shellWindows       ; ShellFolderView object: https://is.gd/eyZ4zG
         if (hWnd = window.HWND) && (shellFolderView := window.Document)
            break
   }
   for item in shellFolderView.SelectedItems
      result .= (result = "" ? "" : "`n") . item.Path
   Return result
}

PutFilesIntoClipboard(fileList) {
   static GHND := 0x42, CF_HDROP := 0xF
   fileList := Trim( RegExReplace(fileList, "\R", "`n"), " `t`r`n" ), RegExReplace(fileList, "\R", "", count)
   VarSetCapacity(DROPFILES, size := 20 + StrLen(fileList) + count + 2, 0)
   NumPut(20, DROPFILES)
   prevLen := 0
   Loop, parse, fileList, `n
      prevLen += StrPut(A_LoopField, &DROPFILES + 20 + prevLen + A_Index - 1, StrLen(A_LoopField), "CP0")
   hMem := DllCall("GlobalAlloc", "UInt", GHND, "Ptr", size, "Ptr")
   pData := DllCall("GlobalLock", "Ptr", hMem, "Ptr")
   DllCall("RtlMoveMemory", "Ptr", pData, "Ptr", &DROPFILES, "Ptr", size)
   DllCall("GlobalUnlock", "Ptr", hMem)
   DllCall("OpenClipboard", "Ptr", 0)
   DllCall("SetClipboardData", "UInt", CF_HDROP, "Ptr", hMem)
   DllCall("CloseClipboard")
}
]]> Thu, 28 Oct 2021 15:23:21 +0000 https://forum.script-coding.com/viewtopic.php?pid=150275#p150275 <![CDATA[Re: AHK: Copy, Paste, назначенные на боковые кнопки мыши не видят объекты]]> https://forum.script-coding.com/viewtopic.php?pid=150273#p150273 alpap, ознакомьтесь, пожалуйста, с правилами, отредактируйте свой пост. Обратите внимание на заглавные буквы в начале предложений.

]]> Thu, 28 Oct 2021 15:12:05 +0000 https://forum.script-coding.com/viewtopic.php?pid=150273#p150273 <![CDATA[Re: AHK: Copy, Paste, назначенные на боковые кнопки мыши не видят объекты]]> https://forum.script-coding.com/viewtopic.php?pid=150272#p150272

если назначать на другие горячие клавиши

Я как-то и не подумал попробовать ...
Попробовал - то же самое, копировать-вставить с помощью назначенных горячих клавиш получается только текст.

]]> Thu, 28 Oct 2021 15:10:32 +0000 https://forum.script-coding.com/viewtopic.php?pid=150272#p150272 <![CDATA[Re: AHK: Copy, Paste, назначенные на боковые кнопки мыши не видят объекты]]> https://forum.script-coding.com/viewtopic.php?pid=150271#p150271 alpap пишет:

Copy, Paste, назначенные на боковые кнопки мыши не видят объекты

То-есть, если назначать на другие горячие клавиши, то нет проблем?

]]> Thu, 28 Oct 2021 14:57:30 +0000 https://forum.script-coding.com/viewtopic.php?pid=150271#p150271 <![CDATA[AHK: Copy, Paste, назначенные на боковые кнопки мыши не видят объекты]]> https://forum.script-coding.com/viewtopic.php?pid=150267#p150267 День добрый!
При использовании такого скрипта:


XButton2:: send {LCtrl Down}C{LCtrl Up}
XButton1:: send {LCtrl Down}V{LCtrl Up}

Т.е. на горячие боковые клавиши (4 и 5) назначены стандартные клавиатурные Copy (Ctrl+C), Paste (Ctrl+V).
Это работает, но только с текстом.
А вот копировать-вставить файлы или папки - увы. Те же комбинации Copy (Ctrl+C), Paste (Ctrl+V), назначенные с помощью программы "Key Manager", работают везде и как с текстом так и объектами.
Есть какой-то выход при использовании AHK в данном случае?

]]> Thu, 28 Oct 2021 13:37:10 +0000 https://forum.script-coding.com/viewtopic.php?pid=150267#p150267