Серый форум — AHK: Как перекодировать файл из UTF8 в ANSI

Re: AHK: Как перекодировать файл из UTF8 в ANSI

null@example.com (YMP) — Thu, 11 Aug 2016 04:25:11 +0000

Мне такой метод не известен.

Re: AHK: Как перекодировать файл из UTF8 в ANSI

null@example.com (Malcev) — Thu, 11 Aug 2016 00:34:24 +0000

А вот такие символы возможно заменить иным методом, кроме как через RegexReplace?

msgbox % replace("ÐæẔ")

replace(data)
{
   list:={ầẦắẮằẰẵẴảẢạẠậẬấẤ:"a",æÆǣǢ:"ae",ßþÞ:"b",ḑḐðÐḍḌḑḐ:"d",ếẾềỀệỆǝƎəƏểỂễỄẹ̀Ẹ̀ɛ́ɛƐ:"e",ḩḨḥḤẖ̱̲̲ḩḨ:"h",ııỉỈịỊ:"i",ŋŊ:"n",ốỐồỒọỌớỚộỘɔƆɔ́Ɔ́ổỔỏỎ:"o",œŒœ̆Œ̆:"oe",ṣṢș̲̲:"s",ṭṬț:"t",ủỦừỪựỰụỤṳṲứỨ:"u",ỹỸỳỲ̧̧̄̄:"y",ẕẔ:"z"}
   for k,v in list
      data := RegexReplace(data, "[" k "]", v)
   return data
}

Re: AHK: Как перекодировать файл из UTF8 в ANSI

null@example.com (YMP) — Tue, 02 Feb 2016 21:03:34 +0000

Одним никак, наверно, только через посредство какого-нибудь Юникода. Кстати, Latin-1 — это тоже ANSI, только не наша.

Re: AHK: Как перекодировать файл из UTF8 в ANSI

null@example.com (Malcev) — Tue, 02 Feb 2016 17:40:57 +0000

А как одним махом можно преобразовать ISO 8859-1 Latin 1; Western European (ISO) в Ansi?
У меня только через 2 преобразования получается:

var := "Ã³"
Utf8ToLatin(var)
MsgBox, % ToAnsi(var)

Utf8ToLatin(ByRef string) {
   VarSetCapacity(latin, StrPut(string, "cp28591"))
   StrPut(string, &latin, "cp28591")
   string := StrGet(&latin, "UTF-8")
}

ToAnsi(str)
{
    len := StrLen(str)
    VarSetCapacity(buf, len)
    prev_locale := StrGet( DllCall("msvcrt.dll\_wsetlocale", "int", 0, "ptr", 0, "cdecl") )
    DllCall("msvcrt.dll\_wsetlocale", "int", 0, "str", "Russian", "cdecl")
    DllCall("msvcrt.dll\wcstombs", "ptr", &buf, "str", str, "ptr", len, "cdecl")
    DllCall("msvcrt.dll\_wsetlocale", "int", 0, "str", prev_locale, "cdecl")
    Return StrGet(&buf, len, "cp0")
}

Re: AHK: Как перекодировать файл из UTF8 в ANSI

null@example.com (Malcev) — Thu, 02 Jul 2015 11:12:29 +0000

YMP, спасибо!

А чем вам создание файла конкретно мешает? Я так понимаю, это религия?

Просто этих обработок очень много - из-за этого притормаживает и не хочется ресурс SSD диска рассходовать.

Re: AHK: Как перекодировать файл из UTF8 в ANSI

null@example.com (YMP) — Thu, 02 Jul 2015 10:23:43 +0000

Два раза можно не открывать.


str := "Ä"
MsgBox, % Utf2Ansi(str)

Utf2Ansi(str)
{
   File := FileOpen("utf8", "rw", "CP0")
   File.Write(str)
   File.Pos := 0
   ansi := File.Read()
   File.Close()
   FileDelete, utf8
   Return, ansi
}

А чем вам создание файла конкретно мешает? Я так понимаю, это религия? Какая-то идиосинкразия к временным файлам у народа.

Без файла можно, но тогда больше писанины.


str := "Ä"
MsgBox, % ToAnsi(str)

ToAnsi(str)
{
    len := StrLen(str)
    VarSetCapacity(buf, len)
    prev_locale := StrGet( DllCall("msvcrt.dll\_wsetlocale", "int", 0, "ptr", 0, "cdecl") )
    DllCall("msvcrt.dll\_wsetlocale", "int", 0, "str", "Russian", "cdecl")
    DllCall("msvcrt.dll\wcstombs", "ptr", &buf, "str", str, "ptr", len, "cdecl")
    DllCall("msvcrt.dll\_wsetlocale", "int", 0, "str", prev_locale, "cdecl")
    Return StrGet(&buf, len, "cp0")
}

Re: AHK: Как перекодировать файл из UTF8 в ANSI

null@example.com (Malcev) — Thu, 02 Jul 2015 09:45:18 +0000

Так разве лучше? Все-равно файл потом как-то удалять надо.
Жалко, что нельзя вообще без создания файла сделать.

