Серый форум — AHK: Настройка запуска/перезапуска скрипта

Re: AHK: Настройка запуска/перезапуска скрипта

null@example.com (__Михаил__) — Tue, 18 Apr 2023 14:35:28 +0000

Не проще ли нормальный код писать и не выдумывать всякие костыли? Задача быстро применять новые изменения в скрипте? Тогда просто добавив одну строку можно перезапускать текущий скрипт. Зачем искать его в папке, дважды кликать по нему?

F6:: Reload

Re: AHK: Настройка запуска/перезапуска скрипта

null@example.com (marusa122) — Mon, 17 Apr 2023 18:35:38 +0000

teadrinker спасибо, это то, что нужно!

Re: AHK: Настройка запуска/перезапуска скрипта

null@example.com (teadrinker) — Mon, 17 Apr 2023 18:05:48 +0000

Тогда можно так:

#SingleInstance Off
SetTitleMatchMode, 2
DetectHiddenWindows, On

WinGet, list, List, %A_ScriptName% ahk_class AutoHotkey
found := false
Loop % list
   continue
until list%A_Index% != A_ScriptHwnd && found := list%A_Index%

if !found
   MsgBox, 64, Готово, Script запущен!
else {
   WinMenuSelectItem, ahk_id %found%,, File, Exit (Terminate Script)
   MsgBox, 48, Перезапуск, Script перезапущен, 2
}

Но проще было бы написать в начале #SingleInstance, Force, тогда новый скрипт будет заменять старый без всяких ухищрений.

Re: AHK: Настройка запуска/перезапуска скрипта

null@example.com (marusa122) — Mon, 17 Apr 2023 17:11:49 +0000

teadrinker а как сделать так, чтобы при перезапуске закрывалась предыдущая версия скрипта? Чтобы в трее постоянно оставался только один значок - версия скрипта, актуальная после последнего перезапуска.
Например, в скрипте автозамены. В первой версии скрипта код

:*:btw::by the way

Я вношу изменения в скрипт (в Блокноте). Например, добавляю еще одну замену. Сохраняю скрипт. Теперь он выглядит так:

:*:btw::by the way
:*:exp::example

Перезапускаю скрипт, чтобы изменения вступили в силу. Выскакивает "An older instance of this script is already running. Replace it with this instance?". И пока не нажмешь "Да", новая версия версия скрипта не запустится. Цель - чтобы вместо этого оповещения выскакивал Msgbox "Выполняется перезапуск Script. Программа будет открыта через несколько секунд...", который автоматически пропадает через пару секунд, и после этого запускается обновленная версия скрипта (уже с новой добавленной автозаменой).

Re: AHK: Настройка запуска/перезапуска скрипта

null@example.com (teadrinker) — Mon, 17 Apr 2023 16:18:49 +0000

marusa122 пишет:

в трее появляется второй-третий-четвертый значок Script.ahk

Ну да, работает соответственно вашему описанию. Если скрипт уже существует, то новозапущенный скрипт выдаёт сообщение и перезапускается, соответственно, получается уже два скрипта. Если запустить ещё раз, то будет три, и т. д.

Re: AHK: Настройка запуска/перезапуска скрипта

null@example.com (marusa122) — Mon, 17 Apr 2023 15:51:53 +0000

teadrinker, да, оно! Только теперь в трее появляется второй-третий-четвертый значок Script.ahk после каждого перезапуска. Как это исправить? Пробовала поменять в вашем скрипте "#SingleInstance Off" на "#SingleInstance Force" - помогло, но опять пропал MsgBox2 с сообщением о перезапуске.

Re: AHK: Настройка запуска/перезапуска скрипта

null@example.com (teadrinker) — Mon, 17 Apr 2023 15:17:10 +0000

Если я всё правильно понял, то так:

#SingleInstance Off
SetTitleMatchMode, 2
DetectHiddenWindows, On

if A_Args[1]
   MsgBox, 64, Готово, Script запущен!
