Серый форум — AHK: Взаимодействие со строками в Listbox.

Re: AHK: Взаимодействие со строками в Listbox.

null@example.com (teadrinker) — Sat, 12 Feb 2022 10:53:26 +0000

GuiControl.

Re: AHK: Взаимодействие со строками в Listbox.

null@example.com (Morux2112) — Sat, 12 Feb 2022 10:05:03 +0000

teadrinker, как выделить?

Re: AHK: Взаимодействие со строками в Listbox.

null@example.com (teadrinker) — Sat, 12 Feb 2022 08:09:22 +0000

Что именно?

Re: AHK: Взаимодействие со строками в Listbox.

null@example.com (Morux2112) — Fri, 11 Feb 2022 23:00:31 +0000

teadrinker пишет:

Можно снова выделить её же, номер же есть.

Не подскажите?)

Re: AHK: Взаимодействие со строками в Listbox.

null@example.com (teadrinker) — Fri, 11 Feb 2022 13:28:09 +0000

Morux2112 пишет:

можно ли сделать так, чтобы при изменении строки выделение с неё не убиралось?

По-моему, нет. Можно снова выделить её же, номер же есть.

Re: AHK: Взаимодействие со строками в Listbox.

null@example.com (Morux2112) — Fri, 11 Feb 2022 12:52:53 +0000

teadrinker, огромное спасибо. Ну и последний вопрос: можно ли сделать так, чтобы при изменении строки выделение с неё не убиралось? Либо же как-то считывать содержимое строки по другому? Просто я использую код с кнопки "OnButton" и в качестве переменной с содержанием этой строчки использую text.

Re: AHK: Взаимодействие со строками в Listbox.

null@example.com (teadrinker) — Thu, 10 Feb 2022 22:15:35 +0000

Замените

text := InStr(text, "☐") ? StrReplace(text, "☐", "✅") : StrReplace(text, "✅", "☐")

на

text := StrReplace(text, "☐", "✅")

Re: AHK: Взаимодействие со строками в Listbox.

null@example.com (Morux2112) — Thu, 10 Feb 2022 22:07:34 +0000

teadrinker пишет:

В последнем варианте моего кода переменная items не используется для замен, попробуйте его.

А не могли бы вы убрать функцию "активации/деактивации" этой галочки на одну кнопку. Просто я не знаю как эта функция работает и поэтому самостоятельно убрать её не могу.

Re: AHK: Взаимодействие со строками в Listbox.

null@example.com (teadrinker) — Thu, 10 Feb 2022 20:19:32 +0000

Я ничего не понял, что откуда удалять.

Morux2112 пишет:

SendMessage, 0x188 ...

Никто не обязан знать, что означает число 0х188 и какому сообщению оно соответствует, поэтому непонятно, что это сообщение делает.
В последнем варианте моего кода переменная items не используется для замен, попробуйте его.

Re: AHK: Взаимодействие со строками в Listbox.

null@example.com (Morux2112) — Thu, 10 Feb 2022 18:43:50 +0000

teadrinker, мне уже не удобно просить, и так много сделали для меня. Как очищать item от строки, которую я удалил?

Delete:  
    SendMessage, 0x188, 0, 0, , ahk_id %hListbox%     ; If (ErrorLevel = 0xffffffff) Not Selected 
    Control, Delete, % ++ErrorLevel, , ahk_id %hListbox%   
    return

Данный скрипт удаляет просто строку из Listbox'a и если попытаться изменить содержимое строки, которое идет после удаленной - оно поменяется на удаленную строку, т.к. в переменной items осталась данная удаленная строка. Так как её можно удалить из Items?

Re: AHK: Взаимодействие со строками в Listbox.

null@example.com (Morux2112) — Thu, 10 Feb 2022 15:00:02 +0000

teadrinker, огромное спасибо.

Re: AHK: Взаимодействие со строками в Listbox.

null@example.com (teadrinker) — Thu, 10 Feb 2022 14:29:14 +0000

Хотя, если уж использовать сообщения, можно избавиться от переменной items:

global hListbox, squawk := 2000

