Серый форум — AHK: Переход на уровень вверх по double click

Re: AHK: Переход на уровень вверх по double click

null@example.com (ppss42) — Fri, 20 May 2022 02:45:00 +0000

Сейчас только проверил, по мне этот вариант идеальный! Ни одного ложного срабатывания. 100% отработал как надо. Большое вам спасибо уважаемый teadrinker за такой замечательный скрипт. Скрипту точно место в коллекции.

Re: AHK: Переход на уровень вверх по double click

null@example.com (teadrinker) — Thu, 19 May 2022 11:56:58 +0000

Вот так должно быть надёжнее:

#If !res && hWnd := WinActive("ahk_class CabinetWClass")
~LButton::
   if !res := IsEmptySpaceUnderCusor()
      Return
   KeyWait, LButton
   KeyWait, LButton, D T.4
   (!ErrorLevel && NavigateToParentDir(hWnd))
   res := ""
   Return
#If

IsEmptySpaceUnderCusor() {
   Return AccObjectFromPoint().accRole(0) = (ROLE_SYSTEM_LIST := 0x21)
}

AccObjectFromPoint(ByRef childId = "", x = "", y = "") {
   static VT_DISPATCH := 9, F_OWNVALUE := 1, h := DllCall("LoadLibrary", "Str", "oleacc", "Ptr")
   AccObject := 0
   (x = "" || y = "") ? DllCall("GetCursorPos", "Int64P", pt) : pt := x & 0xFFFFFFFF | y << 32
   VarSetCapacity(varChild, 8 + A_PtrSize*2, 0)
   if DllCall("oleacc\AccessibleObjectFromPoint", "Int64", pt, "PtrP", pAcc, "Ptr", &varChild) = 0
      childId := NumGet(varChild, 8, "UInt"), AccObject := ComObject(VT_DISPATCH, pAcc, F_OWNVALUE)
   Return AccObject
}

NavigateToParentDir(hWnd) {
   static comType := (VT_ARRAY := 0x2000) | (VT_UI1 := 0x11)
   Shell := ComObjCreate("Shell.Application")
   for Window in Shell.Windows {
      if (hWnd = Window.hwnd) {
         Folder := Window.Document.Folder
         parentDirPath := Folder.ParentFolder.Self.Path
         break
      }
   }
   if parentDirPath {
      DllCall("shell32\SHParseDisplayName", "WStr", parentDirPath, "Ptr", 0, "PtrP", PIDL, "UInt", 0, "Ptr", 0)
      ilSize := DllCall("shell32\ILGetSize", "Ptr", PIDL, "UInt")
      VarSetCapacity(SAFEARRAY, 16 + A_PtrSize*2, 0)
      NumPut(1     , SAFEARRAY)
      NumPut(1     , SAFEARRAY, 4)
      NumPut(PIDL  , SAFEARRAY, 8 + A_PtrSize)
      NumPut(ilSize, SAFEARRAY, 8 + A_PtrSize*2)
      try Window.Navigate2( ComObject(comType, &SAFEARRAY), 0 )
      DllCall("shell32\ILFree", "Ptr", PIDL)
   }
}

Re: AHK: Переход на уровень вверх по double click

null@example.com (ppss42) — Thu, 19 May 2022 11:24:40 +0000

teadrinker Понимаю, изначально считал что невозможно это сделать средствами ahk. Спасибо вам большое за реализацию скрипта.

Re: AHK: Переход на уровень вверх по double click

null@example.com (teadrinker) — Thu, 19 May 2022 10:50:30 +0000

ppss42 пишет:

теперь понял как выкладывать на i.imgur.

Ваш сервис тоже даёт прямую ссылку, вот она:

+ открыть спойлер

ppss42 пишет:

изредка имеют место ложные срабатывания

Скорее всего, с этим ничего не сделаешь, просто основная функция двойного клика успевает сработать раньше, чем код скрипта. Потестировал, у меня такое происходит очень редко, но случалось.

Re: AHK: Переход на уровень вверх по double click

