Серый форум — AHK: Поле ввода на GUI

Re: AHK: Поле ввода на GUI

null@example.com (jbn238) — Sat, 29 Oct 2022 11:46:15 +0000

teadrinker
Замечательно, это именно то, что я хотел, щас осталось сделать по нажатию Enter чтобы она принимало в переменную это число и на экране пропадала надпись. Спасибо большое за помощь, извините если возможно плохо объяснил что именно нужно было.

Re: AHK: Поле ввода на GUI

null@example.com (serzh82saratov) — Sat, 29 Oct 2022 10:54:34 +0000

Хотя скорее всего. Иначе наверняка и обычный Edit устроил бы.

Re: AHK: Поле ввода на GUI

null@example.com (teadrinker) — Sat, 29 Oct 2022 10:46:45 +0000

Или про такое:

#UseHook
X_Text := 500
Y_Text := 300
fontName := "Calibri"
fontSize := 64
fontColor := 0x4682B4

Gui, Text: New, +LastFound +Owner -Caption +AlwaysOnTop +E0x20
Gui, Margin, 0, 0
Gui, Font, s%fontSize% q4 c%fontColor%, %fontName%
Gui, Color, FFFFFF
WinSet, Transcolor, FFFFFF
Gui, Add, Text
Return

F1::
   if (t := !t) {
      Hook := InputHook()
      Hook.KeyOpt("{All}", "N")
      Hook.OnKeyDown := Func("OnKeyDown").Bind(X_Text, Y_Text, fontSize, fontName)
      Hook.Start()
   }
   else {
      Gui, Text:Show, Hide
      Hook.Stop()
   }
   Return

Esc:: ExitApp

OnKeyDown(X_Text, Y_Text, fontSize, fontName, Hook, vk, sc) {
   text := Hook.Input
   if (text = "") {
      Gui, Text:Show, Hide
      Return
   }
   Gui, New
   Gui, Font, s%fontSize% q4, %fontName%
   Gui, Add, Text,, % text
   GuiControlGet, Pos, Pos, Static1
   Gui, Destroy
   
   Gui, Text: Default
   GuiControl, Move, Static1, w%PosW% h%PosH%
   GuiControl,, Static1, % text
   Gui, Show, NA x%X_Text% y%Y_Text% w%PosW% h%PosH%
}

Re: AHK: Поле ввода на GUI

null@example.com (serzh82saratov) — Sat, 29 Oct 2022 10:46:10 +0000

Тут нет поля ввода.

Re: AHK: Поле ввода на GUI

null@example.com (serzh82saratov) — Sat, 29 Oct 2022 10:44:32 +0000

Я думаю что речь про такое.


#NoEnv
#SingleInstance Force  

Gui, +AlwaysOnTop -Caption
Gui, Margin, 0, 0
Gui, Font, s66  
Gui, Font, cE5F3FF 
Gui, Color, 389AE8
Gui, Add, Text, Center Border gText1 vText1 w262, PIN
Gui, Add, Edit, vKey1 Center Hidden Limit4 Number gKey1 xp yp wp hp   
Gui, Show
Return

Esc::ExitApp 
 
Text1() {
	GuiControl, Focus, Key1
}
	
Key1() {    
	GuiControlGet, Key1 
	GuiControl, , Text1, % Key1
}

Re: AHK: Поле ввода на GUI

null@example.com (teadrinker) — Sat, 29 Oct 2022 10:39:55 +0000

Я думал без поля ввода вообще.

Re: AHK: Поле ввода на GUI

null@example.com (serzh82saratov) — Sat, 29 Oct 2022 10:38:05 +0000

Кстати "цифровое" пропустил.


#NoEnv
#SingleInstance Force  
 
Gui, Font, s16  
Gui, Add, Text, Center Border gText1 vText1 w222,кликни меня
Gui, Add, Edit, vKey1 Hidden Number gKey1 xp yp wp hp  
Gui, Add, Edit, Center wp    
Gui, Show
Return

Esc::ExitApp 
 
Text1() {
	GuiControl, Focus, Key1
}
	
Key1() {    
	GuiControlGet, Key1 
	GuiControl, , Text1, % Key1
}

Re: AHK: Поле ввода на GUI

null@example.com (serzh82saratov) — Sat, 29 Oct 2022 10:35:10 +0000

teadrinker
Так он и будет выводится в виде Gui, Add, Text.
Тебя не смущает в тз - "своё цифровое поле ввода".

Re: AHK: Поле ввода на GUI

null@example.com (teadrinker) — Sat, 29 Oct 2022 10:31:02 +0000

Я так понял, что нужно, чтобы текст выводился прямо на экран. Тогда действительно InputHook.

Re: AHK: Поле ввода на GUI

null@example.com (serzh82saratov) — Sat, 29 Oct 2022 10:25:30 +0000

Самое простое решение.


#NoEnv
#SingleInstance Force  
 
Gui, Font, s16  
Gui, Add, Text, Center Border gText1 vText1 w222,кликни меня
Gui, Add, Edit, Center wp    
Gui, Add, Edit, vKey1 Hidden gKey1 w0 h0  
Gui, Show
Return

Esc::ExitApp 
 
Text1() {
	GuiControl, Focus, Key1
}
	
Key1() {    
	GuiControlGet, Key1 
	GuiControl, , Text1, % Key1
}

Re: AHK: Поле ввода на GUI

null@example.com (Phoenixxx_Czar) — Sat, 29 Oct 2022 08:14:26 +0000

Возможно вам поможет InputHook?

Re: AHK: Поле ввода на GUI

null@example.com (Clannad5) — Sat, 29 Oct 2022 02:04:42 +0000

jbn238
Это все равно особо не говорит о том, где вы хотите это вводить, то есть, когда учитывать ваши нажатия, а когда нет.
Если ввод осуществляется внутри Gui вашего окна, тогда то, что я вам выше посоветовал, а если это происходит только в некоторых моментах, то тут немного посложнее будет.
Однако я все равно не вижу смысла от этого, если второй вариант.
Визуально бы показали, либо подождите других, может они вас поймут и ответят.

Re: AHK: Поле ввода на GUI

null@example.com (jbn238) — Sat, 29 Oct 2022 01:12:46 +0000

Clannad5
Хочу реализовать ввод пин-кода, чтобы на экране показывало какие именно цифры нажимаю, если допустил ошибку, чтобы была возможность стирать, и все это так же отображалось на экране. А именно на GUI, чтобы красиво оформить.

Re: AHK: Поле ввода на GUI

null@example.com (Clannad5) — Fri, 28 Oct 2022 21:22:32 +0000

jbn238
Не особо понял что вы хотите.
Вы хотите конкретно использовать Gui, как вывод текста при нажатий? Обычного ToolTip не подойдёт?
Если Gui, то используйте Gui + Горячие клавиши, в чём проблема?При нажатий по горячим клавишам, выводите информацию в Gui.

AHK: Поле ввода на GUI

null@example.com (jbn238) — Fri, 28 Oct 2022 15:31:27 +0000

Доброго времени, хочу сделать своё цифровое поле ввода, с помощью GUI. Например: при нажатие на кнопку 1 (неважно Num или обычную), на экране выводилось 1, после при нажатие 2, на экране уже было "12", при нажатие на Backspace чтобы символ стирался. Подскажите, пожалуйста, как можно такое реализовать?

p.s. стандартные InputBox и Gui,Edit не подходят.