Серый форум — AHK: Убрать всплывающую ошибку у файла AutoHotkey.exe

Re: AHK: Убрать всплывающую ошибку у файла AutoHotkey.exe

null@example.com (serzh82saratov) — Wed, 31 Aug 2022 16:50:24 +0000

Что то с памятью моей стало...
Всё получилось, прилепил BASE64.

Re: AHK: Убрать всплывающую ошибку у файла AutoHotkey.exe

null@example.com (teadrinker) — Wed, 31 Aug 2022 16:29:26 +0000

serzh82saratov пишет:

как зашифровать ей строку в обычную строку

Так я же объяснял уже.

Re: AHK: Убрать всплывающую ошибку у файла AutoHotkey.exe

null@example.com (serzh82saratov) — Wed, 31 Aug 2022 15:34:48 +0000

teadrinker пишет:

У меня так работает на версии 1.1.33.10:

string:="This is a message from AutoHotkey."
sz := ZipRawMemory(string, StrLen(string) * 2 + 2, var, "password") ; подразумевается UTF-16
UnZipRawMemory(&var, sz, text, "password")
MsgBox % text

string := "Hello, World"
size := StrPutBuff(string, buf)
size := CryptAES(&buf, size, "sdfKIop", true, 128)
MsgBox, % StrGet(&buf, size, "UTF-8")
size := CryptAES(&buf, size, "sdfKIop", false, 128)
MsgBox, % StrGet(&buf, size, "UTF-8")

StrPutBuff(str, ByRef buff, encoding := "UTF-8") {
   VarSetCapacity(buff, len := (StrPut(str, encoding) - 1) << (encoding ~= "i)^(UTF-16|cp1200)$"))
   StrPut(str, &buff, encoding)
   Return len
}

В первом примере + 2 не обязательно, но желательно.

То ли я всегда пробовал этот код целиком, но CryptAES заработал, ошибка была в ZipRawMemory.
Чё то всё равно не доходит, как зашифровать ей строку в обычную строку, и после эту строку дешифровать.

#SingleInstance Force
#NoEnv
SetBatchLines, -1

decstring := "Hello, World"
size := StrPutBuff(decstring, decbuf)
size := CryptAES(&decbuf, size, "sdfKIop", true, 128)
encstring := StrGet(&decbuf, size, "UTF-8")
MsgBox, % encstring

size := StrPutBuff(encstring, encbuf)
size := CryptAES(&encbuf, size, "sdfKIop", false, 128)
MsgBox, % StrGet(&encbuf, size, "UTF-8")

StrPutBuff(str, ByRef buff, encoding := "UTF-8") {
   VarSetCapacity(buff, len := (StrPut(str, encoding) - 1) << (encoding ~= "i)^(UTF-16|cp1200)$"))
   StrPut(str, &buff, encoding)
   Return len
}

Re: AHK: Убрать всплывающую ошибку у файла AutoHotkey.exe

null@example.com (serzh82saratov) — Wed, 17 Aug 2022 14:07:42 +0000

Malcev пишет:

насколько тут по-взрослому.

Ну видимо на сколько-то. От школьника есть защита, уже хорошо. Насколько я слышал, питон и ява тоже не защищены достойно, хотя на счёт ява может и ошибаюсь.

Malcev пишет:

можно скинуться и на кворке заказать взлом и проверить насколько крепка защита

А вот это не надо, так и появляются в итоге публичные методы взлома.

Re: AHK: Убрать всплывающую ошибку у файла AutoHotkey.exe

null@example.com (Malcev) — Mon, 15 Aug 2022 09:55:06 +0000

serzh82saratov пишет:

AHK_L, школьник взломает, а тут вроде всё по взрослому.

Вопрос конечно интересный, насколько тут по-взрослому.
Я с хакерами не знаком, виртуально знаю только одного - очень серьезного, но он точно заниматься подобными глупостями не будет.
Если есть интерес, то можно скинуться и на кворке заказать взлом и проверить насколько крепка защита.

Re: AHK: Убрать всплывающую ошибку у файла AutoHotkey.exe

null@example.com (serzh82saratov) — Thu, 11 Aug 2022 11:45:06 +0000

teadrinker пишет:

если в переменной бинарные данные, её нельзя возвращать через return

Это да, косяк. Надо указатель передавать когда это требуется.

Re: AHK: Убрать всплывающую ошибку у файла AutoHotkey.exe

null@example.com (teadrinker) — Thu, 11 Aug 2022 11:31:03 +0000

К тому, что если в переменной бинарные данные, её нельзя возвращать через return.

Re: AHK: Убрать всплывающую ошибку у файла AutoHotkey.exe

null@example.com (serzh82saratov) — Thu, 11 Aug 2022 09:05:38 +0000

teadrinker пишет:

Но так тоже как строку возвращает, пример:

А к чему этот пример, что то не понял.

Re: AHK: Убрать всплывающую ошибку у файла AutoHotkey.exe

null@example.com (teadrinker) — Thu, 11 Aug 2022 06:55:08 +0000

serzh82saratov пишет:

с ней же заработало

А, не очень внимательно посмотрел. Там было

   	If crypt
		Return outData

Но так тоже как строку возвращает, пример:

data := CryptString()
MsgBox, % data
MsgBox, % Format("{:#x}", NumGet(data, "Int64"))

