Старая линия не стирается.
Чтобы понять, как стирать ненужное изображение, см. мой последний пример с синусоидой.
]]>x1 := 1
y1 := 2
x2 := 10
y2 := 20
Width := Height := 500
Gui, Add, Pic, hwndhPic x0 y0 w%Width% h%Height% ; в этом контроле будем рисовать
Gui, Show, w%Width% h%Height%
OnExit, Exit
OnMessage(0xF, "WM_PAINT") ; поддержка изображения при перерисовке окна
pToken := Gdip_Startup()
hbm := CreateDIBSection(Width, Height)
hdc := CreateCompatibleDC()
obm := SelectObject(hdc, hbm)
G := Gdip_GraphicsFromhdc(hdc)
Gdip_SetSmoothingMode(G, 4)
pFillBrush := Gdip_BrushCreateSolid(0xffAAAAAA) ; кисть для заливки
Gdip_FillRectangle(G, pFillBrush, 0, 0, Width, Height) ; заливаем белым поле рисования
Gdip_DeleteBrush(pFrameBrush)
pPen := Gdip_CreatePen(0xff0000FF, 1) ; карандаш для рисования
hPicDC := GetDC(hPic) ; получаем контекст контрола, чтобы переносить в него изображение
x1 := y1 := 0
Loop, 100
{
x1 := x1 + 1
y1 := y1 + 2
x2 := x2 + 3
y2 := y2 + 4
Gdip_DrawLine(G, pPen, x1, y1, x2, y2)
BitBlt(hPicDC, 0, 0, Width, Height, hdc, 0, 0)
Sleep, 10
}
Gdip_DeletePen(pPen)
return
GuiClose:
ExitApp
Exit:
ReleaseDC(hPicDC, hPic)
SelectObject(hdc, obm), DeleteObject(hbm)
DeleteDC(hdc), Gdip_DeleteGraphics(G)
Gdip_Shutdown(pToken)
ExitApp
WM_PAINT() ; поддержка изображения при перерисовке окна
{
global
SetTimer, Timer, -10
Return
Timer:
BitBlt(hPicDC, 0, 0, Width, Height, hdc, 0, 0)
Return
}Width := Height := 300
Gui, Add, Pic, hwndhPic x0 y0 w%Width% h%Height% ; к этому контролу привяжем окно для рисования
Gui, Show, w%Width% h%Height%
OnMessage(0x3, "WM_MOVE") ; отслеживаем перемещения окна
OnExit, Exit
; WS_EX_LAYERED := 0x80000, WS_EX_TRANSPARENT := 0x20
Gui, 2:-Caption +E0x80020 +hwndID +Owner1 ; в этом окне будем рисовать
Gui, 2:Show, NA
pToken := Gdip_Startup()
hbm := CreateDIBSection(Width, Height)
hdc := CreateCompatibleDC()
obm := SelectObject(hdc, hbm)
G := Gdip_GraphicsFromhdc(hdc)
Gdip_SetSmoothingMode(G, 4)
pPen := Gdip_CreatePen(0xff0000FF, 1) ; карандаш для рисования
x1 := y1 := 0
WinGetPos, x, y,,, ahk_id %hPic%
Loop % Width
{
Gdip_DrawLine(G, pPen, x1, y1, x2 := x1++, y2 := y1++)
UpdateLayeredWindow(ID, hdc, x, y, Width, Height)
Sleep, 10
}
Gdip_DeletePen(pPen)
return
Exit:
SelectObject(hdc, obm), DeleteObject(hbm)
DeleteDC(hdc), Gdip_DeleteGraphics(G)
Gdip_Shutdown(pToken)
ExitApp
GuiClose:
ExitApp
WM_MOVE()
{
global
WinGetPos, x, y,,, ahk_id %hPic%
UpdateLayeredWindow(ID, hdc, x, y, Width, Height)
}Рисовать можно также непосредственно в обычном окне, пример:
Width := Height := 300
Gui, Add, Pic, hwndhPic x0 y0 w%Width% h%Height% ; в этом контроле будем рисовать
Gui, Show, w%Width% h%Height%
OnExit, Exit
OnMessage(0xF, "WM_PAINT") ; поддержка изображения при перерисовке окна
pToken := Gdip_Startup()
hbm := CreateDIBSection(Width, Height)
hdc := CreateCompatibleDC()
obm := SelectObject(hdc, hbm)
G := Gdip_GraphicsFromhdc(hdc)
Gdip_SetSmoothingMode(G, 4)
pFillBrush := Gdip_BrushCreateSolid(0xffffffff) ; кисть для заливки
Gdip_FillRectangle(G, pFillBrush, 0, 0, Width, Height) ; заливаем белым поле рисования
Gdip_DeleteBrush(pFrameBrush)
pPen := Gdip_CreatePen(0xff0000FF, 1) ; карандаш для рисования
hPicDC := GetDC(hPic) ; получаем контекст контрола, чтобы переносить в него изображение
x1 := y1 := 0
Loop % Width
{
Gdip_DrawLine(G, pPen, x1, y1, x2 := x1++, y2 := y1++)
BitBlt(hPicDC, 0, 0, Width, Height, hdc, 0, 0)
Sleep, 10
}
Gdip_DeletePen(pPen)
return
GuiClose:
ExitApp
Exit:
ReleaseDC(hPicDC, hPic)
SelectObject(hdc, obm), DeleteObject(hbm)
DeleteDC(hdc), Gdip_DeleteGraphics(G)
Gdip_Shutdown(pToken)
ExitApp
WM_PAINT() ; поддержка изображения при перерисовке окна
{
global
SetTimer, Timer, -10
Return
Timer:
BitBlt(hPicDC, 0, 0, Width, Height, hdc, 0, 0)
Return
}Анимированная синусоида:
If !pToken := Gdip_Startup()
{
MsgBox, 48, Ошибка GDI+, Убедитесь в наличии gdiplus.dll в вашей системе!
ExitApp
}
OnExit, Exit
SetBatchLines, -1
SetWinDelay, 0
k1 = 52 ; коэффициент частоты
k2 = 80 ; коэффициент амплитуды
Width = 492
Height = 250 ; размеры картинки
SleepDuration = 6 ; пауза в цикле
Frame = 3 ; рамка
H2 := Height//2
X := (A_ScreenWidth-Width)//2
Y := (A_ScreenHeight-Height)//2
DllCall("Winmm\timeBeginPeriod", UInt, 3)
hbm := CreateDIBSection(Width, Height)
hdc := CreateCompatibleDC()
obm := SelectObject(hdc, hbm)
G := Gdip_GraphicsFromHDC(hdc)
Gdip_SetSmoothingMode(G, 4)
pFrameBrush := Gdip_BrushCreateSolid(0xffC4C0B8) ; кисть для рамки
pFillBrush := Gdip_BrushCreateSolid(0xffffffff) ; кисть для заливки
pGrayPen := Gdip_CreatePen(0xff808080, 1) ; карандаш для оси
pBluePen := Gdip_CreatePen(0xff0000ff, 1) ; карандаш для графика
Gdip_FillRectangle(G, pFrameBrush, -1, -1, Width+2, Height+2) ; с запасом
Gdip_FillRectangle(G, pFillBrush, Frame, Frame, Width-Frame*2-1, Height-Frame*2-1)
Gdip_DeleteBrush(pFrameBrush)
Gdip_DrawLine(G, pGrayPen, Frame, H2, Width-Frame-1, H2)
Gui, Color, 0xECE9D8
Gui, Add, Pic, x20 y20 w%Width% h%Height% hwndhPic
Gui, Add, Button, % "x" (Width - 40)//2 " y" 35 + Height " w80 h23 gPause vButton", Start
Gui, Show, % "w" Width+40 " h" Height + 75
hPicDC := GetDC(hPic) ; получаем контекст контрола, чтобы переносить в него изображение
BitBlt(hPicDC, 0, 0, Width, Height, hdc, 0, 0) ; переносим рисунок в контекст контрола
OnMessage(0xF, "WM_PAINT") ; поддержка изображения при перерисовке окна
Loop
{
i := !i
x1 := Frame+1
y1 := Round((-Sin((x1 - Frame - 1)*k1/1000))*k2 + H2)
While x1 < Width-Frame-2
{
DllCall("Sleep", UInt, SleepDuration)
if !p
Continue
x2 := x1 + 1
y2 := Round((-Sin((x2 - Frame - 1)*k1/1000))*k2 + H2)
if i
Gdip_DrawLine(G, pBluePen, x1, y1, x2, y2)
Else
{
end := x2 = Width-Frame-2
Gdip_FillRectangle(G, pFillBrush, x1-1, Frame+1, end ? 3 : 2, Height-Frame*2-2)
Gdip_DrawLine(G, pGrayPen, x1-1, H2, end ? x2+1 : x2, H2)
}
x1 := x2, y1 := y2
BitBlt(hPicDC, 0, 0, Width, Height, hdc, 0, 0)
}
}
Pause:
GuiControl,, Button, % (p := !p) ? "Stop" : "Start"
Return
GuiClose:
GuiEscape:
ExitApp
Exit:
Gdip_DeletePen(pGrayPen), Gdip_DeletePen(pBluePen), Gdip_DeleteBrush(pFillBrush)
ReleaseDC(hPicDC, hPic)
SelectObject(hdc, obm), DeleteObject(hbm), DeleteDC(hdc), Gdip_DeleteGraphics(G)
Gdip_Shutdown(pToken)
DllCall("Winmm\timeEndPeriod", UInt, 3)
ExitApp
WM_PAINT() ; поддержка изображения при перерисовке окна
{
global
SetTimer, Timer, -10
Return
Timer:
BitBlt(hPicDC, 0, 0, Width, Height, hdc, 0, 0)
Return
}Нажать кнопку "Старт".
Foma пишет:Может что-то нужно вывести из цикла наружу или вообще убрать?
Правильно так:
Не стирается предыдущая линия. Получается не движение линии, а рисование трапеции.
]]>x2 := 0
y2 := 0
Gui, 8: Show, x10 y10 w1000 h800, Главное
WinGet,hwnd,ID,Главное
pToken := Gdip_Startup()
Gui, 9: -Caption +E0x80000 +HWNDhwnd1 +LastFound +ToolWindow +OwnDialogs +Owner%hwnd% ;+AlwaysOnTop
Gui, 9: Show, NA
F1::
gosub, draw
return
draw:
loop, 500
{
WinGetPos,xx,yy,ww,hh,Главное
hbm := CreateDIBSection(A_ScreenWidth, A_ScreenHeight)
hdc := CreateCompatibleDC()
obm := SelectObject(hdc, hbm)
G := Gdip_GraphicsFromhdc(hdc)
Gdip_SetSmoothingMode(G, 4)
pPen := Gdip_CreatePen(0xff0000FF, 1)
Gdip_DrawLine(G, pPen, xx, yy, x2, y2)
Gdip_DeleteBrush(pPen)
UpdateLayeredWindow(hwnd1, hdc, xx, yy, ww, hh)
SelectObject(hdc, obm)
DeleteObject(hbm)
DeleteDC(hdc)
Gdip_DeleteGraphics(G)
xx := xx + 1
yy := yy + 1
x2 := x2 + 1
y2 := y2 + 1
sleep, 50
}
Return
~Esc::
Clean:
Gui 9: Destroy
ReturnFoma пишет:Может что-то нужно вывести из цикла наружу или вообще убрать?
Правильно так:
Спасибо, учту.
А о каких конкретно окнах идёт речь?
Я брал код из примера. Там поверх всего создаётся прозрачное окно gui и графика рисуется как бы отдельно от всего. А если мне нужно сделать это в непрозрачном окне с кучей других кнопок и пр?
Для окна с графикой убрал +AlwaysOnTop, добавил +Owner, привязав к основному окну. Вроде терпимо получается. Единственное, если сдвигаешь мышкой главное окно, графика остаётся на месте, иногда вне родительского окна, до тех пор, пока не отпустишь кнопку мыши. Смотрится не очень красиво. Было бы здорово как-то более крепко привязать окно с графикой к родительскому.
]]>Может что-то нужно вывести из цикла наружу или вообще убрать?
Правильно так:
draw:
hbm := CreateDIBSection(A_ScreenWidth, A_ScreenHeight)
hdc := CreateCompatibleDC()
obm := SelectObject(hdc, hbm)
G := Gdip_GraphicsFromhdc(hdc)
Gdip_SetSmoothingMode(G, 4)
pPen := Gdip_CreatePen(0xff0000FF, 1)
loop, 200
{
Gdip_DrawLine(G, pPen, x1, y1, x2, y2)
UpdateLayeredWindow(hwnd1, hdc, 0, 0, A_ScreenWidth, A_ScreenHeight)
x1 += 2, x2 += 2
Sleep, 10
}
Gdip_DeletePen(pPen)
SelectObject(hdc, obm)
DeleteObject(hbm)
DeleteDC(hdc)
Gdip_DeleteGraphics(G)
Return Совершенно не понятно как это приспособить к окну, которое должно нормально отражаться на экране. Всё равно накладывать новое окно поверх него?
А о каких конкретно окнах идёт речь?
]]>Нужно писать.
Совершенно не понятно как это приспособить к окну, которое должно нормально отражаться на экране. Всё равно накладывать новое окно поверх него?
]]>x1 := 111
y1 := 111
x2 := 222
y2 := 222
pToken := Gdip_Startup()
Gui, 9: -Caption +E0x80000 +HWNDhwnd1 +LastFound +AlwaysOnTop +ToolWindow +OwnDialogs
Gui, 9: Show, NA
F1::
gosub, draw
return
draw:
loop, 200
{
hbm := CreateDIBSection(A_ScreenWidth, A_ScreenHeight)
hdc := CreateCompatibleDC()
obm := SelectObject(hdc, hbm)
G := Gdip_GraphicsFromhdc(hdc)
Gdip_SetSmoothingMode(G, 4)
pPen := Gdip_CreatePen(0xff0000FF, 1)
Gdip_DrawLine(G, pPen, x1, y1, x2, y2)
Gdip_DeleteBrush(pPen)
UpdateLayeredWindow(hwnd1, hdc, 0, 0, A_ScreenWidth, A_ScreenHeight)
SelectObject(hdc, obm)
DeleteObject(hbm)
DeleteDC(hdc)
Gdip_DeleteGraphics(G)
x1 := x1 + 2
x2 := x2 + 2
}
Return
~Esc::
Clean:
Gui 9: Destroy
ReturnПланирую использовать как подпрограмму. Прошу посмотреть не будет ли забиваться память, тормозить и т.п. Может что-то нужно вывести из цикла наружу или вообще убрать?
]]>