Серый форум — AHK: Изменение громкости только в Хроме [Решено]

Re: AHK: Изменение громкости только в Хроме [Решено]

null@example.com (svoboden) — Wed, 10 Nov 2021 14:47:06 +0000

Хорошо, спасибо.

Re: AHK: Изменение громкости только в Хроме [Решено]

null@example.com (Malcev) — Wed, 10 Nov 2021 14:42:32 +0000

Можно сделать так:

Setbatchlines -1
DllCall("LoadLibrary", "str", "Wtsapi32.dll", "ptr")
DllCall("Wtsapi32\WTSEnumerateProcesses", "ptr", 0, "uint", 0, "uint", 1, "ptr*", pProcessInfo, "uint*", count)
addr := pProcessInfo
Loop % count
{
   if (A_Index = 1)
      var := "System Idle Process"
   else
      var := StrGet(NumGet(addr + 8))
   msgbox % var
   addr += A_PtrSize = 4 ? 16 : 24
}
DllCall("Wtsapi32\WTSFreeMemory", "ptr", pProcessInfo)

Re: AHK: Изменение громкости только в Хроме [Решено]

null@example.com (svoboden) — Wed, 10 Nov 2021 14:12:42 +0000

А так нельзя написать?

 var := StrGet(NumGet(addr + 24))

Чтобы не было пустого значения в начале цикла. Ну это так .

Re: AHK: Изменение громкости только в Хроме [Решено]

null@example.com (svoboden) — Wed, 10 Nov 2021 14:05:11 +0000

Все, заработало. Первый результат пустое значение выдал.

Re: AHK: Изменение громкости только в Хроме [Решено]

null@example.com (Malcev) — Wed, 10 Nov 2021 13:58:11 +0000

Ну не знаю.
У меня на 3 компьютерах выдает нужные значения.

Re: AHK: Изменение громкости только в Хроме [Решено]

null@example.com (svoboden) — Wed, 10 Nov 2021 13:48:44 +0000

Проверил, выдает пустое значения, что в анси, что в юникод.

Re: AHK: Изменение громкости только в Хроме [Решено]

null@example.com (Malcev) — Wed, 10 Nov 2021 13:41:01 +0000

Сравните ваш и правильный.

setbatchlines -1
DllCall("LoadLibrary", "str", "Wtsapi32.dll", "ptr")
DllCall("Wtsapi32\WTSEnumerateProcesses", "ptr", 0, "uint", 0, "uint", 1, "ptr*", pProcessInfo, "uint*", count)
addr := pProcessInfo
Loop % count
{
   var := StrGet(NumGet(addr + 8))
   msgbox % var
   addr += A_PtrSize = 4 ? 16 : 24
}
DllCall("Wtsapi32\WTSFreeMemory", "ptr", pProcessInfo)

Re: AHK: Изменение громкости только в Хроме [Решено]

null@example.com (svoboden) — Wed, 10 Nov 2021 13:34:54 +0000

Так я и не менял его даже. Просто хотел получить имя процесса здесь:

StrGet(NumGet(addr + 8))

У меня всегда пустая строка возвращается. Решил сменить на utf-16, знаки вопроса.

Re: AHK: Изменение громкости только в Хроме [Решено]

null@example.com (Malcev) — Wed, 10 Nov 2021 12:15:55 +0000

Во-первых, вы криво изменили код.
Во-вторых, если в strget кодировку не указывать, то возвращается не utf-16, а ansi.

Re: AHK: Изменение громкости только в Хроме [Решено]

null@example.com (svoboden) — Wed, 10 Nov 2021 06:57:32 +0000

Malcev пишет:

Чтобы перебирать массив с этими структурами.

Понятно. А почему в этой строке:

 if (StrGet(NumGet(addr + 8)) = "chrome.exe")

сравнивается c "chrome.exe". Пробовал так:

setbatchlines -1
DllCall("LoadLibrary", "str", "Wtsapi32.dll", "ptr")

loop 100
{
   DllCall("Wtsapi32\WTSEnumerateProcesses", "ptr", 0, "uint", 0, "uint", 1, "ptr*", pProcessInfo, "uint*", count)
   addr := pProcessInfo
   
      var := StrGet(NumGet(addr + 8), "utf-16")
       msgbox % var

   DllCall("Wtsapi32\WTSFreeMemory", "ptr", pProcessInfo)
}

Возвращает знаки вопроса.

Re: AHK: Изменение громкости только в Хроме [Решено]

null@example.com (__Михаил__) — Tue, 09 Nov 2021 21:12:20 +0000

Malcev
Хорошо, уговорили.

Обновил шапку последней правкой.

Re: AHK: Изменение громкости только в Хроме [Решено]

null@example.com (Malcev) — Tue, 09 Nov 2021 15:38:37 +0000

__Михаил__, по идее меняться не должен, но знаю точно, что у хрома, процесс отвечающий за аудио создается только после начала проигрывания музыки.

Re: AHK: Изменение громкости только в Хроме [Решено]

null@example.com (teadrinker) — Tue, 09 Nov 2021 15:35:46 +0000

Malcev пишет:

А почему у тебя count как ptr, он же dword?

Да, ошибка, должно быть "UIntP".

Re: AHK: Изменение громкости только в Хроме [Решено]

null@example.com (__Михаил__) — Tue, 09 Nov 2021 15:34:22 +0000

Я так понимаю они могут измениться только в случае перезапуска Хрома? Тогда можно оставить так, я обычно не выключаю его.

Re: AHK: Изменение громкости только в Хроме [Решено]

null@example.com (Malcev) — Tue, 09 Nov 2021 15:30:24 +0000

PIDs могут меняться, лучше так.

setbatchlines -1
DllCall("LoadLibrary", "str", "Wtsapi32.dll", "ptr")

f11::
DllCall("Wtsapi32\WTSEnumerateProcesses", "ptr", 0, "uint", 0, "uint", 1, "ptr*", pProcessInfo, "uint*", count)
addr := pProcessInfo, PIDs := []
Loop % count
{
   if (StrGet(NumGet(addr + 8)) = "chrome.exe")
      PIDs[NumGet(addr + 4, "uint")] := 1
   addr += A_PtrSize = 4 ? 16 : 24
}
DllCall("Wtsapi32\WTSFreeMemory", "ptr", pProcessInfo)