null@example.com (ppss42) — Thu, 19 May 2022 10:40:48 +0000

teadrinker теперь понял как выкладывать на i.imgur. По скрипту: ошибки не выдает, но изредка имеют место ложные срабатывания. При открытие папки, она открывается на сотые доли секунды, и тут же возвращается на уровень вверх (то есть на исходную директорию где был сделан клик)
P.s. Если бы не этот небольшой недочет, то наверное ему место в коллекции. Уж очень удобный в повседневном использовании.

Re: AHK: Переход на уровень вверх по double click

null@example.com (teadrinker) — Thu, 19 May 2022 10:00:59 +0000

Чтобы отобразить картинку, пользуйтесь сервисами, где можно получить прямую ссылку на изображение, эту ссылку оборачиваете тегами img. Я отредактировал ваш пост, можете посмотреть, как это сделано, нажав кнопку «Изменить».

ppss42 пишет:

работает, но к сожалению с ошибками

Попробуйте так:

#If hWnd := WinActive("ahk_class CabinetWClass")
~LButton::
   if (A_PriorHotkey = A_ThisHotkey && A_TimeSincePriorHotkey < 400 && IsEmptySpaceUnderCusor())
      NavigateToParentDir(hWnd)
   Return
#If

IsEmptySpaceUnderCusor() {
   Return AccObjectFromPoint().accRole(0) = (ROLE_SYSTEM_LIST := 0x21)
}

AccObjectFromPoint(ByRef childId = "", x = "", y = "") {
   static VT_DISPATCH := 9, F_OWNVALUE := 1, h := DllCall("LoadLibrary", "Str", "oleacc", "Ptr")
   AccObject := 0
   (x = "" || y = "") ? DllCall("GetCursorPos", "Int64P", pt) : pt := x & 0xFFFFFFFF | y << 32
   VarSetCapacity(varChild, 8 + A_PtrSize*2, 0)
   if DllCall("oleacc\AccessibleObjectFromPoint", "Int64", pt, "PtrP", pAcc, "Ptr", &varChild) = 0
      childId := NumGet(varChild, 8, "UInt"), AccObject := ComObject(VT_DISPATCH, pAcc, F_OWNVALUE)
   Return AccObject
}

NavigateToParentDir(hWnd) {
   static comType := (VT_ARRAY := 0x2000) | (VT_UI1 := 0x11)
   Shell := ComObjCreate("Shell.Application")
   for Window in Shell.Windows {
      if (hWnd = Window.hwnd) {
         Folder := Window.Document.Folder
         parentDirPath := Folder.ParentFolder.Self.Path
         break
      }
   }
   if parentDirPath {
      DllCall("shell32\SHParseDisplayName", "WStr", parentDirPath, "Ptr", 0, "PtrP", PIDL, "UInt", 0, "Ptr", 0)
      ilSize := DllCall("shell32\ILGetSize", "Ptr", PIDL, "UInt")
      VarSetCapacity(SAFEARRAY, 16 + A_PtrSize*2, 0)
      NumPut(1     , SAFEARRAY)
      NumPut(1     , SAFEARRAY, 4)
      NumPut(PIDL  , SAFEARRAY, 8 + A_PtrSize)
      NumPut(ilSize, SAFEARRAY, 8 + A_PtrSize*2)
      try Window.Navigate2( ComObject(comType, &SAFEARRAY), 0 )
      DllCall("shell32\ILFree", "Ptr", PIDL)
   }
}

Re: AHK: Переход на уровень вверх по double click

null@example.com (ppss42) — Thu, 19 May 2022 06:00:40 +0000

Re: AHK: Переход на уровень вверх по double click

null@example.com (teadrinker) — Thu, 19 May 2022 05:42:03 +0000

Сделайте скриншот сообщения об ошибке.

Re: AHK: Переход на уровень вверх по double click

null@example.com (ppss42) — Thu, 19 May 2022 02:56:21 +0000

teadrinker Даже не думал что будет решение. Опробовал скрипт, работает, но к сожалению с ошибками. После открытия нескольких папок выходит ошибка на 11 строке, где нужно вернуть значение из функции. Появляется в момент double клика по папке.

