Серый форум — AHK v2: захват текста из окна cmd.

Re: AHK v2: захват текста из окна cmd.

null@example.com (equipment66) — Mon, 14 Apr 2025 09:07:08 +0000

teadrinker пишет:

Я запускал скрипт не двойным кликом, а из редактора, поэтому у меня проблемы не возникало.

Мать его за ногу, так и есть.
Только у меня на оборот.
На десятке, при запуске двойным кликом, всё работает. Из Sci-Te - только v1.
Вот и разобрались. Надо бы тему поднять. Тем более, у меня Sci-Te на одиннадцатую криво встала, из редактора ни запуск, ни дебаг не работает, а ещё ассоциации работают через раз.

Спасибо!

Re: AHK v2: захват текста из окна cmd.

null@example.com (teadrinker) — Sun, 13 Apr 2025 22:47:41 +0000

Понял, в чём косяк второй версии. Если вы установили вторую версию поверх первой, то скрипты запускаются не сами по себе, а их запускает лаунчер, дополнительный скрипт (чтобы выбрать нужный интерпретатор), и там путаница с консолями выходит. Можно прописать в начале перезагрузку, тогда всё будет ок:

if !(DllCall('GetCommandLine', 'Str') ~= ' /restart(?!\S)') {
    Reload
}

Ну, или создать ярлык, где будет прописан путь к интерпретатору.
Вот такой вариант лучше:

#Requires AutoHotkey v2

if !(DllCall('GetCommandLine', 'Str') ~= ' /restart(?!\S)') {
    Reload
}

#HotIf WinActive('ahk_class ConsoleWindowClass')
1:: MsgBox A_Clipboard := ReadConsoleOutput(WinGetPID('A'))
#HotIf

ReadConsoleOutput(PID) {
    static STD_OUTPUT_HANDLE := -11, INVALID_HANDLE_VALUE := -1
    if !DllCall('AttachConsole', 'UInt', PID) {
        throw OSError()
    }
    hConsole := DllCall('GetStdHandle', 'UInt', STD_OUTPUT_HANDLE, 'Ptr')
    if hConsole == INVALID_HANDLE_VALUE {
        throw OSError()
    }
    CONSOLE_SCREEN_BUFFER_INFO := Buffer(24, 0)
    if !DllCall('GetConsoleScreenBufferInfo', 'Ptr', hConsole, 'Ptr', CONSOLE_SCREEN_BUFFER_INFO) {
        throw OSError()
    }
    bufferSize := NumGet(CONSOLE_SCREEN_BUFFER_INFO, 'UInt')
    bufferWidth := bufferSize & 0xFF
    bufferHeight := bufferSize >> 16
    outBuf := Buffer(bufferWidth * bufferHeight * 4, 0)
    NumPut('UInt', bufferSize, readRegion := Buffer(8, 0), 4)
    if !DllCall('ReadConsoleOutput', 'Ptr', hConsole, 'Ptr', outBuf, 'UInt', bufferSize, 'UInt', 0, 'Ptr', readRegion) {
        throw OSError()
    }
    emptyCounter := 0
    Loop bufferHeight {
        lineNum := A_Index - 1
        line := ''
        Loop bufferWidth {
            line .= Chr(NumGet(outBuf, 4 * (A_Index - 1) + lineNum * bufferWidth * 4, 'UShort'))
        }
        text .= RegExReplace(line, '\s+$', '`r`n')
        emptyCounter := (line ~= '^\s*$') ? emptyCounter + 1 : 0
    } until emptyCounter == 5
    DllCall('FreeConsole')
    return RegExReplace(text, '\s*$')
}

Я запускал скрипт не двойным кликом, а из редактора, поэтому у меня проблемы не возникало.

Re: AHK v2: захват текста из окна cmd.

null@example.com (teadrinker) — Sun, 13 Apr 2025 20:48:05 +0000

Не особо понятно, в чём может быть проблема, если v1 работает, а v2 нет. Принцип работы не отличается.

Re: AHK v2: захват текста из окна cmd.

null@example.com (equipment66) — Sun, 13 Apr 2025 17:56:18 +0000

teadrinker пишет:

Так а на какой строке ошибка?

В этих, в обоих случаях:

 if !DllCall('ReadConsoleOutputCharacter', 'Ptr', hConsole, 'Str', text, 'UInt', charCount, 'Ptr', 0, 'UInt*', &read := 0),

bResult := DllCall("ReadConsoleOutputCharacter", "ptr", hConsole, "ptr", &Buffer, "uint", characterCount, "ptr", 0, "uint*", x, "int")

Re: AHK v2: захват текста из окна cmd.

null@example.com (teadrinker) — Sun, 13 Apr 2025 17:42:47 +0000

equipment66 пишет:

Но при попытке подключения консоли к процессу ошибок не было.

Так а на какой строке ошибка?

Re: AHK v2: захват текста из окна cmd.

null@example.com (equipment66) — Sun, 13 Apr 2025 15:55:03 +0000

teadrinker
Проверил обе версии скрипта на 4 машинках:
....................................AHK v1...............AHK v2
WinXP SP3.................не работает..............n/a
Win10.......................не работает...............n/a
Win10 (основной).........работает...........не работает
Win11..........................работает.............работает

Похоже, на разных машинах тот же код может вести себя по разному.

Если эта ошибка случилась на функции AttachConsole, то это бывает тогда, когда функция не видит консоль у процесса.

