Серый форум — AHK: Spintax с несколькими уровнями вложенности

Re: AHK: Spintax с несколькими уровнями вложенности

null@example.com (ppss42) — Mon, 26 Dec 2022 10:03:34 +0000

Все работает. Проверил на более сложной вариации текста, все идеально рандомизирует. Просто нет слов! Большое вам спасибо уважаемый teadrinker, не первый раз выручаете меня!

Re: AHK: Spintax с несколькими уровнями вложенности

null@example.com (teadrinker) — Mon, 26 Dec 2022 09:52:38 +0000

ppss42 пишет:

Да, действительно )

Ознакомьтесь, пожалуйста, с Правилами, отредактируйте свой пост. Обратите внимание на точки в конце предложений.
Вроде так работает:

text = {Привет {Артем|Владимир}. Как твои дела?|Здравствуй {Света|Маша}. Чем занята?}
randomText := text
while RegExMatch(randomText, "xO)( \{ (?: [^{}]++ | (?-1) )* } )", m)
   randomText := SubStr(randomText, 1, m.Pos - 1) . GetRandomText(SubStr(m[0], 2, -1)) . SubStr(randomText, m.Pos + m.Len)

MsgBox, % randomText

GetRandomText(text) {
   newText := RegExReplace(text, "(\{|(?!^)\G)((?!}).)*?\K\|", Chr(1))
   arr := StrSplit(newText, "|")
   Random, rand, 1, arr.Count()
   Return StrReplace(arr[rand], Chr(1), "|")
}

Особо не тестировал.

Re: AHK: Spintax с несколькими уровнями вложенности

null@example.com (ppss42) — Mon, 26 Dec 2022 08:48:39 +0000

teadrinker
Да, действительно. Проглядел. Возможно такой пример будет правильнее:
"{привет {Артем|Владимир}. Как твои дела?|Здравствуй {Света|Маша}. Чем занята?}"
Т.е. на выходе будет какое то одно предложение. Например "Привет Артем. Как твои дела?" либо "Здравствуй Маша. Чем занята?" Проверил на первом попавшемся онлайн сервисе по рандомизации текста, и он выдает правильную вариацию, но в приведенном выше скрипте, это не срабатывает. Искал решение на зарубежном форуме и ничего не нашел.

Re: AHK: Spintax с несколькими уровнями вложенности

null@example.com (teadrinker) — Mon, 26 Dec 2022 08:17:25 +0000

ppss42 пишет:

{Привет|Здравствуй} {Ты сейчас {дома|на улице|в кафе}}?

По-моему, здесь одна пара скобок лишняя:

{Привет|Здравствуй} Ты сейчас {дома|на улице|в кафе}?

Или я чего-то не понимаю?

AHK: Spintax с несколькими уровнями вложенности

null@example.com (ppss42) — Mon, 26 Dec 2022 02:58:58 +0000

Здравствуйте. Подскажите пожалуйста, как реализовать spintax на ahk с несколькими уровнями вложенности? На просторах рунета находил спинтакс, но он работает по типу "{Привет|Хай}" а мне необходимо как в примере ниже:
"{Привет|Здравствуй} {Ты сейчас {дома|на улице|в кафе}}?"
Скрипт который я пытался использовать:

string = {Привет|Здравствуй}
MsgBox % spintax(string)

spintax(string) {
	Pos := 1
	while (Pos := RegExMatch(string, "{([^}]*)}", M, Pos + StrLen(R)))
		string := StrReplace(string, M, R := getRandomElement(StrSplit(M1, "|")))

	return string
}

getRandomElement(Arr) {
	Random rand, 1, % Arr.Count()
	return Arr.RemoveAt(rand)
}