Серый форум — AHK v2: Имитация C-like

Re: AHK v2: Имитация C-like

null@example.com (m00slim25) — Fri, 08 Dec 2023 11:15:40 +0000

Ну, по всему выходит, что да - можно и так сказать.

Re: AHK v2: Имитация C-like

null@example.com (teadrinker) — Fri, 08 Dec 2023 10:56:28 +0000

Понял, что цель — неполноценно сымитировать enum, просто потому, что очень хотелось неполноценно сымитировать enum. Ну, ок.

Re: AHK v2: Имитация C-like

null@example.com (m00slim25) — Fri, 08 Dec 2023 08:44:59 +0000

Блин, примерно такого ответа я и ожидал...
Ок, «мыло и мачало, начнём ка всё сначало»©
Цель: автоматизировать присваивание значений спискам переменных, с конкретно, и жёстко, заданными именами.
Глобальный список может быть сколь угодно гигантским - десятки, сотни переменных.
Глобальный список разбит на подгруппы, состоящие из единиц, десятков, значительно реже - сотен переменных.
Порядок присваиваемых значений целочисленный инкрементный последовательный. Может начинаться с произвольного числа, либо с нуля, если начальное значение стартовой переменной не задано.
Последовательность может прерываться как в рамках глобального списка, так и в рамках конкретной локальной подгруппы.

Сама задача взята из кропотливого создания врапперов для DLL библиотек, написанных на C/C++. Со всеми вытекающими.
Так как в исходном коде оригиналов повсеместно используется встроенный оператор enum, и возникла идея перенести (сразу оговорюсь - перенести частично!!!) поведение оператора по автоматизированному присвоению значений спискам переменных в сам враппер, силами Autohotkey.
Ничего большего не требовалось.

Надеюсь, что теперь разъяснил более детально.

ЗЫ. Никаких полноценных свойств enum не требуется! Это просто невозможно. Константы не поддерживаются Autohotkey. Присвоение переменной внутри списка значения другой переменной из того же списка, но объявленной ранее - невозможно, throw ValueError будет итогом такой попытки.
Любые попытки «колдовать» над решением этих невозможностей - избыточны. Поэтому смысла не имеют.

Re: AHK v2: Имитация C-like

null@example.com (teadrinker) — Fri, 08 Dec 2023 08:08:05 +0000

Не совсем тоже понял, в чём вопрос. Ну да, получаем сразу массив значений, без предварительного указания переменных. Аналогом переменных STD_FIRST, STD_SECOND ... будет MyArray[1], MyArray[2] ...

Re: AHK v2: Имитация C-like

null@example.com (m00slim25) — Fri, 08 Dec 2023 07:56:33 +0000

В каком то, отдельно взятом случае, возможно - да, было бы удобнее.
Но для общего применения - отнюдь, первоначальный подход удобнее.

ЗЫ. И вот, кстати, я не до конца понял, либо не понял совсем. Если я в своём примере подаю на вход функции рефы на переменные, там же и объявляемые, а на выходе получаю эти переменные уже со значениями, то в Вашем примере ничего, кроме массива значений, я не увидел. Объяснитесь, пожалуйста.

Re: AHK v2: Имитация C-like

null@example.com (teadrinker) — Thu, 07 Dec 2023 11:30:40 +0000

Я не уговариваю, но разве не проще сразу получить все значения в массиве, чем указывать все переменные по одной?

Re: AHK v2: Имитация C-like

null@example.com (m00slim25) — Thu, 07 Dec 2023 10:55:50 +0000

В случае, когда лучше сделать всё как можно проще.

Re: AHK v2: Имитация C-like

null@example.com (teadrinker) — Thu, 07 Dec 2023 08:19:34 +0000

А в каком случае вместо переменных нельзя использовать элементы массива?

Re: AHK v2: Имитация C-like

null@example.com (m00slim25) — Thu, 07 Dec 2023 06:31:32 +0000

teadrinker
Код конечно интересный. Спасибо. Но такая реализация не подойдёт.

Идея была именно в автоматической инициализации списков переменных. И реализованнго выше алгоритма пока что, на данном этапе, вполне достаточно.

В то же время, в процессе реализации, стало понятно, что полностью имитировать поведение «C-like enum» не удастся. По крайней мере без поддержки на уровне интерпретатора Autohotkey (а это, боюсь, будет та же история, что с Си-шным циклом for(statement, condition, expression) - Lexikos упорно сопротивляется любым просьбам о её реализации вот уже несколько лет).

Поэтому, я считаю, любые имитации, отходящие от начального плана - это «имитации ради имитаций». Что, в общем то, излишне.
Тем не менее ещё раз спасибо за интересный код.

