Серый форум — AHK: RegisterCallback() и количество параметров

Re: AHK: RegisterCallback() и количество параметров

null@example.com (YMP) — Fri, 07 Oct 2022 16:16:49 +0000

Malcev пишет:

И если функция уберет 1 параметр вместо 2, то чем это чревато?

Зависит от того, как код скомпилировался. Может, и ничего. Смотря от чего, например, адресуются локальные переменные, они ведь хранятся в стеке. Если от указателя стека, то он после вызова окажется не там, где был до вызова, и адресация собьётся.

Malcev пишет:

А почему на 64 битах такой ситуации не наблюдается?

Там соглашение вызова fastcall, где стек очищает вызывающая функция. Сколько положила, столько и уберёт.

Re: AHK: RegisterCallback() и количество параметров

null@example.com (Malcev) — Fri, 07 Oct 2022 15:48:52 +0000

А почему на 64 битах такой ситуации не наблюдается?
И если функция уберет 1 параметр вместо 2, то чем это чревато?

Re: AHK: RegisterCallback() и количество параметров

null@example.com (YMP) — Fri, 07 Oct 2022 02:18:36 +0000

Вызванная функция должна сама очищать стек от своих параметров (если соглашение вызова stdcall). Фактически в стеке 2 параметра, а функция уберёт 5, т.е. удалит лишнее.

Re: AHK: RegisterCallback() и количество параметров

null@example.com (teadrinker) — Thu, 06 Oct 2022 20:35:10 +0000

Да, в этом случае функция просто крашится:

counter := 0
EnumAddress := RegisterCallback("EnumWindowsProc", "Fast")
MsgBox, % DllCall("EnumWindows", "Ptr", EnumAddress, "Ptr", 0)
MsgBox %Output%  ; Display the information accumulated by the callback.
    
EnumWindowsProc(hwnd, lParam, a, b, c)   ; 5 параметров вместо 2
{
    global Output, counter
    ToolTip % ++counter
    WinGetClass, class, ahk_id %hwnd%
    WinGetTitle, title, ahk_id %hwnd%
    
    if title
        Output .= "HWND: " . hwnd . "`tTitle: " . title . "`tClass: " . class . "`n"
    return true  ; Tell EnumWindows() to continue until all windows have been enumerated.
}

Re: AHK: RegisterCallback() и количество параметров

null@example.com (Malcev) — Thu, 06 Oct 2022 19:57:23 +0000

Сейчас проверил код из первого поста на 32бит и если параметров больше, то выводит пустоту.

Re: AHK: RegisterCallback() и количество параметров

null@example.com (teadrinker) — Thu, 06 Oct 2022 19:47:48 +0000

teadrinker пишет:

иначе просто интерпретатор выдаст ошибку

Проверил, не выдаёт. Просто не сработает:

EnumAddress := RegisterCallback("EnumWindowsProc", "Fast", 3)
DllCall("EnumWindows", "Ptr", EnumAddress, "Ptr", 0)
MsgBox %Output%  ; Display the information accumulated by the callback.
    
EnumWindowsProc(hwnd, lParam)
{
    global Output
    WinGetTitle, title, ahk_id %hwnd%
    WinGetClass, class, ahk_id %hwnd%
    if title
        Output .= "HWND: " . hwnd . "`tTitle: " . title . "`tClass: " . class . "`n"
    return true  ; Tell EnumWindows() to continue until all windows have been enumerated.
}

Re: AHK: RegisterCallback() и количество параметров

null@example.com (teadrinker) — Thu, 06 Oct 2022 19:42:04 +0000

В данном случае ничем, лишние просто не будут приходить. Наверно, имеется в виду, что если указано количество, то должно быть правильным, иначе просто интерпретатор выдаст ошибку.

AHK: RegisterCallback() и количество параметров

null@example.com (Malcev) — Thu, 06 Oct 2022 19:17:21 +0000

В справке написано, что при создании колбека нужно убедиться, что количество параметров у вызова и принимающей функции должны совпадать.
А почему не написано.
Чем теоретически может обернуться если их количество совпадать не будет?
Например:

 EnumAddress := RegisterCallback("EnumWindowsProc", "Fast")
DllCall("EnumWindows", "Ptr", EnumAddress, "Ptr", 0)
MsgBox %Output%  ; Display the information accumulated by the callback.
    
EnumWindowsProc(hwnd, lParam, temp1, temp2, temp3)   ; 5 параметров вместо 2
{
    global Output
    WinGetTitle, title, ahk_id %hwnd%
    WinGetClass, class, ahk_id %hwnd%
    if title
        Output .= "HWND: " . hwnd . "`tTitle: " . title . "`tClass: " . class . "`n"
    return true  ; Tell EnumWindows() to continue until all windows have been enumerated.
}