... откуда Инфу берёте...

1. Полнее, чем MSDN, источника не существует.
2. alexii уже указал Вам на коллекцию ссылок, выбирайте оттуда, что требуется. Ссылка на MSDN, например,- самая первая в первом же сообщении этой коллекции.

... возникла необходимость Блокировка не через Логин, а через displayName. Случаем не подскажите уважаемые как еще и такое можно организовать?

Либо с помощью ADO (подобно ранее приведённому Вами примеру), либо с помощью интерфейса IADsNameTranslate найти "учётку" в AD, выполнить привязку и, наконец, отключить.
Пример с ADO:

Dim objRoot, strDomain
Dim objUser, strDisplayName, strTemp
Dim objConnection, objCommand, objRSet, strCommandText
Const ADS_SCOPE_SUBTREE = 2

Set objRoot = GetObject("LDAP://RootDSE")
strDomain = objRoot.Get("DefaultNamingContext")
Set objRoot = Nothing
strDisplayName = Trim(InputBox("Выводимое имя пользователя:"))
If Len(strDisplayName) > 0 Then
    Set objConnection = CreateObject("ADODB.Connection")
    objConnection.Provider = "ADsDSOObject"
    objConnection.Open "Active Directory Provider"
    Set objCommand = CreateObject("ADODB.Command")
    Set objCommand.ActiveConnection = objConnection
    strCommandText = "SELECT ADsPath FROM 'LDAP://" & strDomain & _
        "' WHERE objectCategory='Person' AND objectClass='User' AND displayName='" & strDisplayName & "'"
    objCommand.CommandText = strCommandText
    objCommand.Properties("Page Size") = 1000
    objCommand.Properties("Timeout") = 30
    objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE
    Set objRSet = objCommand.Execute
    If objRSet.RecordCount = 1 Then
        objRSet.MoveFirst
        strTemp = objRSet.Fields("ADsPath").Value
        On Error Resume Next
        Set objUser = GetObject(strTemp)
        If Err.Number = 0 Then
            objUser.AccountDisabled = True
            objUser.SetInfo
            If Err.Number = 0 Then
                strTemp = "Учётная запись отключена."
            Else
                strTemp = "Ошибка отключения учётной записи: " & Err.Number
                Err.Clear
            End If
        Else
            strTemp = "Ошибка привязки к найденному объекту: " & Err.Number
            Err.Clear
        End If
        Set objUser = Nothing
    Else
        strTemp = "Учётная запись пользователя " & UCase(strDisplayName) & " не обнаружена."
    End If
    Set objRSet = Nothing
    Set objCommand = Nothing
    objConnection.Close
    Set objConnection = Nothing
    WScript.Echo strTemp
End If
WScript.Quit 0

Пример с IADsNameTranslate:

Dim objWSNet, strDomain
Dim objTranslate, objUser, strDisplayName, strTemp
Const ADS_NAME_INITTYPE_DOMAIN = 1
Const ADS_NAME_TYPE_DISPLAY = 4
Const ADS_NAME_TYPE_1779 = 1

strDisplayName = Trim(InputBox("Выводимое имя пользователя:"))
If Len(strDisplayName) > 0 Then
    Set objWSNet = CreateObject("WScript.Network")
    strDomain = objWSNet.UserDomain
    Set objWSNet = Nothing
    On Error Resume Next
    Set objTranslate = CreateObject("NameTranslate")
    If Err.Number = 0 Then
        objTranslate.Init ADS_NAME_INITTYPE_DOMAIN, strDomain
        If Err.Number = 0 Then
            objTranslate.Set ADS_NAME_TYPE_DISPLAY, strDisplayName
            If Err.Number = 0 Then
                Set objUser = GetObject("LDAP://" & objTranslate.Get(ADS_NAME_TYPE_1779))
                If Err.Number = 0 Then
                    objUser.AccountDisabled = True
                    objUser.SetInfo
                    If Err.Number = 0 Then
                        strTemp = "Учётная запись отключена."
                    Else
                        strTemp = "Ошибка отключения учётной записи: " & Err.Number
                        Err.Clear
                    End If
                    Set objUser = Nothing
                Else
                    strTemp = "Ошибка привязки к найденному объекту: " & Err.Number
                    Err.Clear
                End If
            Else
                strTemp = "Ошибка транслирования: " & Err.Number
                Err.Clear
            End If
        Else
            strTemp = "Ошибка привязки к источнику транслирования: " & Err.Number
            Err.Clear
        End If
        Set objTranslate = Nothing
    Else
        strTemp = "Ошибка создания объекта ""NameTranslate"": " & Err.Number
        Err.Clear
    End If
    WScript.Echo strTemp
