Серый форум — AHK: Составление анаграмм

Re: AHK: Составление анаграмм

2022-01-08T18:04:13Z

MsgBox не предназначен для пользователя, он просто показывает, что данные получены, осталось их как-то сохранить. А вот если сделано GUI, предполагается, что оно как раз для пользователя, и должно быть удобным. Вот сейчас у вас после закрытия окна скрипт остаётся висеть в трее — тоже не очень-то удобно.

Re: AHK: Составление анаграмм

2022-01-08T17:35:27Z

А что мешает подправить код? Тот же 'MsgBox' не очень вариант как по мне. Хоть и позволит извлечь данные, но их нужно будет обрезать.

Gui +AlwaysOnTop +ToolWindow
Gui Add, Edit, vText x8 y8 w200 h21
Gui Add, Edit, vTS x8 y32 w200 h21 +ReadOnly, После ввода нажать 'Enter'
Gui Show, w214 h58, Анаграммы - Онлайн
Return

Enter::
Gui, Submit, NoHide
WinHTTP := ComObjCreate("WinHTTP.WinHttpRequest.5.1")
WinHTTP.Open("POST", "https://cepia.ru/service/words/findbyanagram", 0)
WinHTTP.SetRequestHeader("User-Agent", "Mozilla/5.0 (Windows NT 6.1; rv:65.0) Gecko/20100101 Firefox/65.0")
WinHTTP.SetRequestHeader("Content-Type", "application/x-www-form-urlencoded")
WinHTTP.SetRequestHeader("Pragma", "no-cache")
WinHTTP.SetRequestHeader("Cache-Control", "no-cache, no-store")
WinHTTP.SetRequestHeader("If-Modified-Since", "Sat, 1 Jan 2000 00:00:00 GMT")
WinHTTP.Send("anagram=" Text)
GuiControl,,TS, % WinHTTP.ResponseText
Return

GuiEscape:
GuiClose:
ExitApp

Re: AHK: Составление анаграмм

2022-01-08T17:11:39Z

Что именно наоборот? И как варианты-то получить, переписывать вручную?

Re: AHK: Составление анаграмм

2022-01-08T17:08:36Z

Наоборот, в окне ввёл получил варианты. Захотелось другое слово - повторил.

Re: AHK: Составление анаграмм

2022-01-08T17:04:39Z

Так и окно не нужно было, и с сайта получать тоже.

Re: AHK: Составление анаграмм

2022-01-08T17:03:37Z

А разве это было нужно? Таких условий нет.

Re: AHK: Составление анаграмм

2022-01-08T15:39:16Z

__Михаил__, а как из такого окна скопировать результат?

Re: AHK: Составление анаграмм

2022-01-08T10:35:00Z

С графическим интерфейсом лучше будет.

Name = Анаграммы - Онлайн
Gui +AlwaysOnTop +ToolWindow
Gui Add, Edit, vText x8 y8 w200 h21
Gui Add, Text, vTS x8 y32 w200 h23, После ввода нажать 'Enter'
Gui Show, w214 h58, % Name
Return

Enter::
Gui, Submit, NoHide
WinHTTP := ComObjCreate("WinHTTP.WinHttpRequest.5.1")
WinHTTP.Open("POST", "https://cepia.ru/service/words/findbyanagram", 0)
WinHTTP.SetRequestHeader("User-Agent", "Mozilla/5.0 (Windows NT 6.1; rv:65.0) Gecko/20100101 Firefox/65.0")
WinHTTP.SetRequestHeader("Content-Type", "application/x-www-form-urlencoded")
WinHTTP.SetRequestHeader("Pragma", "no-cache")
WinHTTP.SetRequestHeader("Cache-Control", "no-cache, no-store")
WinHTTP.SetRequestHeader("If-Modified-Since", "Sat, 1 Jan 2000 00:00:00 GMT")
WinHTTP.Send("anagram=" Text)
GuiControl,,TS, % WinHTTP.ResponseText
Return

Re: AHK: Составление анаграмм

2022-01-08T00:38:52Z