str := "Ä"
MsgBox, % Utf2Ansi(str)

Utf2Ansi(str)
{
   File := FileOpen("utf8", "w", "CP0")
   File.Write(str)
   File.Close()
   File := FileOpen("utf8", "r-d", "CP0")
   ansi := File.Read()
   File.Close()
   Return, ansi
}

Re: AHK: Как перекодировать файл из UTF8 в ANSI

null@example.com (YMP) — Thu, 02 Jul 2015 06:33:44 +0000

Со StrPut/StrGet не выходит, заменяется на "?". Вариант через файл вполне годится. Этот файл даже на диск-то записаться не успеет, я думаю, т.е. все операции в памяти проходят. Только желательно единообразие. А то выглядит каким-то винегретом. Сначала объект используете, потом просто команды.

Re: AHK: Как перекодировать файл из UTF8 в ANSI

null@example.com (Malcev) — Thu, 02 Jul 2015 01:21:02 +0000

Мне надо чтобы получился результат идентичным сохранению в блокноте не ANSI символов, как ANSI.
То есть копируем этот символ в блокнот, сохраняем документ как ANSI.
Notepad сделает предупреждение, что не все символы сохранятся - мы согласимся с этим.
Закроем этот документ и откроем снова.
В результате "Ä" переконвертится в "A".

Re: AHK: Как перекодировать файл из UTF8 в ANSI

null@example.com (YMP) — Thu, 02 Jul 2015 01:13:31 +0000

А где у вас перекодировка? Вместо одного символа получается совсем другой.
В переменной str не utf-8, а utf-16. Можете конкретнее описать ситуацию, где вам требуется перекодировать?

Re: AHK: Как перекодировать файл из UTF8 в ANSI

null@example.com (Malcev) — Thu, 02 Jul 2015 00:56:57 +0000

Не пойму как использовать. Подскажешь? А то сейчас приходится через временный файл кодировать.

str := "Ä"
MsgBox, % Utf2Ansi(str)

Utf2Ansi(str)
{
   FileOpen("utf8", "w", "CP0").Write(str)
   FileRead, ansi, utf8
   FileDelete, utf8
   Return, ansi
}

Re: AHK: Как перекодировать файл из UTF8 в ANSI

null@example.com (teadrinker) — Sun, 21 Jun 2015 09:53:45 +0000

Сейчас этот способ уже не актуален, для перекодировки можно использовать StrPut/StrGet.

Re: AHK: Как перекодировать файл из UTF8 в ANSI

null@example.com (Malcev) — Sun, 21 Jun 2015 09:35:09 +0000

А как сделать с помощью этого кода конвертацию UTF-8 символов в ANSI?
Так не оплучается:

msgbox % Ansi := Utf8ToAnsi("Ä")  ; Преобразуем в Ansi.


; ---- Функция преобразования ----

Utf8ToAnsi(ByRef Utf8String, CodePage = 1251)
{
    If (NumGet(Utf8String) & 0xFFFFFF) = 0xBFBBEF
        BOM = 3
    Else
        BOM = 0

    UniSize := DllCall("MultiByteToWideChar", "UInt", 65001, "UInt", 0
                                            , "UInt", &Utf8String + BOM, "Int", -1
                                            , "Int", 0, "Int", 0)
    VarSetCapacity(UniBuf, UniSize * 2)
    DllCall("MultiByteToWideChar", "UInt", 65001, "UInt", 0
                                 , "UInt", &Utf8String + BOM, "Int", -1
                                 , "UInt", &UniBuf, "Int", UniSize)

    AnsiSize := DllCall("WideCharToMultiByte", "UInt", CodePage, "UInt", 0
                                             , "UInt", &UniBuf, "Int", -1
                                             , "Int", 0, "Int", 0
                                             , "Int", 0, "Int", 0)
    VarSetCapacity(AnsiString, AnsiSize)
    DllCall("WideCharToMultiByte", "UInt", CodePage, "UInt", 0
                                 , "UInt", &UniBuf, "Int", -1
                                 , "Str", AnsiString, "Int", AnsiSize
                                 , "Int", 0, "Int", 0)
    Return AnsiString
}

Re: AHK: Как перекодировать файл из UTF8 в ANSI

null@example.com (teadrinker) — Fri, 01 Oct 2010 17:57:00 +0000

Спасибо, понял.

Re: AHK: Как перекодировать файл из UTF8 в ANSI

null@example.com (YMP) — Fri, 01 Oct 2010 17:54:14 +0000

Вообще-то, смотря какая кодировка. Говорят, дальневосточные ANSI многобайтные и там соотношение размеров сложнее. Поэтому и требуется такой предварительный вызов функции, чтобы узнать реальный размер выходного буфера. На случай, если вдруг такая кодировка.

Завершающий нуль в возвращённом размере будет учтён, если передана -1 в качестве размера входной строки. Это подразумевает, что строка нуль-терминирована и ноль тоже нужен. Если указать не -1, а конкретное количество символов/байтов (возможно, не всю строку), то возвращённый размер выходного буфера расчитан строго под эти символы и соответственно нуль в конец при конвертации не будет добавлен.