Серый форум — AutoHotKey: Передача указателя между двумя процессами (скриптами)

Re: AutoHotKey: Передача указателя между двумя процессами (скриптами)

null@example.com (cahta_emae30) — Fri, 09 Feb 2018 16:55:42 +0000

Так началась легенда...

Re: AutoHotKey: Передача указателя между двумя процессами (скриптами)

null@example.com (YMP) — Tue, 26 May 2009 12:58:41 +0000

garkin пишет:

А чем отличается MoveMemory от CopyMemory? Я так понял, что movememory может копировать между перекрывающимися блоками. Она затирает за собой память источника, или просто использует промежуточный буфер?

Видимо, разница именно в этом. MoveMemory именно копирует, источник она специально не затирает. Если блоки перекрываются и запись должна затирать места, которые ещё не прочитаны, она просто меняет направление копирования на обратное, т.е. копирует с конца к началу. Буфер не используется.

Re: AutoHotKey: Передача указателя между двумя процессами (скриптами)

null@example.com (garkin) — Mon, 25 May 2009 17:34:05 +0000

Огромное спасибо. А чем отличается MoveMemory от CopyMemory? Я так понял, что movememory может копировать между перекрывающимися блоками. Она затирает за собой память источника, или просто использует промежуточный буфер?

Re: AutoHotKey: Передача указателя между двумя процессами (скриптами)

null@example.com (YMP) — Mon, 25 May 2009 12:18:56 +0000

Расследование показало, что CopyMemory — это псевдоним RtlCopyMemory, которая в свою очередь — псевдоним memcpy. Ну и типы неправильные были. Так что, видимо, так:

From:= "abcdefgh"
To:="1234567890"

DllCall("msvcrt\memcpy"
       , "Str", To
       , "Str", From
       , "Uint", 5
       , "Cdecl")

msgbox % "DllResult: " To

Ещё можно использовать RtlMoveMemory:

From:= "abcdefgh"
To:="1234567890"

DllCall("RtlMoveMemory"
       , "Str", To
       , "Str", From
       , "Uint", 5)

msgbox % "DllResult: " To

Re: AutoHotKey: Передача указателя между двумя процессами (скриптами)

null@example.com (garkin) — Mon, 25 May 2009 10:40:14 +0000

Не могу заставить работать CopyMemory, подскажите где глюк.

    From:= "abcdefgh"
    To:="1234567890"

    DllCall("CopyMemory"
       , UintP, To
       , UintP, From
       , Uint, 5)

    msgbox % "DllResult: " To    ;И фиг - нет изменений, "1234567890"
ExitApp

Re: AutoHotKey: Передача указателя между двумя процессами (скриптами)

null@example.com (Wlad) — Sun, 24 May 2009 13:43:59 +0000

garkin пишет:

Ну уж если совсем извращаться, то можно и невидимый контрол на форме.

Тоже вариант, но все равно придется использовать "PostMessage" для передачи скрипту момента изменения контрола.

Re: AutoHotKey: Передача указателя между двумя процессами (скриптами)

null@example.com (garkin) — Sun, 24 May 2009 13:35:34 +0000

Wlad пишет:

Еще вариант - использовать буфер обмена.
передающий скрипт:
clipboard = 123456
принимающий скрипт:
OnClipboardChange:
MsgBox, %clipboard%
return

Ну уж если совсем извращаться, то можно и невидимый контрол на форме.

Re: AutoHotKey: Передача указателя между двумя процессами (скриптами)

null@example.com (Wlad) — Sun, 24 May 2009 13:32:50 +0000

Еще вариант - использовать буфер обмена.

передающий скрипт:
clipboard = 123456

принимающий скрипт:
OnClipboardChange:
MsgBox, %clipboard%
return

Re: AutoHotKey: Передача указателя между двумя процессами (скриптами)

null@example.com (teadrinker) — Sun, 24 May 2009 10:19:49 +0000

Всё когда-то случается впервые...:rolleyes: Но лучше поздно, чем никогда!

Re: AutoHotKey: Передача указателя между двумя процессами (скриптами)

null@example.com (YMP) — Sun, 24 May 2009 10:11:17 +0000

teadrinker пишет:

Каюсь. Но, справедливости ради, о нём можно было узнать ещё несколькими постами ранее, а также в конце этой страницы.

И что тебе помешало? Давай уж до конца кайся, облегчи душу.

Re: AutoHotKey: Передача указателя между двумя процессами (скриптами)

null@example.com (teadrinker) — Sun, 24 May 2009 10:00:27 +0000

Каюсь. Но, справедливости ради, о нём можно было узнать ещё несколькими постами ранее, а также в конце этой страницы.

Re: AutoHotKey: Передача указателя между двумя процессами (скриптами)

