Серый форум — AHK: Передать instance (this) родительского класса из дочернего.

Re: AHK: Передать instance (this) родительского класса из дочернего.

null@example.com (teadrinker) — Fri, 02 Sep 2022 20:57:08 +0000

А почему нет?

Re: AHK: Передать instance (this) родительского класса из дочернего.

null@example.com (Phoenixxx_Czar) — Fri, 02 Sep 2022 20:29:48 +0000

Получается я внутри testFunc могу обратиться к instance и вызвать допустим instance.stop(), правильно?

Re: AHK: Передать instance (this) родительского класса из дочернего.

null@example.com (teadrinker) — Fri, 02 Sep 2022 20:03:08 +0000

В данном случае можно передать указатель на this:

#Persistent
#SingleInstance FORCE

class Test1
{
   __new(callback)
   {
      this.Test2.callback := callback
   }

   __delete()
   {
      this.stop()
      tooltip, % "Удалено"
   }

   start()
   {
      timerObj := this.timerObj := ObjBindMethod(this.Test2, "method", &this)
      setTimer, % timerObj, 500
   }

   stop()
   {
      timerObj := this.timerObj
      setTimer, % timerObj, delete
   }

   class Test2
   {
      method(pInstance)
      {
         this.callback.call(Object(pInstance), "one")
      }
   }
}

test := new Test1(func("testFunc"))
test.start()
sleep, 1700
test := ""


testFunc(instance, param)
{
   toolTip, % instance.__class "`n" param
}

Re: AHK: Передать instance (this) родительского класса из дочернего.

null@example.com (Phoenixxx_Czar) — Fri, 02 Sep 2022 19:53:42 +0000

Думаю что-то такое, но я не знаю как получить this от Test1:

#Persistent
#SingleInstance FORCE

class Test1
{
	__new(callback)
	{
		this.Test2.callback := callback
	}

	__delete()
	{
		this.stop()
		tooltip, % "Удалено"
	}

	start()
	{
		timerObj := this.timerObj := ObjBindMethod(this.Test2, "method")
		setTimer, % timerObj, 500
	}

	stop()
	{
		timerObj := this.timerObj
		setTimer, % timerObj, delete
	}

	class Test2
	{
		method()
		{
			this.callback.call(this, "one")
		}
	}
}

test := new Test1(func("testFunc"))
test.start()
sleep, 1700
test := ""


testFunc(instance, param)
{

	toolTip, % instance.__class "`n" param
}

Это если я пытаюсь передать this в objBindMethod:

#Persistent
#SingleInstance FORCE

class Test1
{
	__new(callback)
	{
		this.Test2.callback := callback
	}

	__delete()
	{
		this.stop()
		tooltip, % "Удалено"
	}

	start()
	{
		timerObj := this.timerObj := ObjBindMethod(this.Test2, "method", this)
		setTimer, % timerObj, 500
	}

	stop()
	{
		timerObj := this.timerObj
		setTimer, % timerObj, delete
	}

	class Test2
	{
		method(instance)
		{
			this.callback.call(instance, "one")
		}
	}
}

test := new Test1(func("testFunc"))
test.start()
sleep, 1700
test := ""


testFunc(instance, param)
{

	toolTip, % instance.__class "`n" param
}

Re: AHK: Передать instance (this) родительского класса из дочернего.

null@example.com (teadrinker) — Fri, 02 Sep 2022 19:43:57 +0000

Но этот код невозможно запустить.

Приведите просто минимально возможный код, наподобие того, что в первом посте, только чтобы продемонстрировать проблему.

Re: AHK: Передать instance (this) родительского класса из дочернего.

null@example.com (Phoenixxx_Czar) — Fri, 02 Sep 2022 19:37:01 +0000

Удалено.

Re: AHK: Передать instance (this) родительского класса из дочернего.

null@example.com (teadrinker) — Fri, 02 Sep 2022 19:14:38 +0000

А зачем представлять, просто напишите сразу полный код.

Re: AHK: Передать instance (this) родительского класса из дочернего.

null@example.com (Phoenixxx_Czar) — Fri, 02 Sep 2022 19:10:04 +0000

Представьте, что там он есть, со вторым кодом же не вызовет метод __delete.

Re: AHK: Передать instance (this) родительского класса из дочернего.

null@example.com (teadrinker) — Fri, 02 Sep 2022 18:34:29 +0000

Phoenixxx_Czar пишет:

мне нужно не потерять работоспособность метода `__delete()`

А где там метод __delete() ?

AHK: Передать instance (this) родительского класса из дочернего.

null@example.com (Phoenixxx_Czar) — Fri, 02 Sep 2022 18:16:58 +0000

Приведу абстрактный код:


class Test1
{
	__new(callback)
	{
		this.Test2.callback := callback
	}

	method()
	{
		ObjBindMethod(this.Test2, "method").call()
	}

	class Test2
	{
		method()
		{
			this.callback.call(this) ; как мне передать this указывающий на Test1?
		}
	}
}

test := new Test1(func("testFunc"))
test.method()


testFunc(classInstance)
{
	msgbox, % classInstance.__class ; Хочу тут получить Test1
}

Мне необходимо вызвать callback функцию во вложенном классе, и при этом передать instance родительского класса (Test1). При этом мне нужно не потерять работоспособность метода `__delete()`, то есть у нас не получится сделать так:


class Test1
{
	__new(callback)
	{
		this.Test2.callback := callback
	}

	method()
	{
		ObjBindMethod(this.Test2, "method", this).call()
	}

	class Test2
	{
		method(instance)
		{
			this.callback.call(instance)
		}
	}
}

test := new Test1(func("testFunc"))
test.method()


testFunc(classInstance)
{
	msgbox, % classInstance.__class
}