else {
   WinGet, list, List, %A_ScriptName% ahk_class AutoHotkey
   found := false
   Loop % list
      continue
   until list%A_Index% != A_ScriptHwnd && found := true
   
   if !found
      MsgBox, 64, Готово, Script запущен!
   else {
      MsgBox, 48, Перезапуск, Выполняется перезапуск Script. Программа будет открыта через несколько секунд..., 2
      Run, % A_ScriptFullPath . " 1"
      ExitApp
   }
}

Re: AHK: Настройка запуска/перезапуска скрипта

null@example.com (marusa122) — Mon, 17 Apr 2023 13:49:57 +0000

teadrinker перезапуск скрипта после появления MsgBox1 "Выполняется перезапуск программы".

Re: AHK: Настройка запуска/перезапуска скрипта

null@example.com (teadrinker) — Mon, 17 Apr 2023 06:42:47 +0000

А перезапуск когда? И что в итоге, должны работать два скрипта параллельно?

Re: AHK: Настройка запуска/перезапуска скрипта

null@example.com (marusa122) — Mon, 17 Apr 2023 03:57:24 +0000

Перезапуск чего, себя, или другого скрипта?

Перезапуск себя

Сообщать до перезапуска, или после?

До перезапуска
Извините, если я что-то упустила. Алгоритм действий скрипта должен быть таким:
1) Запускаем скрипт Script.ahk
2) Autohotkey проверяет, был ли запущен такой скрипт ранее (активен ли в данный момент такой же процесс).

Если да, то вместо "An older instance of this script is already running. Replace it with this instance?" должен появиться MsgBox1 "Выполняется перезапуск программы". Этот MsgBox1 должен исчезнуть через 3 секунды. И после него должен появиться другой MsgBox2 "Программа запущена".

Если нет, то сразу должен появиться MsgBox2 "Программа запущена".

Re: AHK: Настройка запуска/перезапуска скрипта

null@example.com (__Михаил__) — Sun, 16 Apr 2023 21:43:37 +0000

Что я делаю не так?

Да собственно всё. начиная с вопроса, заканчивая кодом.

Re: AHK: Настройка запуска/перезапуска скрипта

null@example.com (EV) — Sun, 16 Apr 2023 21:16:27 +0000

Обратите внимание на "process, exist, Script.ahk", нет процесса Script.ahk, у всех ровных пацанов процесс Script.exe , и на if errorlevel1.
Скомпилируйте Script.ahk в Script.exe если нужен process, exist.

Re: AHK: Настройка запуска/перезапуска скрипта

null@example.com (teadrinker) — Sun, 16 Apr 2023 20:59:42 +0000

marusa122 пишет:

Что я делаю не так?

Похоже, не можете сами точно сформулировать задачу.

marusa122 пишет:

Если да - выполнять перезапуск

Перезапуск чего, себя, или другого скрипта?

marusa122 пишет:

сообщать об этом с помощью другого MsgBox (MsgBox2)

Сообщать до перезапуска, или после?

marusa122 пишет:

и после этого запускать скрипт

Так мы же вроде его уже запустили?
Я запутался!

AHK: Настройка запуска/перезапуска скрипта

null@example.com (marusa122) — Sun, 16 Apr 2023 18:51:15 +0000

Здравствуйте!
Есть скрипт с названием Script.ahk - появление MsgBox1 с текстом "Программа запущена". При запуске скрипта Autohotkey должен проверять, был ли он запущен ранее и не закрыт. Если да - выполнять перезапуск, сообщать об этом с помощью другого MsgBox (MsgBox2) и после этого запускать скрипт. Пыталась написать такой скрипт, но он просто перезапускается без появления MsgBox2. Что я делаю не так?

process, exist, Script.ahk ;проверяет, был ли запущен ранее такой же скрипт
if errorlevel1
	{
	#SingleInstance Force
	MsgBox, 48, Перезапуск, Выполняется перезапуск Script. Программа будет открыта через несколько секунд..., 2 ;это MsgBox2
	MsgBox, 64, Готово, Script запущен!, ;это MsgBox1
	}
else
{
MsgBox, 64, Готово, Script запущен!, ;это MsgBox1
}