Серый форум — AHK: Отправка сообщений с вложениями через CDO

Re: AHK: Отправка сообщений с вложениями через CDO

null@example.com (teadrinker) — Mon, 18 Apr 2022 09:50:28 +0000

По-моему, лучше utf-8.

Re: AHK: Отправка сообщений с вложениями через CDO

null@example.com (Phoenixxx_Czar) — Mon, 18 Apr 2022 04:57:04 +0000

А не подскажите, как передать русский текст?
Нашел решение, нужно после "objMessage := ComObjCreate("CDO.Message")" добавить:

objMessage.BodyPart.Charset := "windows-1251"

Re: AHK: Отправка сообщений с вложениями через CDO

null@example.com (teadrinker) — Thu, 14 Apr 2022 16:25:32 +0000

Во всяком случае не с помощью объекта CDO.Message.

Re: AHK: Отправка сообщений с вложениями через CDO

null@example.com (inseption86) — Thu, 14 Apr 2022 16:03:31 +0000

teadrinker
Добрый день, а возможно ли сохранение письма в "отправленных"?

Re: AHK: Отправка сообщений с вложениями через CDO

null@example.com (yakmuve) — Wed, 13 Apr 2022 09:20:22 +0000

teadrinker, благодарю, вы помогли не только мне, но и людям из 2025, которые тоже будут задаваться таким вопроса хе-хе. Спасибо вам большое!

Re: AHK: Отправка сообщений с вложениями через CDO

null@example.com (teadrinker) — Wed, 13 Apr 2022 08:35:07 +0000

То же самое, вместо звёздочек своё имя пользователя.

Re: AHK: Отправка сообщений с вложениями через CDO

null@example.com (yakmuve) — Wed, 13 Apr 2022 08:24:10 +0000

teadrinker, хм, а что вы подставляли вместо

From: """AHKUser"" <******@gmail.com>"

просто может я тупой новичок что-то не туда поставил...

Re: AHK: Отправка сообщений с вложениями через CDO

null@example.com (teadrinker) — Wed, 13 Apr 2022 08:20:37 +0000

Не знаю, у меня так работает:

objMessage := ComObjCreate("CDO.Message")

Keys := { Subject: "Example CDO Message"
        , From: """AHKUser"" <******@gmail.com>"
        , To: "******@mail.ru"
        , Subject: "hi"
        , HTMLBody: ""  ; или TextBody 
                  . "Первая строка сообщения
Вторая строка сообщения" }

for key, value in Keys
   objMessage[key] := value

objMessage.AddAttachment("D:\Downloads\Иконки\AutoHotKey Logo (Medium).ico")

namespace := "http://schemas.microsoft.com/cdo/configuration/"
Fields := { sendusing: 2
          , smtpserver: "smtp.gmail.com"
          , smtpauthenticate: 1
          , sendusername: "******@gmail.com"
          , sendpassword: "****************" ; пароль приложения https://support.google.com/accounts/answer/185833?hl=ru&ref_topic=7189145
          , smtpusessl: 1
          , smtpconnectiontimeout: 60
          , smtpserverport: 465 }

for field, value in Fields
   objMessage.Configuration.Fields.Item(namespace . field) := value
   
objMessage.Configuration.Fields.Update
objMessage.Send

Проверял на Windows 7 и 10.

Re: AHK: Отправка сообщений с вложениями через CDO

null@example.com (yakmuve) — Wed, 13 Apr 2022 05:50:48 +0000

teadrinker Хм, сделал пароль приложения (Windows, ToMail (написал название ahk без указания расширения) и на выходе получил 16-ти значный пароль) и вставил его в код на место пароля,

fields.sendusername := "123456789@gmail.com"
fields.sendpassword := "****************"

однако ошибка осталась. Может быть я как-то некорректно указал имя пользователя или пароль?

Re: AHK: Отправка сообщений с вложениями через CDO

null@example.com (teadrinker) — Tue, 12 Apr 2022 23:13:10 +0000

Возможно, нужно ввести пароль приложения (а не пароль аккаунта). Порт 465.

AHK: Отправка сообщений с вложениями через CDO

null@example.com (yakmuve) — Tue, 12 Apr 2022 20:26:42 +0000

Здравствуйте, понадобилась автоматизация данного процесса. Изучив просторы интернета нашёл такой код (аж из 2014):

pmsg 			:= ComObjCreate("CDO.Message")
pmsg.From 		:= """AHKUser"" <...@gmail.com>"
pmsg.To 		:= "anybody@somewhere.com"
pmsg.BCC 		:= ""   ; Blind Carbon Copy, Invisable for all, same syntax as CC
pmsg.CC 		:= "Somebody@somewhere.com, Other-somebody@somewhere.com"
pmsg.Subject 	:= "Message_Subject"

;You can use either Text or HTML body like
pmsg.TextBody 	:= "Message_Body"
;OR
;pmsg.HtmlBody := "HelloHello
Testing!"


sAttach   		:= "Path_Of_Attachment" ; can add multiple attachments, the delimiter is |

fields := Object()
fields.smtpserver   := "smtp.gmail.com" ; specify your SMTP server
fields.smtpserverport     := 465 ; 25
fields.smtpusessl      := True ; False
fields.sendusing     := 2   ; cdoSendUsingPort
fields.smtpauthenticate     := 1   ; cdoBasic
fields.sendusername := "...@gmail.com"
fields.sendpassword := "your_password_here"
fields.smtpconnectiontimeout := 60
schema := "http://schemas.microsoft.com/cdo/configuration/"


pfld :=   pmsg.Configuration.Fields

For field,value in fields
	pfld.Item(schema . field) := value
pfld.Update()

Loop, Parse, sAttach, |, %A_Space%%A_Tab%
  pmsg.AddAttachment(A_LoopField)
pmsg.Send()

Все данные у себя я заполнил/изменил. Номер порта выставил 25. После "таймаута" выходит ошибка 0x80040213.
Error: 0x80040213
Source: CDO.Message.1
Description: Транспорту не удалось подключиться к серверу.
HelpFile: (null)
HelpContext: 0
Specifically: Send

---> pmsg.Send()

Прошу вас о помощи, либо задачка сложная, либо я тупой (скорее второе).