items =
(Join|
☐ / ILKOK / ULLI / ULLI / A012 / V / —— / RNAV / RVSM / %squawk%
☐ / RYR1TZ / ULLI / UUEE / FL350 / I / —— / RNAV / RVSM / %squawk%
☐ / BRU457 / ULLI / UMMS / FL250 / I / —— / RNAV / RVSM / %squawk%
)
Gui, Add, ListBox, x12 y13 w410 h140 hwndhListbox vMyListBox AltSubmit, % items
Gui, Add, Button, x12 y153 w30 h30 gOnButton, ✅
Gui, Add, Button, x50 y153 w30 h30 gAdd, +
Gui, Show, w435 h220, test
return

OnButton() {
   static LB_INSERTSTRING := 0x0181
        , LB_DELETESTRING := 0x0182
        , LB_GETTEXT      := 0x0189
        , LB_GETTEXTLEN   := 0x018A
   GuiControlGet, selected,, MyListBox
   WinExist("ahk_id" . hListbox)
   SendMessage, LB_GETTEXTLEN, --selected
   VarSetCapacity(text, ErrorLevel << !!A_IsUnicode, 0)
   SendMessage, LB_GETTEXT, selected, &text
   text := InStr(text, "☐") ? StrReplace(text, "☐", "✅") : StrReplace(text, "✅", "☐")
   SendMessage, LB_DELETESTRING, selected
   SendMessage, LB_INSERTSTRING, selected, &text
}

Add() {
   sost := "☐"
   callsign := "NWS1234"
   dep := "ULLI"
   dest := "URSS"
   fl := "FL350"
   rules := "I"
   sid := "SUGIN 1A"
   rnav := "RNAV"
   rvsm := "RVSM"
   newItem := sost " / " callsign " / " dep " / " dest " / " fl " / " rules " / " sid " / " rnav " / " rvsm " / " squawk
   GuiControl,, MyListBox, % newItem
}

GuiClose() {
   ExitApp
}

Re: AHK: Взаимодействие со строками в Listbox.

null@example.com (teadrinker) — Thu, 10 Feb 2022 13:38:51 +0000

Также можно воспользоваться более продвинутым способом, который будет заменять не всё содержимое контрола сразу, а только одну строку:

global items, hListbox, squawk := 2000

items =
(Join|
☐ / ILKOK / ULLI / ULLI / A012 / V / —— / RNAV / RVSM / %squawk%
☐ / RYR1TZ / ULLI / UUEE / FL350 / I / —— / RNAV / RVSM / %squawk%
☐ / BRU457 / ULLI / UMMS / FL250 / I / —— / RNAV / RVSM / %squawk%
)
Gui, Add, ListBox, x12 y13 w410 h140 hwndhListbox vMyListBox AltSubmit, % items
Gui, Add, Button, x12 y153 w30 h30 gOnButton, ✅
Gui, Add, Button, x50 y153 w30 h30 gAdd, +
Gui, Show, w435 h220, test
return

OnButton() {
   static LB_INSERTSTRING := 0x0181
        , LB_DELETESTRING := 0x0182
   GuiControlGet, selected,, MyListBox
   newItems := ""
   Loop, parse, items, |
   {
      item := A_LoopField
      if (A_Index = selected) {
         if InStr(A_LoopField, "☐")
            item := StrReplace(A_LoopField, "☐", "✅")
         else
            item := StrReplace(A_LoopField, "✅", "☐")
         SendMessage, LB_DELETESTRING, A_Index - 1,,, ahk_id %hListbox%
         SendMessage, LB_INSERTSTRING, A_Index - 1, &item,, ahk_id %hListbox%
      }
      newItems .= (A_Index = 1 ? "" : "|") . item
   }
   items := newItems
}

Add() {
   sost := "☐"
   callsign := "NWS1234"
   dep := "ULLI"
   dest := "URSS"
   fl := "FL350"
   rules := "I"
   sid := "SUGIN 1A"
   rnav := "RNAV"
   rvsm := "RVSM"
   newItem := sost " / " callsign " / " dep " / " dest " / " fl " / " rules " / " sid " / " rnav " / " rvsm " / " squawk
   items  .= "|" . newItem
   GuiControl,, MyListBox, % newItem
}

GuiClose() {
   ExitApp
}

Re: AHK: Взаимодействие со строками в Listbox.

null@example.com (teadrinker) — Thu, 10 Feb 2022 13:00:59 +0000

Нужно всё время менять содержимое переменной items, чтобы оно соответствовало текущему содержимому контрола:

global items, squawk := 2000

