Серый форум — VBS: Модифицировать скрипт: выгрузить данные из Active Directory

Re: VBS: Модифицировать скрипт: выгрузить данные из Active Directory

null@example.com (bnp322) — Thu, 11 Nov 2010 13:31:13 +0000

Да! Это идеально! Спасибо, в конечном виде так:

Dim objRoot, strDomain
Dim objConnection, objCommand, objRSet
Dim objFS, objExcel, objWB, objWSheet, strBook, intRow, intColumn, strTemp
Const ADS_SCOPE_SUBTREE = 2
strBook = "Users.xls"
intRow = 2
Set objExcel  = CreateObject("Excel.Application")
objExcel.Visible = True
Set objWB = objExcel.Workbooks.Add
Set objWSheet = objWB.Worksheets(1)
Set objFS = CreateObject("Scripting.FileSystemObject")
strBook = objFS.BuildPath(objFS.GetParentFolderName(WScript.ScriptFullName), strBook)
Set objRoot = GetObject("LDAP://RootDSE")
strDomain = objRoot.Get("DefaultNamingContext")
Set objRoot = Nothing
Set objConnection = CreateObject("ADODB.Connection")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"
Set objCommand = CreateObject("ADODB.Command")
Set objCommand.ActiveConnection = objConnection
objCommand.Properties("Page Size") = 1000
objCommand.Properties("Timeout") = 30
objCommand.Properties("Sort On") = "description"
objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE
strCommandText = _
"SELECT mDBOverQuotaLimit,mDBStorageQuota,telephoneNumber,userPrincipalName,description,GivenName,sn FROM 'LDAP://" _
& strDomain & "' WHERE objectCategory='Person' AND objectClass='User'"
objCommand.CommandText = strCommandText
Set objRSet = objCommand.Execute
objRSet.MoveFirst
Do

    If intRow = 2 Then
        For intColumn = 1 To objRSet.Fields.Count
            objWSheet.Cells(intRow - 1, intColumn).Value = UCase(objRSet.Fields(intColumn - 1).Name)
        Next
    End If
    For intColumn = 1 To objRSet.Fields.Count
        strTemp = objRSet.Fields(intColumn - 1).Value
If Not IsNull(strTemp) Then
    objWSheet.Cells(intRow, intColumn).NumberFormat = "@"
    If IsArray(strTemp) Then
        objWSheet.Cells(intRow, intColumn).Value = Join(strTemp, vbLf)
    Else
        objWSheet.Cells(intRow, intColumn).Value = strTemp
End If
    End If
    Next
    intRow = intRow + 1
    objWSheet.Cells(intRow, 1).Activate 'своего рода индикатор процесса
    objRSet.MoveNext
Loop While Not objRSet.EOF
Set objRSet = Nothing
Set objCommand = Nothing
objConnection.Close
Set objConnection = Nothing
Set objFS = Nothing
objExcel.DisplayAlerts = False 'позволяет отключить запрос на выбор действия в случае,
                                             'когда файл уже существует
objWSheet.Columns.AutoFit
objWB.SaveAs strBook
'objWB.Close
'objExcel.Quit
Set objWSheet = Nothing
Set objWB = Nothing
Set objExcel = Nothing
'WScript.Echo "Готово."
WScript.Quit 0

Re: VBS: Модифицировать скрипт: выгрузить данные из Active Directory

null@example.com (Dmitrii) — Thu, 11 Nov 2010 12:57:19 +0000

bnp322 пишет:

... лучше без символа ' в каждой ячейки, чем номера телефонов без +

Вы не обратили должного внимания на второй из указанных способов. Между тем, его использование позволяет и "плюс" сохранить, и дополнительных символов не использовать.
Реализация очень проста:

If Not IsNull(strTemp) Then
    '===
    objWSheet.Cells(intRow, intColumn).NumberFormat = "@"
    '===
    If IsArray(strTemp) Then
        objWSheet.Cells(intRow, intColumn).Value = Join(strTemp, vbLf)
    Else
        objWSheet.Cells(intRow, intColumn).Value = strTemp
    End If
End If

Re: VBS: Модифицировать скрипт: выгрузить данные из Active Directory

