Серый форум — AHK v2: InputHook()

Re: AHK v2: InputHook()

null@example.com (bilolbi) — Sun, 07 Dec 2025 10:09:17 +0000

Ошибка возникает из-за того, что ИИ смешал синтаксис JavaScript и AutoHotkey v2.

В AutoHotkey v2 стрелочная функция => ожидает одно выражение, а не блок кода в фигурных скобках {...}. Когда интерпретатор AHK видит { сразу после =>, он думает, что вы пытаетесь создать Объект (Object Literal), и поэтому требует пары "ключ: значение" (propertyname:), а находит MsgBox.

Кроме того, ИИ выдумал метод .On(). У объекта InputHook в AHK v2 нет метода On. Для назначения событий используются свойства (например, OnKeyDown).

#Requires AutoHotkey v2.0

MsgBox "Версия: " A_AhkVersion

ih := InputHook()
; Важно: включаем уведомления (N) для всех клавиш, иначе событие не сработает
ih.KeyOpt("{All}", "N")

; Назначаем функцию-обработчик по имени (без скобок вызова)
ih.OnKeyDown := MyKeyDownFunc

ih.Start()

; --- Отдельная функция для обработки нажатия ---
MyKeyDownFunc(ihObj, vk, sc) {
    MsgBox("Нажата клавиша vk: " vk)
    ihObj.Stop() ; Останавливаем хук после первого нажатия
}

Re: AHK v2: InputHook()

null@example.com (teadrinker) — Fri, 30 May 2025 21:20:44 +0000

InputHook тут не при чём вообще. Стрелочные функции в AHK v2.0 не поддерживают фигурные скобки, а так же многострочные выражения. Грок наверно крутой (не пользуюсь для кода), но писать код нейросетями без понимания — не лучшая затея.

Re: AHK v2: InputHook()

null@example.com (1srafel) — Fri, 30 May 2025 19:05:40 +0000

Пожалуй, не актуально. Grok предложил рабочий вариант без InputHook(). И вообще он лучше остальных ИИ пишет код.

AHK v2: InputHook()

null@example.com (1srafel) — Fri, 30 May 2025 18:17:25 +0000

Пытался составить код с ИИ для работы одного функционала с InputHook(). В итоге после ошибок на моей стороне, ИИ дал этот фрагмент для проверки того, что InputHook() у меня вообще работает:

#Requires AutoHotkey v2.0

MsgBox "Версия: " A_AhkVersion

ih := InputHook()
ih.On("KeyDown", (ihObj, vk, sc) => {
    MsgBox("Нажата клавиша vk: " vk)
    ih.Stop()
})
ih.Start()

Но после запуска я всегда получаю ошибку:

Error: Missing "propertyname:" in object literal.

	005: ih := InputHook()
	006: {
▶	006: Return  { MsgBox("Нажата клавиша vk: " vk) ih.Stop() }

Версия v2 последняя. В чем может быть дело?