CryptString() {
   VarSetCapacity(outData, 8, 0)
   NumPut(0x6100000061, outData, "Int64")
   VarSetCapacity(outData, -1)
   MsgBox, % outData
   MsgBox, % Format("{:#x}", NumGet(outData, "Int64"))
   Return outData
}

Re: AHK: Убрать всплывающую ошибку у файла AutoHotkey.exe

null@example.com (serzh82saratov) — Thu, 11 Aug 2022 06:01:31 +0000

Malcev пишет:

А смысл возиться и плясать с бубном с AHK_H?

Ну он с шифрованием кода, с антиотладчиком, в памяти вроде части кода затирает чтобы в дампе памяти не видно было. AHK_L, школьник взломает, а тут вроде всё по взрослому.
И многопоточность без танцев с бубнами.

Re: AHK: Убрать всплывающую ошибку у файла AutoHotkey.exe

null@example.com (serzh82saratov) — Thu, 11 Aug 2022 05:56:39 +0000

teadrinker пишет:

Ну да, это строка и это неправильно

Вроде верно, так, с ней же заработало.


CryptString(string, password, iv := "", crypt := true, algorithm := "AES", textEncoding := "UTF-8") {
; crypt: true — encrypt, false — decrypt
	If crypt
		lenInData := StrPutBuff(string, inData, textEncoding) 
	Else 
		lenInData := StringBase64ToData(string, inData)
    
   hLib := DllCall("LoadLibrary", "Str", "Bcrypt.dll", "Ptr")
   lenPasswordData := StrPutBuff(password, passwordData, textEncoding)
   lenHashPassword := CreateHash(&passwordData, lenPasswordData, hashPassword)
   pHashIv := lenIv := 0
   
   if (iv != "") {
      lenIvData := StrPutBuff(iv, ivData, textEncoding)
      lenHashIv := CreateHash(&ivData, lenIvData, hashIv)
      VarSetCapacity(iv16, 16, 0)
      DllCall("RtlMoveMemory", "Ptr", pHashIv := &iv16, "Ptr", &hashIv + lenHashIv - 16, "Ptr", lenIv := 16)
   } 
   crypt := (crypt ? "En" : "De") . "crypt"
   lenOutData := Bcrypt(&inData, lenInData, outData, &hashPassword, lenHashPassword, pHashIv, lenIv, algorithm, crypt)
   DllCall("FreeLibrary", "Ptr", hLib)  
   	If (crypt = "Encrypt")
		Return CryptBinaryToStringBASE64(&outData, lenOutData, 1) 
   Return StrGet(&outData, lenOutData, textEncoding) 
}

Re: AHK: Убрать всплывающую ошибку у файла AutoHotkey.exe

null@example.com (Malcev) — Thu, 11 Aug 2022 02:49:16 +0000

serzh82saratov пишет:

Попробовал на виртуалке, работает. Что за ерунда может мешать работе этих функций...

А смысл возиться и плясать с бубном с AHK_H?

Re: AHK: Убрать всплывающую ошибку у файла AutoHotkey.exe

null@example.com (teadrinker) — Wed, 10 Aug 2022 22:35:36 +0000

Либо, если уж хочется иметь одну и ту же функцию для шифрования и расшифровки строки, то в случае шифрования возвращать сразу base64, а в случае расшифровки строку.

Re: AHK: Убрать всплывающую ошибку у файла AutoHotkey.exe

null@example.com (teadrinker) — Wed, 10 Aug 2022 21:34:49 +0000

Return StrGet(&outData, lenOutData, textEncoding)

Ну да, это строка и это неправильно. Функция должна вернуть буфер и его длину.

Re: AHK: Убрать всплывающую ошибку у файла AutoHotkey.exe

null@example.com (serzh82saratov) — Wed, 10 Aug 2022 21:32:09 +0000

teadrinker пишет:

А у тебя CryptString() пытается вернуть строку.


CryptString(string, password, iv := "", crypt := true, algorithm := "AES", textEncoding := "UTF-8") {
; crypt: true — encrypt, false — decrypt
	If crypt
		lenInData := StrPutBuff(string, inData, textEncoding) 
	Else 
		lenInData := StringBase64ToData(string, inData)
    
   hLib := DllCall("LoadLibrary", "Str", "Bcrypt.dll", "Ptr")
   lenPasswordData := StrPutBuff(password, passwordData, textEncoding)
   lenHashPassword := CreateHash(&passwordData, lenPasswordData, hashPassword)
   pHashIv := lenIv := 0
   if (iv != "") {
      lenIvData := StrPutBuff(iv, ivData, textEncoding)
      lenHashIv := CreateHash(&ivData, lenIvData, hashIv)
      VarSetCapacity(iv16, 16, 0)
      DllCall("RtlMoveMemory", "Ptr", pHashIv := &iv16, "Ptr", &hashIv + lenHashIv - 16, "Ptr", lenIv := 16)
   }
   crypt := (crypt ? "En" : "De") . "crypt"
   lenOutData := Bcrypt(&inData, lenInData, outData, &hashPassword, lenHashPassword, pHashIv, lenIv, algorithm, crypt)
   DllCall("FreeLibrary", "Ptr", hLib)  
   	If crypt
		Return outData
   Return StrGet(&outData, lenOutData, textEncoding)
}