null@example.com (bnp322) — Thu, 11 Nov 2010 12:15:47 +0000

Да все получилось, хорошо!
Но я посмотрел... лучше без символа ' в каждой ячейки, чем номера телефонов без + !

Спасибо!

Re: VBS: Модифицировать скрипт: выгрузить данные из Active Directory

null@example.com (alexii) — Thu, 11 Nov 2010 09:44:34 +0000

См. выше. То есть, наподобие:

If Not IsNull(strTemp) Then
    If IsArray(strTemp) Then
        objWSheet.Cells(intRow, intColumn).Value = "'" & Join(strTemp, vbLf)
    Else
        objWSheet.Cells(intRow, intColumn).Value = "'" & strTemp
    End If
End If

Re: VBS: Модифицировать скрипт: выгрузить данные из Active Directory

null@example.com (bnp322) — Thu, 11 Nov 2010 08:58:47 +0000

Dmitrii пишет:

Речь об отображении значений в книге Excel?
Если так, то всё просто - номер телефона воспринимается как числовое значение и "плюс" (по умолчанию) опускается.
Варианты решения:
- использовать в номере телефона строковые символы (например, +7(495)1112233);
- настроить соответствующим образом формат тех ячеек, где будет отображаться номер (например, указать формат "Текстовый");
- ставить перед значением номера специальный символ "прямой апостроф", что равносильно указанию на текстовый формат данных в ячейке
objWSheet.Cells(intRow, intColumn).Value = "'" & strTemp

Да в Excel.

Я сделал изменения в скрипте:

Dim objRoot, strDomain
Dim objConnection, objCommand, objRSet
Dim objFS, objExcel, objWB, objWSheet, strBook, intRow, intColumn, strTemp
Const ADS_SCOPE_SUBTREE = 2
strBook = "Users.xls"
intRow = 2
Set objExcel  = CreateObject("Excel.Application")
objExcel.Visible = True
Set objWB = objExcel.Workbooks.Add
Set objWSheet = objWB.Worksheets(1)
Set objFS = CreateObject("Scripting.FileSystemObject")
strBook = objFS.BuildPath(objFS.GetParentFolderName(WScript.ScriptFullName), strBook)
Set objRoot = GetObject("LDAP://RootDSE")
strDomain = objRoot.Get("DefaultNamingContext")
Set objRoot = Nothing
Set objConnection = CreateObject("ADODB.Connection")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"
Set objCommand = CreateObject("ADODB.Command")
Set objCommand.ActiveConnection = objConnection
objCommand.Properties("Page Size") = 1000
objCommand.Properties("Timeout") = 30
objCommand.Properties("Sort On") = "description"
objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE
strCommandText = "SELECT mDBOverQuotaLimit,mDBStorageQuota,telephoneNumber,userPrincipalName,description,GivenName,sn FROM 'LDAP://" & strDomain & "' WHERE objectCategory='Person' AND objectClass='User'"
objCommand.CommandText = strCommandText
Set objRSet = objCommand.Execute
objRSet.MoveFirst
Do

    If intRow = 2 Then
        For intColumn = 1 To objRSet.Fields.Count
            objWSheet.Cells(intRow - 1, intColumn).Value = UCase(objRSet.Fields(intColumn - 1).Name)
        Next
    End If
    For intColumn = 1 To objRSet.Fields.Count
        strTemp = objRSet.Fields(intColumn - 1).Value
    If Not IsNull(strTemp) Then
    objWSheet.Cells(intRow, intColumn).Value = "'" & strTemp
    End If

    Next
    intRow = intRow + 1
    objWSheet.Cells(intRow, 1).Activate 'своего рода индикатор процесса
    objRSet.MoveNext
Loop While Not objRSet.EOF
Set objRSet = Nothing
Set objCommand = Nothing
objConnection.Close
Set objConnection = Nothing
Set objFS = Nothing
objExcel.DisplayAlerts = False 'позволяет отключить запрос на выбор действия в случае,
                                             'когда файл уже существует
objWSheet.Columns.AutoFit
objWB.SaveAs strBook
'objWB.Close
'objExcel.Quit
Set objWSheet = Nothing
Set objWB = Nothing
Set objExcel = Nothing
'WScript.Echo "Готово."
WScript.Quit 0

