; Если первый символ в строке ";", то это комментарий 
; (им можно временно отключать обработку отдельных строк).

; Относительные пути к папкам, начиная с папки программы:
IN\Папка1
IN\Папка3
;IN\Папка4

; Абсолютные пути и расширения в именах папок также работают:
D:\TEST\Папка.Тест

@echo off & title %~nx0 & SetLocal EnableExtensions EnableDelayedExpansion

rem Файл с именами копируемых папок
set "sFileIni=%~n0.ini"

goto :Main
rem ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:Help
  echo.Копирование выбранных папок ^(см. файл !sFileIni!^)
  echo.Вызов : %~nx0 Папка_Куда
  echo.Пример: %~nx0 OUT
  echo.
:PauseEnd
  pause
:End
  exit /b

rem ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:Main

  rem Проверка наличия параметров и файла INI.
  if "%~1"=="" goto :Help
  if not exist "!sFileIni!" echo.*** Не найден файл !sFileIni!! & goto :PauseEnd

  set "sFldOut=%~1\"
  call set "sFldOut=%%sFldOut:\\=\%%" &rem В конце sFldOut будет ровно 1 символ "\"

  for /f "eol=; delims=" %%a in (!sFileIni!) do (
	for %%b in (%%~a) do (
	  set "sFld=%%~nxb\"
	  call set "sFld=%%sFld:\\=\%%" &rem В конце sFld будет ровно 1 символ "\"
	  echo. "%%~a" -^> "!sFldOut!!sFld!"
	  xcopy "%%~a"     "!sFldOut!!sFld!" /e /h /k /r /y >nul
            rem /E Копирует все папки и подпапки, включая пустые.
            rem /H Копирует скрытые и системные файлы.
            rem /R Заменяет файлы, доступные только для чтения.
            rem /K Копирует атрибуты. Простая команда Xcopy сбрасывает атрибут "Только чтение".
            rem /Y Подавляет запрос на подтверждение перезаписи существующего конечного файла.
  	)
  )

Endlocal
exit /b