End If
WScript.Quit 0

Так ведь уже есть готовый пример: здесь. Что в нём не устраивает?

Сорри уже все нормально! Решил проблему, просто меня смущало что через Имя компа оно искало, подставил домен, и все заработало
Только вот теперь возникла необходимость Блокировка не через Логин, а через displayName. Случаем не подскажите уважаемые как еще и такое можно организовать?

Вот только единственная проблема с такой строчки! Нужны права Админа, как их тут ввести?

Используйте runas

Зачем его искать-то, если Вам уже известно имя "учётки"? Если есть сомнения в том, верно ли указано имя, то можно просто "ловить" ошибку подключения. Например:

On Error Resume Next
Set objUser = GetObject("WinNT://" & strComputerName & "/" & strUserName & ",user")
If Err.Number = 0 Then
    objUser.AccountDisabled = True
    objUser.SetInfo
Else
    Err.Clear
End If
On Error GoTo 0

Так ведь уже есть готовый пример: здесь. Что в нём не устраивает?

domainname=inputbox("Enter DNS Domain Name" & vbcrlf & "(Leave blank for current domain):")
username=inputbox("Enter username:")


if domainname = "" then
    set objRoot = getobject("LDAP://RootDSE")
    domainname = objRoot.get("defaultNamingContext")
end if

if username <> "" then

    wscript.echo finduser(username,domainname)
    
end if


Function FindUser(Byval UserName, Byval Domain) 
    on error resume next

    set cn = createobject("ADODB.Connection")
    set cmd = createobject("ADODB.Command")
    set rs = createobject("ADODB.Recordset")

    cn.open "Provider=ADsDSOObject;"
    
    cmd.activeconnection=cn
    cmd.commandtext="SELECT ADsPath FROM 'LDAP://" & Domain & "' WHERE sAMAccountName = '" & UserName & "'"
    
    set rs = cmd.execute


    if err<>0 then
        FindUser="Error connecting to Active Directory Database:" & err.description
    else
        if not rs.BOF and not rs.EOF then
                 rs.MoveFirst
                 FindUser = rs(0)

        else
            FindUser = "Not Found"
        end if
    end if
    cn.close
end function

Вот нашел именно поиск самого пользователя в АД, находит показывает, а как теперь его заблокировать? Сделать Disable Account?

не знаю зачем люди городят леса такие
в cmd всё сводится к одной строке:

net user <название учетки> /domain /active:no

Вот только единственная проблема с такой строчки! Нужны права Админа, как их тут ввести?

Нет не встроенной, объект AD

Тогда действуйте, как я Вам уже посоветовал.

afteroot пишет:

... но в домене можно же на любой комп зайти под любой учеткой , значит мне нужно отключить учетку в АД, и не на локальном компьютере а что б ей никто не мог пользоваться!

В рассматриваемом случае обращение к "учётке" на контроллере и есть обращение к объекту AD. Или Вы хотите управлять встроенной "учёткой" администратора?

Нет не встроенной, объект AD!

Dmitrii пишет:

... надо указать NetBIOS-имя любого контроллера домена.

Поправка: если контроллеры - на платформе Win 2008, то (в данной задаче) не годятся контроллеры, исполняющие роль RODC (Read Only DC), т.к. не позволяют вносить изменения в AD.

платформа Win 2003

... но в домене можно же на любой комп зайти под любой учеткой , значит мне нужно отключить учетку в АД, и не на локальном компьютере а что б ей никто не мог пользоваться!

В рассматриваемом случае обращение к "учётке" на контроллере и есть обращение к объекту AD. Или Вы хотите управлять встроенной "учёткой" администратора?

Поправка: если контроллеры - на платформе Win 2008, то (в данной задаче) не годятся контроллеры, исполняющие роль RODC (Read Only DC), т.к. не позволяют вносить изменения в AD.

afteroot пишет:

... как просто Блокировать пользователя в АД...

Не оставляет меня мысль, что на самом деле Вы хотите не блокировать, а отключить "учётку" (это не одно и то же). Если речь именно об отключении, то в сообщении #5 темы "VBS, блокирование учетной записи пользователя на локальном компьютере" уже имеется соответствующий пример.
Адаптация его к использованию в домене минимальна - в качестве значения переменной strComputerName надо указать NetBIOS-имя любого контроллера домена.

Эм.. но в домене можно же на любой комп зайти под любой учеткой , значит мне нужно отключить учетку в АД, и не на локальном компьютере а что б ей никто не мог пользоваться!