Серый форум — VBS: Удаление файлов с завершением процессов.

Re: VBS: Удаление файлов с завершением процессов.

null@example.com (alexii) — Thu, 25 Nov 2010 20:49:23 +0000

Ну, да. Это ведь, в принципе, то же самое, только «ручками». А в примере по ссылке делается автоматически: в основной части — перебор всех смонтированных дисков, из них отбираются нужные (и доступные), затем вызывается процедура перебора для корневого каталога диска.

Re: VBS: Удаление файлов с завершением процессов.

null@example.com (maxv) — Thu, 25 Nov 2010 19:08:48 +0000

Понятно. А, например, через маску, если указать -

RecourseDeleteByMask shell.GetFolder("C:\"), "*.$$$"
RecourseDeleteByMask shell.GetFolder("D:\"), "*.$$$"
RecourseDeleteByMask shell.GetFolder("E:\"), "*.$$$"

возможно?

Re: VBS: Удаление файлов с завершением процессов.

null@example.com (alexii) — Thu, 25 Nov 2010 18:44:35 +0000

В «RecourseDeleteByMask» — никак. Этот перебор надо делать снаружи, в основном модуле, наподобие этого: VBScript: поиск файла.

Re: VBS: Удаление файлов с завершением процессов.

null@example.com (maxv) — Thu, 25 Nov 2010 16:50:18 +0000

А каким образом в RecourseDeleteByMask можно указать все DriveType=1?
То есть сканирование всех внешних носителей.

Re: VBS: Удаление файлов с завершением процессов.

null@example.com (alexii) — Thu, 18 Nov 2010 17:46:08 +0000

Угу. Периодически забываю, что не везде поддерживаются маски. File/FolderExists — самое печальное из этого. Приношу свои извинения.

Тогда без вариантов, дабы избежать плясок с бубном — надо перенести команду удаления внутрь «On Error…» и добавить сразу после неё Err.Clear.

Re: VBS: Удаление файлов с завершением процессов.

null@example.com (maxv) — Thu, 18 Nov 2010 16:44:37 +0000

    If objFSO.FileExists(strFullMask) Then
        objFSO.DeleteFile strFullMask, True                              ' Удаляем файлы по маске.
    End If

не работает вообще

Re: VBS: Удаление файлов с завершением процессов.

null@example.com (alexii) — Thu, 18 Nov 2010 16:24:40 +0000

maxv пишет:

после цикла лучше поставить smile

Разве от этого скрипт падать перестанет (если убрать On Error Resume Next)? Посему такой вариант мне не нравится.

Re: VBS: Удаление файлов с завершением процессов.

null@example.com (alexii) — Thu, 18 Nov 2010 16:22:00 +0000

Спасибо, ясно. Правда, дело обстоит несколько иначе: скрипт не «не обрабатывает», а банально падает с ошибкой из-за:

DeleteFile Method пишет:

Remarks
An error occurs if no matching files are found. …

Тогда, думаю, следует поменять логику таким образом, с:

    objFSO.DeleteFile strFullMask, True                              ' Удаляем файлы по маске.

на:

    If objFSO.FileExists(strFullMask) Then
        objFSO.DeleteFile strFullMask, True                              ' Удаляем файлы по маске.
    End If

Re: VBS: Удаление файлов с завершением процессов.

null@example.com (maxv) — Thu, 18 Nov 2010 16:12:49 +0000

objFSO.DeleteFile strFullMask, True

после цикла лучше поставить

Option Explicit

Dim objFSO

Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

RecourseDeleteByMask objFSO.GetFolder("D:\111111"), "*.cdx"

Set objFSO = Nothing

WScript.Quit 0
'=============================================================================
Sub RecourseDeleteByMask(objFolder, strMask)
    Dim objSubFolder
    Dim strFullMask
    
    WScript.Echo objFolder.Path                                      ' Выводим путь обрабатываемой папки (для
                                                                     ' отладки; имеет смысл закомментировать).
    
    strFullMask = objFSO.BuildPath(objFolder.Path, strMask)          ' Строим полный путь.
    
    On Error Resume Next                                             ' Обрабатываем ошибки, возможные в случае,
                                                                     ' когда нет доступа к содержимому папки
                                                                     ' (пример - «System Volume Information».
    For Each objSubFolder In objFolder.SubFolders
        If Err.Number = 0 Then                                       ' Удалось получить доступ к содержимому папки?
            RecourseDeleteByMask objSubFolder, strMask               ' Вызываем процедуру для каждой из подпапок.
        Else                                                         ' Если не удалось —
            Err.Clear                                                ' сбрасываем состояние ошибки и движемся дальше.
            WScript.Echo "Can't enumerate subfolders for folder [" & objFolder.Path & "]."
        End If
    Next

    objFSO.DeleteFile strFullMask, True                              ' Удаляем файлы по маске.
    
    On Error Goto 0                                                  ' Восстанавливаем стандартную обработку ошибок
End Sub

Re: VBS: Удаление файлов с завершением процессов.

null@example.com (maxv) — Thu, 18 Nov 2010 16:04:39 +0000

#16

Option Explicit

Dim objFSO

Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

RecourseDeleteByMask objFSO.GetFolder("D:\111111"), "*.cdx"

Set objFSO = Nothing

WScript.Quit 0
'=============================================================================
Sub RecourseDeleteByMask(objFolder, strMask)
    Dim objSubFolder
    Dim strFullMask
    
    WScript.Echo objFolder.Path                                      ' Выводим путь обрабатываемой папки (для
                                                                     ' отладки; имеет смысл закомментировать).
    
    strFullMask = objFSO.BuildPath(objFolder.Path, strMask)          ' Строим полный путь.
    
    objFSO.DeleteFile strFullMask, True                              ' Удаляем файлы по маске.
    
    On Error Resume Next                                             ' Обрабатываем ошибки, возможные в случае,
                                                                     ' когда нет доступа к содержимому папки
                                                                     ' (пример - «System Volume Information».
    For Each objSubFolder In objFolder.SubFolders
        If Err.Number = 0 Then                                       ' Удалось получить доступ к содержимому папки?
            RecourseDeleteByMask objSubFolder, strMask               ' Вызываем процедуру для каждой из подпапок.
        Else                                                         ' Если не удалось —
            Err.Clear                                                ' сбрасываем состояние ошибки и движемся дальше.
            WScript.Echo "Can't enumerate subfolders for folder [" & objFolder.Path & "]."
        End If
    Next
    
    On Error Goto 0                                                  ' Восстанавливаем стандартную обработку ошибок
End Sub

Re: VBS: Удаление файлов с завершением процессов.

null@example.com (alexii) — Thu, 18 Nov 2010 15:58:14 +0000

maxv, какой именно скрипт: укажите пост со скриптом, к которому относится Ваше сообщение.

Re: VBS: Удаление файлов с завершением процессов.

null@example.com (maxv) — Thu, 18 Nov 2010 15:29:55 +0000

Данный скрипт работает при условии, если найден файл в корне, то происходит обработка в подпапках.
Если в корне фалов по маске не найдено, то подпапки скрипт не обрабатывает.

Re: VBS: Удаление файлов с завершением процессов.

null@example.com (Arlekin_s) — Mon, 16 Mar 2009 10:30:53 +0000

о )) спасибо большое )

Re: VBS: Удаление файлов с завершением процессов.

null@example.com (alexii) — Mon, 16 Mar 2009 10:16:17 +0000

Правильно ругается. Пишите так:

RecourseDeleteByMask objFSO.GetFolder("D:\111111"), "*.cdx"
RecourseDeleteByMask objFSO.GetFolder("D:\111111"), "*.dbf"

Или надо менять саму функцию «RecourseDeleteByMask» для поддержки множественных масок.

Re: VBS: Удаление файлов с завершением процессов.

null@example.com (Arlekin_s) — Mon, 16 Mar 2009 10:08:09 +0000

ну я имел ввиду что одного типа файлов. т.е. если я пишу

RecourseDeleteByMask objFSO.GetFolder("D:\111111"), "*.cdx, *.dbf"

то он ругается вот на эту строку.

objFSO.DeleteFile strFullMask, True

Не может найти файл.