Но при попытке подключения консоли к процессу ошибок не было.
К тому же, у меня на той же машинке, один работает, другой - нет.
Надо будет попробовать в более развернутом виде потом переписать, авось отловлю что-то.

Re: AHK v2: захват текста из окна cmd.

null@example.com (teadrinker) — Sun, 13 Apr 2025 12:49:58 +0000

Если эта ошибка случилась на функции AttachConsole, то это бывает тогда, когда функция не видит консоль у процесса.

learn.microsoft пишет:

If the specified process does not have a console, the error code returned is ERROR_INVALID_HANDLE

Но у меня на Windows 10 работает.

Re: AHK v2: захват текста из окна cmd.

null@example.com (equipment66) — Sun, 13 Apr 2025 09:25:23 +0000

teadrinker
Вечерком гляну.

Re: AHK v2: захват текста из окна cmd.

null@example.com (teadrinker) — Sun, 13 Apr 2025 08:53:33 +0000

А код на v1 работает?

Re: AHK v2: захват текста из окна cmd.

null@example.com (equipment66) — Sun, 13 Apr 2025 08:18:07 +0000

teadrinker
Спасибо.
На Win11 так работает.
А вот на Win10 - нет, при попытке извлечь текст выдает "Error: (6) The handle is invalid".
К стати, обратил внимание, что у меня и Winspector Spy консоли среди процессов не видит.

Re: AHK v2: захват текста из окна cmd.

null@example.com (teadrinker) — Sat, 12 Apr 2025 15:29:37 +0000

На v2 так:

#Requires AutoHotkey v2

characterCount := 1000 ; сколько символов всего нужно прочитать

#HotIf WinActive('ahk_class ConsoleWindowClass')
1:: MsgBox ReadConsoleOutput(characterCount)
#HotIf

ReadConsoleOutput(charCount) {
    static STD_OUTPUT_HANDLE := -11, INVALID_HANDLE_VALUE := -1
    if !DllCall('AttachConsole', 'UInt', WinGetPID('A')) {
        throw OSError()
    }
    hConsole := DllCall('GetStdHandle', 'UInt', STD_OUTPUT_HANDLE, 'Ptr')
    if hConsole == INVALID_HANDLE_VALUE {
        throw OSError()
    }
    VarSetStrCapacity(&text, charCount * 2)
    if !DllCall('ReadConsoleOutputCharacter', 'Ptr', hConsole, 'Str', text,
                                              'UInt', charCount, 'Ptr', 0, 'UInt*', &read := 0) {
        throw OSError()
    }
    DllCall('FreeConsole')
    return text
}

Re: AHK v2: захват текста из окна cmd.

null@example.com (equipment66) — Sat, 12 Apr 2025 10:25:40 +0000

teadrinker

Поправил.

Re: AHK v2: захват текста из окна cmd.

null@example.com (teadrinker) — Sat, 12 Apr 2025 09:23:51 +0000

equipment66 пишет:

в АНК v2 он не работает:

А, я не понял, что под v2 нужно. Позже подправлю. Измените язык в заголовке на AHK v2.

Re: AHK v2: захват текста из окна cmd.

null@example.com (equipment66) — Sat, 12 Apr 2025 08:02:57 +0000

teadrinker

Ну, в АНК v2 он не работает:
1:

VarSetStrCapacity(&Buffer, characterCount*2)

- функция требует референции, а ее к Buffer нельзя применить. Ну, в мануале пишут, что применение этой функции не обязательно.

2: В строке

DllCall("ReadConsoleOutputCharacter", "ptr", hConsole, "ptr", &Buffer, "uint", characterCount, "ptr", 0, "uint*", x, "int")

какая-то путаница с аргументами:

2.1: Вот здесь

"ptr", &Buffer

насколько я понимаю, требуется использовать "str", так как функция возвращает LPTSTR :
https://learn.microsoft.com/en-us/windo … tcharacter
https://script-coding.com/AutoHotkey/DllCall.html
при смене жалуется на "Error: Expected a String but got a Class."

2.2: для чего используется переменная "x"? При попытке исполнения получаем "Error: This global variable has not been assigned a value." То есть, интерпретатор полагает, что х является вводной? Но по документации, так понимаю, в ее должно выводится количество считанных символов?

Re: AHK v2: захват текста из окна cmd.

null@example.com (teadrinker) — Fri, 11 Apr 2025 20:06:48 +0000

У меня код из этого поста работает. Немного подправил его:

characterCount := 1000 ; сколько символов всего нужно прочитать

#IfWinActive ahk_class ConsoleWindowClass
1:: MsgBox % ReadConsoleOutput(characterCount)

ReadConsoleOutput(characterCount) {
    WinGet, dwProcessId, PID, A ;окно консоли должно быть активно.
    bResult := DllCall("AttachConsole", "uint", dwProcessId, "int")
    if(!bResult)
    {
        msgbox не удалось подключиться к консоли
        return
    }
    hConsole := DllCall("GetStdHandle", "uint", -11, "ptr")
    if(hConsole==-1)
    {
        msgbox не удалось получить хендл консоли
        return
    }
    VarSetCapacity(Buffer, characterCount * 2, 0) ;консоль должна быть юникодной
    bResult := DllCall("ReadConsoleOutputCharacter", "ptr", hConsole, "ptr", &Buffer, "uint", characterCount, "ptr", 0, "uint*", x, "int")
    if(!bResult)
    {
        msgbox не удалось получить данные
        return
    }
    DllCall("FreeConsole")
    Return StrGet(&Buffer, "UTF-16")
}