null@example.com (YMP) — Sun, 24 May 2009 09:23:16 +0000

teadrinker пишет:

А зачем? В Windows для обмена данными уже существует сообщение WM_COPYDATA.

А ты давно о нём узнал-то? Судя по #5, недавно. Ну а я только что — от тебя.

Re: AutoHotKey: Передача указателя между двумя процессами (скриптами)

null@example.com (teadrinker) — Sun, 24 May 2009 08:12:12 +0000

YMP пишет:

Можно, например, зарегистрировать в обоих скриптах оконное сообщение...

А зачем? В Windows для обмена данными уже существует сообщение WM_COPYDATA.

Re: AutoHotKey: Передача указателя между двумя процессами (скриптами)

null@example.com (garkin) — Sun, 24 May 2009 07:30:58 +0000

YMP, огромное спасибо за пример реализации.
Просто у меня был уже отлаженый код для работы внутри одного скрипта с этим сообщением, где для своих нужд задействованы и lparam и wparam и была дилетантская надежда, что можно адаптироваться к многопроцессности без смены структуры сообщений, превратив указатель в волшебный "глобальный" вид, вроде far указаетлей dos.

Re: AutoHotKey: Передача указателя между двумя процессами (скриптами)

null@example.com (YMP) — Sun, 24 May 2009 05:12:32 +0000

garkin
Не уверен, что точно понял Вашу ситуацию, но вот такая идея: у функций SendMessage и PostMessage есть два параметра — lParam и wParam. Вот уже два числа. Можно, например, зарегистрировать в обоих скриптах оконное сообщение с одним и тем же именем, и в нём потом пересылать PID и указатель (ReadAddress). А можно и два сообщения создать, в одном пересылать PID, а в другом — адрес данных и их размер.

Передающий скрипт:

Data =
(
Я теперь скупее стал в желаньях,
Жизнь моя, иль ты приснилась мне?
Словно я весенней гулкой ранью
Проскакал на розовом коне.
)

WinTitle := "Окно №1"  ; Заголовок целевого окна.
PID := DllCall("GetCurrentProcessId")

MsgPID  := DllCall("RegisterWindowMessage", "Str", "MsgPID")
MsgData := DllCall("RegisterWindowMessage", "Str", "MsgData")

F11::  ; Посылать по нажатию F11.
  hWnd := WinExist(WinTitle)
  If not hWnd {
    MsgBox, Не найдено окно:`n%WinTitle%.
    Return
  }

  wParam := PID
  lParam := 0    ; Сюда тоже что-нибудь можно положить.
  PostMessage, MsgPID, wParam, lParam,, ahk_id %hWnd%   ; Посылаем PID.

  wParam := &Data
  lParam := StrLen(Data) + 1  ; Учитываем нулевой байт в конце строки.
  PostMessage, MsgData, wParam, lParam,, ahk_id %hWnd%  ; Адрес данных и размер.
Return

Принимающий скрипт:

WinTitle := "Окно №1"

MsgPID  := DllCall("RegisterWindowMessage", "Str", "MsgPID")
MsgData := DllCall("RegisterWindowMessage", "Str", "MsgData")

OnMessage(MsgPID, "GetPID")   ; Регистрация функций для обработки сообщений.
OnMessage(MsgData, "GetData")

Gui, Show, w400 h300, %WinTitle%
Return


GetPID(wParam, lParam, uMsg, hWnd)
{
  Global PID := wParam
}

GetData(wParam, lParam, uMsg, hWnd)
{
  Global PID
  ReadAddress := wParam             ; Адрес, откуда читать.
  ReadSize := lParam                ; Сколько байт считывать.
  VarSetCapacity(Buf, ReadSize, 0)  ; Буфер, куда считывать.
  
  PROCESS_VM_READ := 0x10           ; Права на процесс.
  
  hProcess := DllCall("OpenProcess", UInt, PROCESS_VM_READ
                                   , Int, False
                                   , UInt, PID)
  If(!hProcess) {
    MsgBox, Не удалось открыть процесс.
    Return
  }
  
  Ret := DllCall("ReadProcessMemory", UInt, hProcess
                                    , UInt, ReadAddress
                                    , UInt, &Buf
                                    , UInt, ReadSize
                                    , UInt, 0)
  
  DllCall("CloseHandle", UInt, hProcess) ; Освобождение хэндла процесса.
  
  If(!Ret) {
    MsgBox, Не удалось прочитать.
    Return
  }
  
  VarSetCapacity(Buf, -1) ; Обновление размера переменной, поскольку запись в неё
                          ; произошла со стороны и AutoHotkey об этом не знает.  
  MsgBox, %Buf%
}

GuiClose:
  ExitApp