Re: AHK v2: Имитация C-like

null@example.com (teadrinker) — Wed, 06 Dec 2023 19:58:59 +0000

Вообще я для реализации объекта, похожего на Enum, использовал бы другой подход:

#Requires AutoHotkey v2

preset := Map(1, -5, 4, 20)
length := 5
MyEnum := Enum(preset, length)

MsgBox 'MyEnum: ' . MyEnum.toString()

MsgBox 'MyEnum[2]: ' . MyEnum[2]

try MyEnum[2] := 100
catch Error as e {
    MsgBox e.Message, 'Error', 16
}

MsgBox 'MyEnum.Length: ' . MyEnum.Length

try MyEnum.Length := 3
catch Error as e {
    MsgBox e.Message, 'Error', 16
}

try MyEnum.Push(42)
catch Error as e {
    MsgBox e.Message, 'Error', 16
}

class Enum extends Array
{
    __New(presetMap, length) {
        this.Length := length
        for k, v in this {
            this[k] := presetMap.Has(k) ? presetMap[k] : k = 1 ? 0 : this[k - 1] + 1
        }
        getItem := Array.Prototype.GetOwnPropDesc('__Item').Get
        this.DefineProp('__Item', {
            get: (s, i) => getItem(s, i),
            set: (*) => this.throwError('Enum element cannot be changed')
        })
        getLength := Array.Prototype.GetOwnPropDesc('Length').Get
        this.DefineProp('Length', {
            get: (s) => getLength(s),
            set: (*) => this.throwError('Enum length cannot be changed')
        })
        for method in ['Delete', 'InsertAt', 'Pop', 'Push', 'RemoveAt'] {
            this.DefineProp(method, {
                call: ((method, *) => this.throwError(method . '() method is not defined')).Bind(method)
            })
        }
    }

    toString() => (
        str := '', e := this.__Enum(2),
        [((*) => e(&k, &v) && (str .= (k = 1 ? '[' : ', ') . v, 1))*],
        str . ']'
    )

    throwError(text) {
        throw Error(text)
    }
}

Re: AHK v2: Имитация C-like

null@example.com (m00slim25) — Wed, 06 Dec 2023 18:56:38 +0000

Ну и поставим, так сказать, жырную точку. И закроем уже тему.
Миллион вызовов функции в цикле Loop: (десять аргументов без значений)

1. 4,8 секунд

typedef_enum(p*)
{
  for i,v in p
    %v%??%v%:=i=1?0:%p[i-1]%+1
}

2. 6,8 секунд

typedef_enum(p*)
{
  e := p.__Enum(2)
  while e(&i,&v)
    %v%??%v%:=i=1?0:%p[i-1]%+1
}

3. 14 секунд

typedef_enum(p*)=>(e:=p.__Enum(2),[((*)=>e(&i,&v)&&(%v%??%v%:=i=1?0:%p[i-1]%+1,true))*])

ПС. Странный эффект от толстой стрелки. Много раз видел такое, обёртывая разнообразные вызовы DllCall в толстую стрелку - время исполнения вызова ощутимо увеличивается, даже если целевая DLL уже загружена в контекст Autohotkey.
Но это уже совсем другая история.

Re: AHK v2: Имитация C-like

null@example.com (m00slim25) — Mon, 04 Dec 2023 11:03:06 +0000

teadrinker пишет:

Только, вызывая энумераторы подобным образом, нужно иметь в виду, что цикл for k, v in obj выполняется в несколько раз быстрее.

Re: AHK v2: Имитация C-like

null@example.com (teadrinker) — Mon, 04 Dec 2023 10:25:17 +0000

Только, вызывая энумераторы подобным образом, нужно иметь в виду, что цикл for k, v in obj выполняется в несколько раз быстрее.

Re: AHK v2: Имитация C-like

null@example.com (m00slim25) — Mon, 04 Dec 2023 09:35:54 +0000

teadrinker
Очень интересная техника. Благодарю за разъяснение!

Re: AHK v2: Имитация C-like

null@example.com (teadrinker) — Mon, 04 Dec 2023 08:51:36 +0000

[( ... )*] можно записать, как Array(( ... )*). В данном случае Array() это функция с переменным количеством параметров. В такую функцию можно передавать как перечислимый объект, так и непосредственно перечислитель. Анонимная функция

(*) => e(&k, &v) && (%v% ?? %v% := k = 1 ? 1 : %p[k - 1]% + 1, 1)

имитирует поведение перечислителя, возвращая 1, когда вызов e(&k, &v) возвращает 1, и 0 в ином случае. Таким образом, эта анонимная функция будет вызываться, пока не вернёт 0.