И он выдает другую ошибку, вероятно я делаю не то?:

Строка:    39
Символ:    5
Ошибка:    Несоответствие типа
Код:    800A000D
Источник:     Ошибка выполнения Microsoft VBScript

Re: VBS: Модифицировать скрипт: выгрузить данные из Active Directory

null@example.com (alexii) — Wed, 10 Nov 2010 14:10:17 +0000

Dmitrii пишет:

В исходном сценарии в этом не было большого смысла, т.к. значения всех просматриваемых в нём атрибутов имеют строковый тип. При этом, значение ни одного из них не может быть многострочным. А вот проверку на NULL вместо определения длины строки, действительно, надо было сделать. Виноват.

Угу, так что, извиняться не за что . Я просто не смотрел в оригинал — там хватало.

Re: VBS: Модифицировать скрипт: выгрузить данные из Active Directory

null@example.com (Dmitrii) — Wed, 10 Nov 2010 12:43:02 +0000

alexii пишет:

Тип возвращаемых данных надо проверять...

В исходном сценарии в этом не было большого смысла, т.к. значения всех просматриваемых в нём атрибутов имеют строковый тип. При этом, значение ни одного из них не может быть многострочным. А вот проверку на NULL вместо определения длины строки, действительно, надо было сделать. Виноват.

bnp322 пишет:

... параметр telephoneNumber почему выгружается без знака +
стоящего перед номером.

Речь об отображении значений в книге Excel?
Если так, то всё просто - номер телефона воспринимается как числовое значение и "плюс" (по умолчанию) опускается.
Варианты решения:
- использовать в номере телефона строковые символы (например, +7(495)1112233);
- настроить соответствующим образом формат тех ячеек, где будет отображаться номер (например, указать формат "Текстовый");
- ставить перед значением номера специальный символ "прямой апостроф", что равносильно указанию на текстовый формат данных в ячейке

objWSheet.Cells(intRow, intColumn).Value = "'" & strTemp

Re: VBS: Модифицировать скрипт: выгрузить данные из Active Directory

null@example.com (bnp322) — Wed, 10 Nov 2010 08:37:18 +0000

Работает!!!

Вопрос из любопытства:
параметр telephoneNumber почему выгружается без знака +
стоящего перед номером.

Re: VBS: Модифицировать скрипт: выгрузить данные из Active Directory

null@example.com (alexii) — Wed, 10 Nov 2010 08:00:45 +0000

Я так понимаю, что автор скрипта пытался отловить пустые значения, тогда можно и так (мне не доводилось видеть на практике многострочных Description, а проверять специально лень ):

If Not IsNull(strTemp) Then
    objWSheet.Cells(intRow, intColumn).Value = strTemp
End If

Re: VBS: Модифицировать скрипт: выгрузить данные из Active Directory

null@example.com (alexii) — Wed, 10 Nov 2010 07:57:15 +0000

Тип возвращаемых данных надо проверять. В данном случае, «description» — это массив, т.е., например:

If IsArray(strTemp) Then
    For Each elem In strTemp
        objWSheet.Cells(intRow, intColumn).Value = objWSheet.Cells(intRow, intColumn).Value & elem & vbLf
    Next
Else
    If Len(strTemp) > 0 Then
        objWSheet.Cells(intRow, intColumn).Value = strTemp
    End If
End If

Правильнее, конечно, сразу проверять тип возвращаемых данных, т.е. objRSet.Fields().Item().Type.

Re: VBS: Модифицировать скрипт: выгрузить данные из Active Directory

null@example.com (bnp322) — Wed, 10 Nov 2010 07:31:34 +0000

alexii пишет:

bnp322, это прелестно — Вы не находите? По приведённой ссылке несколько скриптов. Будем гадать в каком скрипте строка 37? Приведите Ваш код, приведите сообщение об ошибке.
И не забывайте: код оформляется тэгом «code».

Я использую предпоследний скрипт, закоментировав лишние для меня окна:

