Серый форум — AHK: Завершение процесса после закрытия окна

Re: AHK: Завершение процесса после закрытия окна

null@example.com (Ядрён) — Fri, 07 Mar 2025 21:46:12 +0000

Уважаемый teadrinker Спасибо большое всё работает.

Re: AHK: Завершение процесса после закрытия окна

null@example.com (teadrinker) — Fri, 07 Mar 2025 20:52:12 +0000

Попробуйте так:

#Requires AutoHotkey v2
Persistent

wndClass := 'class1|class2'

EVENT_OBJECT_HIDE := 0x8003
Hook := WinEventHook(EVENT_OBJECT_HIDE, EVENT_OBJECT_HIDE, HookProc, 'F')

HookProc(hWinEventHook, event, hwnd, idObject, idChild, dwEventThread, dwmsEventTime) {
    static OBJID_WINDOW := 0
    try if (idObject = OBJID_WINDOW && WinGetClass(hwnd) ~= wndClass) {
        ProcessClose WinGetPID(hwnd)
    }
}

class WinEventHook
{
    __New(eventMin, eventMax, hookProc, options := '', idProcess := 0, idThread := 0, dwFlags := 0) {
        this.pCallback := CallbackCreate(hookProc, options, 7)
        this.hHook := DllCall('SetWinEventHook', 'UInt', eventMin, 'UInt', eventMax, 'Ptr', 0, 'Ptr', this.pCallback
                                               , 'UInt', idProcess, 'UInt', idThread, 'UInt', dwFlags, 'Ptr')
    }
    __Delete() {
        DllCall('UnhookWinEvent', 'Ptr', this.hHook)
        CallbackFree(this.pCallback)
    }
}

Re: AHK: Завершение процесса после закрытия окна

null@example.com (Ядрён) — Fri, 07 Mar 2025 20:39:27 +0000

Большое спасибо teadrinker всё работает. Подскажите как дописать несколько окон в "wndClass".

wndClass := 'GameCenter.TMainForm' or 'Qt51515QWindowIcon'

Так не работает.

Re: AHK: Завершение процесса после закрытия окна

null@example.com (teadrinker) — Fri, 07 Mar 2025 18:58:42 +0000

#Requires AutoHotkey v2
Persistent

wndClass := 'µTorrent4823DF041B09' ; класс окна, закрытие которого отслеживаем

EVENT_OBJECT_HIDE := 0x8003
Hook := WinEventHook(EVENT_OBJECT_HIDE, EVENT_OBJECT_HIDE, HookProc, 'F')

HookProc(hWinEventHook, event, hwnd, idObject, idChild, dwEventThread, dwmsEventTime) {
    static OBJID_WINDOW := 0
    try if (idObject = OBJID_WINDOW && wndClass = WinGetClass(hwnd)) {
        ProcessClose WinGetPID(hwnd)
    }
}

class WinEventHook
{
    __New(eventMin, eventMax, hookProc, options := '', idProcess := 0, idThread := 0, dwFlags := 0) {
        this.pCallback := CallbackCreate(hookProc, options, 7)
        this.hHook := DllCall('SetWinEventHook', 'UInt', eventMin, 'UInt', eventMax, 'Ptr', 0, 'Ptr', this.pCallback
                                               , 'UInt', idProcess, 'UInt', idThread, 'UInt', dwFlags, 'Ptr')
    }
    __Delete() {
        DllCall('UnhookWinEvent', 'Ptr', this.hHook)
        CallbackFree(this.pCallback)
    }
}

Re: AHK: Завершение процесса после закрытия окна

null@example.com (Ядрён) — Fri, 07 Mar 2025 16:03:48 +0000

teadrinker пишет:

Если хотите, могу пример на v2 написать, на v1 уже не хочется.

Если можно напишите.

Re: AHK: Завершение процесса после закрытия окна

null@example.com (teadrinker) — Fri, 07 Mar 2025 15:36:04 +0000

Если хотите, могу пример на v2 написать, на v1 уже не хочется.

AHK: Завершение процесса после закрытия окна

null@example.com (Ядрён) — Fri, 07 Mar 2025 13:46:51 +0000

Доброго времени суток . Подскажите как завершить процесс после закрытия окна . Есть приложения у которых нажимаешь красный крестик а оно висит в трэе.


WinWait, ahk_class GameCenter.TMainForm
WinWaitClose
{
WinGet, ahk_pid, PID, A
WinGet, active_pid, PID, A
WinGetTitle, active_title, A
}
Process, Close, %active_pid%
Return