А зачем составлять скрипт, когда просто:

WinHTTP := ComObjCreate("WinHTTP.WinHttpRequest.5.1")
WinHTTP.Open("POST", "https://cepia.ru/service/words/findbyanagram", 0)
WinHTTP.SetRequestHeader("User-Agent", "Mozilla/5.0 (Windows NT 6.1; rv:65.0) Gecko/20100101 Firefox/65.0")
WinHTTP.SetRequestHeader("Content-Type", "application/x-www-form-urlencoded")
WinHTTP.SetRequestHeader("Pragma", "no-cache")
WinHTTP.SetRequestHeader("Cache-Control", "no-cache, no-store")
WinHTTP.SetRequestHeader("If-Modified-Since", "Sat, 1 Jan 2000 00:00:00 GMT")
WinHTTP.Send("anagram=каприз")
MsgBox % WinHTTP.ResponseText

Re: AHK: Составление анаграмм

2022-01-07T16:55:28Z

Больно мудрёно, я бы упростил:

StringCaseSense, locale
word_search := "каприз"

Wrd_Lst =
(
скрипт
колба
бокал
форум
приказ
каприз
анаграмма
)
length := StrLen(word_search)
sorted := SortLetters(word_search)
Loop, parse, Wrd_Lst, `n, `r
{
   if StrLen(A_LoopField) != length || A_LoopField = word_search
      continue
   if SortLetters(A_LoopField) = sorted
      MsgBox, Найдена анаграмма:`n%A_LoopField%
}

SortLetters(word) {
   sorted := RegExReplace(word, ".(?=.)", "$0`n")
   Sort, sorted
   Return sorted
}

Re: AHK: Составление анаграмм

2022-01-07T16:36:44Z

Идея с сортировкой букв в слове гениальна . Пока искал как их сортировать, нашелся готовый скрипт —

setbatchlines,-1
listlines,off
#noenv
dictionary=
(
скрипт
колба
бокал
форум
приказ
каприз
анаграмма
)
dict:=[]
Loop, Parse, dictionary, `n, `r        ; Put all words in an array dict, at dict[wordLength, wordLettersSorted, entryNumber]
{
 keyword:=A_LoopField
 len:=strlen(A_LoopField)
 keyword:=Ltrim(RegExReplace(keyword,"(.)",",$1"),",")
 Sort,keyword,D,           ; Make a keyword, eg, Dallas -> a,a,D,l,l,s
 if !IsObject(dict[len,keyword])
  dict[len,keyword]:=[]
 dict[len,keyword].push(A_LoopField)      ; Put the word in the keyword slot, all permutations will get the same keyword and end up in this slot
}
allAnagrams:=[]
for len, lengthGroup in dict {
 for keyword, anagrams in lengthGroup
  if (anagrams.length()>1)       ; For each keyword which has more than entry, there is anagrams, save those
   allAnagrams.push(anagrams)
}
str:="Anagram list:`n"          ; Print result
for k, anagrams in allAnagrams {
 str.= "Anagram set`t" k ":`t"
 for l, anagram in anagrams
  str.=anagram  "`t" 
 str.= "`n" 
}
gui, font,,courier new          ; Show result
gui,add,edit,w1000 r40, % str
gui,show

Re: AHK: Составление анаграмм

2022-01-07T15:37:38Z

Рассортируйте буквы в тестируемом слове в алфавитном порядке.

AHK: Составление анаграмм

2022-01-07T14:50:46Z

Здравствуйте. Пытаюсь составить код для поиска анаграмм. Это слова, которые состоят из тех же букв, из которых состоит искомое слово-образец, например: колба — бокал, приказ — каприз. Ниже в переменной "word_search" выделил такое искомое слово-образец, анаграммы к которому должны быть найдены в списке "Wrd_Lst", но затрудняюсь с обработкой.

word_search := "каприз"

Wrd_Lst =
(
скрипт
колба
бокал
форум
приказ
каприз
анаграмма
)

Loop, Parse, Wrd_Lst, `n
{
   dict_word := A_LoopField

   msgbox % dict_word
}
return