items =
(Join|
☐ / ILKOK / ULLI / ULLI / A012 / V / —— / RNAV / RVSM / %squawk%
☐ / RYR1TZ / ULLI / UUEE / FL350 / I / —— / RNAV / RVSM / %squawk%
☐ / BRU457 / ULLI / UMMS / FL250 / I / —— / RNAV / RVSM / %squawk%
)
Gui, Add, ListBox, x12 y13 w410 h140 hwndhListbox vMyListBox AltSubmit, % items
Gui, Add, Button, x12 y153 w30 h30 gOnButton, ✅
Gui, Add, Button, x50 y153 w30 h30 gAdd, +
Gui, Show, w435 h220, test
return

OnButton() {
   GuiControlGet, selected,, MyListBox
   newItems := ""
   Loop, parse, items, |
   {
      item := A_LoopField
      if (A_Index = selected) {
         if InStr(A_LoopField, "☐")
            item := StrReplace(A_LoopField, "☐", "✅")
         else
            item := StrReplace(A_LoopField, "✅", "☐")
      }
      newItems .= (A_Index = 1 ? "" : "|") . item
   }
   GuiControl,, MyListBox, % "|" . (items := newItems)
}

Add() {
   sost := "☐"
   callsign := "NWS1234"
   dep := "ULLI"
   dest := "URSS"
   fl := "FL350"
   rules := "I"
   sid := "SUGIN 1A"
   rnav := "RNAV"
   rvsm := "RVSM"
   newItem := sost " / " callsign " / " dep " / " dest " / " fl " / " rules " / " sid " / " rnav " / " rvsm " / " squawk
   items  .= "|" . newItem
   GuiControl,, MyListBox, % newItem
}

GuiClose() {
   ExitApp
}

Re: AHK: Взаимодействие со строками в Listbox.

null@example.com (Morux2112) — Thu, 10 Feb 2022 10:54:42 +0000

teadrinker пишет:

Конечно, всё можно. Если вы поняли принцип, вам не составит труда изменить код.

Я не совсем понимаю как оно работает. Точнее понимаю, но не могу сделать так, чтобы оно работало на все строчки. Не поможете?

teadrinker пишет:

И можно ли как-то избежать переменной items такого рода, либо же записывать новые строки туда? Просто новые строки записываются таким родом
Я не совсем понял, что вы имеете в виду. Данные всегда находятся в какой-либо переменной, где ж им ещё быть.

Строки в ListBox добавляются таким методом, только данные для переменных берутся с файла. После добавления строчки через GuiControl и попытки изменить в ней хоть что-то - она пропадает. Можно ли как-то это исправить?

global squawk := 2000

items =
(Join|
☐ / ILKOK / ULLI / ULLI / A012 / V / —— / RNAV / RVSM / %squawk%
☐ / RYR1TZ / ULLI / UUEE / FL350 / I / —— / RNAV / RVSM / %squawk%
☐ / BRU457 / ULLI / UMMS / FL250 / I / —— / RNAV / RVSM / %squawk%
)
Gui, Add, ListBox, x12 y13 w410 h140 hwndhListbox vMyListBox AltSubmit, % items
Gui, Add, Button, x12 y153 w30 h30 gOnButton, ✅
Gui, Add, Button, x50 y153 w30 h30 gAdd, +
Gui, Show, w435 h220, test
return

OnButton() {
   global items
   GuiControlGet, selected,, MyListBox
   newItems := ""
   Loop, parse, items, |
      newItems .= "|" . (A_Index = selected ? StrReplace(A_LoopField, "☐", "✅") : A_LoopField)
   GuiControl,, MyListBox, % newItems
}

Numpad1::
InputBox, sqk
global items
GuiControlGet, selected,, MyListBox
newItems := ""
Loop, parse, items, |
newItems .= "|" . (A_Index = selected ? StrReplace(A_LoopField, squawk, sqk) : A_LoopField)
GuiControl,, MyListBox, % newItems
return

Add() {
   sost := "☐"
   callsign := "NWS1234"
   dep := "ULLI"
   dest := "URSS"
   fl := "FL350"
   rules := "I"
   sid := "SUGIN 1A"
   rnav := "RNAV"
   rvsm := "RVSM"
   GuiControl,, MyListBox, %sost% / %callsign% / %dep% / %dest% / %fl% / %rules% / %sid% / %rnav% / %rvsm% / %squawk%
}

GuiClose() {
   ExitApp
}