Re: AHK: Переход на уровень вверх по double click

null@example.com (teadrinker) — Wed, 18 May 2022 16:47:02 +0000

Вижу, без поллитра не разберётесь.

#If hWnd := WinActive("ahk_class CabinetWClass")
~LButton::
   if (A_PriorHotkey = A_ThisHotkey && A_TimeSincePriorHotkey < 400 && IsEmptySpaceUnderCusor())
      NavigateToParentDir(hWnd)
   Return
#If

IsEmptySpaceUnderCusor() {
   static ROLE_SYSTEM_WINDOW := 0x00000009
   AccObj := AccObjectFromPoint(childId)
   Return (childId ? AccObj : AccObj.accParent).accRole(0) = ROLE_SYSTEM_WINDOW
}

AccObjectFromPoint(ByRef childId = "", x = "", y = "") {
   static VT_DISPATCH := 9, F_OWNVALUE := 1, h := DllCall("LoadLibrary", "Str", "oleacc", "Ptr")
   AccObject := 0
   (x = "" || y = "") ? DllCall("GetCursorPos", "Int64P", pt) : pt := x & 0xFFFFFFFF | y << 32
   VarSetCapacity(varChild, 8 + A_PtrSize*2, 0)
   if DllCall("oleacc\AccessibleObjectFromPoint", "Int64", pt, "PtrP", pAcc, "Ptr", &varChild) = 0
      childId := NumGet(varChild, 8, "UInt"), AccObject := ComObject(VT_DISPATCH, pAcc, F_OWNVALUE)
   Return AccObject
}

NavigateToParentDir(hWnd) {
   static comType := (VT_ARRAY := 0x2000) | (VT_UI1 := 0x11)
   Shell := ComObjCreate("Shell.Application")
   for Window in Shell.Windows {
      if (hWnd = Window.hwnd) {
         Folder := Window.Document.Folder
         parentDirPath := Folder.ParentFolder.Self.Path
         break
      }
   }
   if parentDirPath {
      DllCall("shell32\SHParseDisplayName", "WStr", parentDirPath, "Ptr", 0, "PtrP", PIDL, "UInt", 0, "Ptr", 0)
      ilSize := DllCall("shell32\ILGetSize", "Ptr", PIDL, "UInt")
      VarSetCapacity(SAFEARRAY, 16 + A_PtrSize*2, 0)
      NumPut(1     , SAFEARRAY)
      NumPut(1     , SAFEARRAY, 4)
      NumPut(PIDL  , SAFEARRAY, 8 + A_PtrSize)
      NumPut(ilSize, SAFEARRAY, 8 + A_PtrSize*2)
      try Window.Navigate2( ComObject(comType, &SAFEARRAY), 0 )
      DllCall("shell32\ILFree", "Ptr", PIDL)
   }
}

Re: AHK: Переход на уровень вверх по double click

null@example.com (ppss42) — Wed, 18 May 2022 16:40:17 +0000

svoboden Я знаю про эту утилиту, пользовался какое то время (окна по типу вкладок, слишком много настроек). Но не зашла эта утилита, со временем вернулся на проводник Windows. Не хватает для полного счастья, только этой функции.

Re: AHK: Переход на уровень вверх по double click

null@example.com (svoboden) — Wed, 18 May 2022 16:34:49 +0000

Для проводника есть QTTabBar там есть такая функция.

Re: AHK: Переход на уровень вверх по double click

null@example.com (ppss42) — Wed, 18 May 2022 16:32:18 +0000

svoboden Да нет, не обязательно ahk. Нужно для личных нужд. Пользовался разными файловыми менеджерами, и там привык к этому действию.

Re: AHK: Переход на уровень вверх по double click

null@example.com (svoboden) — Wed, 18 May 2022 16:27:11 +0000

Нужно ahk именно?

Re: AHK: Переход на уровень вверх по double click

null@example.com (__Михаил__) — Wed, 18 May 2022 16:21:49 +0000

Библеотека такая.