Dim objRoot, strDomain
Dim objConnection, objCommand, objRSet
Dim objFS, objExcel, objWB, objWSheet, strBook, intRow, intColumn, strTemp
Const ADS_SCOPE_SUBTREE = 2
strBook = "Users.xls"
intRow = 2
Set objExcel  = CreateObject("Excel.Application")
objExcel.Visible = True
Set objWB = objExcel.Workbooks.Add
Set objWSheet = objWB.Worksheets(1)
Set objFS = CreateObject("Scripting.FileSystemObject")
strBook = objFS.BuildPath(objFS.GetParentFolderName(WScript.ScriptFullName), strBook)
Set objRoot = GetObject("LDAP://RootDSE")
strDomain = objRoot.Get("DefaultNamingContext")
Set objRoot = Nothing
Set objConnection = CreateObject("ADODB.Connection")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"
Set objCommand = CreateObject("ADODB.Command")
Set objCommand.ActiveConnection = objConnection
objCommand.Properties("Page Size") = 1000
objCommand.Properties("Timeout") = 30
objCommand.Properties("Sort On") = "description"
objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE
strCommandText = "SELECT mDBOverQuotaLimit,mDBStorageQuota,telephoneNumber,userPrincipalName,description,GivenName,sn FROM 'LDAP://" & strDomain & "' WHERE objectCategory='Person' AND objectClass='User'"
objCommand.CommandText = strCommandText
Set objRSet = objCommand.Execute
objRSet.MoveFirst
Do
    If intRow = 2 Then
        For intColumn = 1 To objRSet.Fields.Count
            objWSheet.Cells(intRow - 1, intColumn).Value = UCase(objRSet.Fields(intColumn - 1).Name)
        Next
    End If
    For intColumn = 1 To objRSet.Fields.Count
        strTemp = objRSet.Fields(intColumn - 1).Value
      If Len(strTemp) > 0 Then
            objWSheet.Cells(intRow, intColumn).Value = strTemp
     End If
    Next
    intRow = intRow + 1
    objWSheet.Cells(intRow, 1).Activate 'своего рода индикатор процесса
    objRSet.MoveNext
Loop While Not objRSet.EOF
Set objRSet = Nothing
Set objCommand = Nothing
objConnection.Close
Set objConnection = Nothing
Set objFS = Nothing
objExcel.DisplayAlerts = False 'позволяет отключить запрос на выбор действия в случае,
                                             'когда файл уже существует
objWSheet.Columns.AutoFit
objWB.SaveAs strBook
'objWB.Close
'objExcel.Quit
Set objWSheet = Nothing
Set objWB = Nothing
Set objExcel = Nothing
'WScript.Echo "Готово."
WScript.Quit 0

Ошибка:

Строка:    37
Символ:    7
Ошибка:    Несоответствие типа
Код:    800A000D
Источник:     Ошибка выполнения Microsoft VBScript

Re: VBS: Модифицировать скрипт: выгрузить данные из Active Directory

null@example.com (alexii) — Wed, 10 Nov 2010 06:28:20 +0000

bnp322, это прелестно — Вы не находите? По приведённой ссылке несколько скриптов. Будем гадать в каком скрипте строка 37? Приведите Ваш код, приведите сообщение об ошибке.

И не забывайте: код оформляется тэгом «code».

Re: VBS: Модифицировать скрипт: выгрузить данные из Active Directory

null@example.com (bnp322) — Wed, 10 Nov 2010 04:31:08 +0000

Dmitrii пишет:

В какой строке?

В строке 37 !?
символ 9

Если я заменяю:

If Len(strTemp) > 0 Then
objWSheet.Cells(intRow, intColumn).Value = strTemp
End If
на:

objWSheet.Cells(intRow, intColumn).Value = strTemp
Все работает!

Как лучше поступить?

Re: VBS: Модифицировать скрипт: выгрузить данные из Active Directory

null@example.com (Dmitrii) — Wed, 10 Nov 2010 03:56:49 +0000

bnp322 пишет:

... ошибка:
Несоответствие типа
код: 800a000d

В какой строке?

Re: VBS: Модифицировать скрипт: выгрузить данные из Active Directory

null@example.com (bnp322) — Tue, 09 Nov 2010 15:45:26 +0000

Нужный вам атрибут имеется в схеме и носит именно такое название.

Но с этим атрибутом скрипт не выполняется - ошибка:
Несоответствие типа
код: 800a000d